GROUP 1.  Run title and other preliminaries
TEXT(Free Convec From Plate In Cross Flow
TITLE
  DISPLAY
  This run deals with the flow arising from a hot vertical plate
  placed in a cross-flow stream. The problem is three-dimensional
  and parabolic.
  The plate is assumed to be at a uniform temperature, higher than
  that of the free-stream (which is also).
                Fixed pressure                 Fixed pressure ____
              _ _ _ _ _ _ _ _  \             _ _ _ _ _ _ _ _ _ _  \
            /|               |  |           |                ^  |  |
            /|                 /                             |    /
            /|               |/   Constant -|->            _/^  |/
   Heated   /|                    mass inflow                |
   wall;    /|               | |  rate and -|->            _/^  |
   held at  /|                 |g velocity                   |
   constant /|               | v           -|->            _/^  |
   temper-  /|                                               |
   ature    /|               |             -|->            _/^  |
            /|                                               |
         ^  /|_ _ _ _ _ _ _ _|           ^  |_ _ _ _ _ _ _ _/_ _|
        y|      Fixed pressure          y|         Fixed pressure
         |--->                           |--->
           x                               z
  ENDDIS
 
    GXBUOY is used for this case.
 
    The locally-defined variables are as follows:
 
     WIN     Free stream velocity                m/s
     TIN     Free stream temperature             C
     HPLA    Height of the plate                 m
     LPLA    Length of the plate                 m
     WPLA    Width of the plate                  m
     TPLA    Plate temperature                   C
 
REAL(WIN,TIN,HPLA,LPLA,WPLA,TPLA,ABUOY)
TPLA=20.1; LPLA=3.0; HPLA=3.0;
WPLA =0.05; TIN=20.0; WIN=0.01;
 
  Groups 3, 4 & 5; domain size aand grid
NX=10; NY=10; NZ=10; XULAST=WPLA; YVLAST=HPLA; ZWLAST=LPLA
 
#unigrid
   *** The flow is parabolic
PARAB=T
 
    GROUP 7. Variables stored, solved & named
#solvel
SOLVE(H1)
 
    GROUP 8. Terms (in differential equations) & devices
   *** Deactivate the built-in source term in H1 equation
TERMS(H1,N,Y,Y,Y,Y,Y)
 
    GROUP 9. Properties of the medium (or media)
ENUL=1.E-5; PRNDTL(H1)=0.7
 
    GROUP 11. Initialization of variable or porosity fields
FIINIT(W1)=WIN
 
    GROUP 13. Boundary conditions and special sources
   1.  Wall boundary: constant temperature
 
WALL (PLTE,WEST,1,1,1,NY,1,NZ,1,1)
COVAL(PLTE,V1,1.0,0.0);COVAL(PLTE,W1,1.0,0.0)
COVAL(PLTE,H1,1.0,TPLA)
 
   2. Free stream boundary (facing the plate): uniform velocity
      and temperature
 
PATCH(HIGHX,EAST,NX,NX,1,NY,1,NZ,1,1)
COVAL(HIGHX,U1,ONLYMS,0.0);COVAL(HIGHX,V1,ONLYMS,0.0)
COVAL(HIGHX,W1,ONLYMS,WIN);COVAL(HIGHX,H1,ONLYMS,TIN)
 
   3. Free stream boundary (above the plate): uniform velocity
      and temperature
 
PATCH(HIGHY,NORTH,1,NX,NY,NY,1,NZ,1,1)
COVAL(HIGHY,P1,FIXVAL,0.0);COVAL(HIGHY,V1,ONLYMS,0.0)
COVAL(HIGHY,W1,ONLYMS,WIN);COVAL(HIGHY,H1,ONLYMS,TIN)
 
   4. Free stream boundary (below the plate): uniform velocity
      and temperature
 
PATCH(LOWY,SOUTH,1,NX,1,1,1,NZ,1,1)
COVAL(LOWY,P1,FIXVAL,0.0);COVAL(LOWY,V1,ONLYMS,0.0)
COVAL(LOWY,W1,ONLYMS,WIN);COVAL(LOWY,H1,ONLYMS,TIN)
 
   5. Cross flow boundary: uniform velocity and temperature
 
PATCH(STREAM,LOW,1,NX,1,NY,1,1,1,1)
COVAL(STREAM,P1,FIXFLU,WIN*RHO1); COVAL(STREAM,W1,ONLYMS,WIN)
COVAL(STREAM,H1,ONLYMS,TIN)
 
   6. Buoyancy force
 
#gravity
gravdir=2; href=tin; dvo1dt=3.6 e-3* CP1
#bouss
 
    GROUP 14. Downstream pressure for PARAB=T
IPARAB=1
 
    GROUP 15. Termination of sweeps
LITHYD=30
 
    GROUP 22. Spot-value print-out
IXMON=NX/2;IYMON=NY/2
TSTSWP=5
 
    GROUP 23. Field print-out and plot control
NZPRIN=5
PATCH(XYPLANE,CONTUR,1,NX,1,NY,1,NZ,1,1)
PLOT (XYPLANE,H1,0.0,20.);PLOT(XYPLANE,U1,0.0,20.)
PLOT (XYPLANE,V1,0.0,20.);PLOT(XYPLANE,W1,0.0,20.)
PATCH(ZWISE1,PROFIL,1,1,1,1,1,NZ,1,1)
PLOT (ZWISE1,H1,0.0,0.0)
PLOT (ZWISE1,V1,0.0,0.0);PLOT(ZWISE1,W1,0.0,0.0)
PATCH(ZWISENY,PROFIL,1,1,NY,NY,1,NZ,1,1)
PLOT (ZWISENY,H1,0.0,0.0)
PLOT (ZWISENY,V1,0.0,0.0);PLOT(ZWISENY,W1,0.0,0.0)
 LIBREF=137