PHOTON USE
  p
  parphi
  .75 .25 1
 
 
 
  msg         LAMINAR 3D BOUNDARY LAYER IN A CORNER
  msg
  msg   Velocity vectors:
  gr ou x 1;gr ou y 1;gr ou z 1
  vec x 1 sh;vec y 1 sh;vec z 1 sh
  msg
  msg Press  to continue
  pause
  vec off;red
  msg        Streamwise velocity contours:
  con w1 x 1 fi;.01
  con w1 y 1 fi;.01
  con w1 z 1 fi;.01
  msg
  msg Press  to continue
  pause
  con off;red
  msg        Contours of x-wise velocity component (u):
  con u1 x 1 fi;.01
  con u1 y 1 fi;.01
  con u1 z 1 fi;.01
  msg            -
  msg Press  to continue
  pause
  con off;red
  msg        Contours of y-wise velocity component (v):
  con v1 x 1 fi;.01
  con v1 y 1 fi;.01
  con v1 z 1 fi;.01
  msg
  msg Press  to continue
  pause
  con off;red
  msg        Temperature distribution:
  con h1 x 1 fi;.01
  con h1 y 1 fi;.01
  con h1 z 1 fi;.01
  msg
  msg Press  to continue
  pause
  con off;red
  msg        Pressure contours:
  con p1 x 1 fi;.01
  con p1 y 1 fi;.01
  con p1 z 1 fi;.01
  msg
  msg Press e to END
  enduse
 
    GROUP 1. Run title and other preliminaries
TEXT(3D Boundary Layer In A Corner    
TITLE
mesg(PC486/50 time last reported as 1.min
  DISPLAY
  This run analyses the boundary-layer flow along a corner
  formed by two walls. These walls have a (non-dimensionalised)
  temperature of 0.0, in contrast to the incoming-fluid
  temperature of 1.0.
                        Fixed pressure
                  ________/__
                /|       /  /|\
    Constant  -->|           |\
    mass      /  |        /  |\
    inflow  -->  |           |\__
    rate at /    |      /    |\  \
    temp. --> -->|           |\   \
    =1.0  /_ _ _ |____/______|\    Walls at fixed
         |  --> /    |      /\    /temperature(=0.0)
         |     /           /\____/
         |--> /      |    /\         ^
         |   /           /\         y|
         |  /        | ___           |--->
         | /           /\ \       x /   z
         |/_______|__|/\   \       v
          \\\\\\\\|\\\\     Fixed pressure
                   \
                    Fixed p.
  ENDDIS
 
    Interesting variants include:setting the walls at different
  temperatures; setting one wall shorter than the other; and
  changing the entry values of the scalar quantities.
 
    GROUP 3. X-direction grid specification
  ** X-direction grid distances vary as IX**2.0
GRDPWR(X,10,0.05,2.0)
 
    GROUP 4. Y-direction grid specification
  ** Y-direction grid distances vary as IY**2.0
GRDPWR(Y,10,0.05,2.0)
 
    GROUP 5. Z-direction grid specification
  ** Z-direction grid distances vary as IZ**2.0
PARAB=T;GRDPWR(Z,10,0.1,2.0)
 
    GROUP 7. Variables stored, solved & named
SOLVE(P1,U1,V1,W1,H1)
 
    GROUP 8. Terms (in differential equations) & devices
  ** The built-in source term in H1 equation is de-activated
TERMS(H1,N,Y,Y,Y,Y,Y)
 
    GROUP 9. Properties of the medium (or media)
ENUL=1.E-5;PRNDTL(H1)=0.7
 
    GROUP 13. Boundary conditions and special sources
 
  ** Upstream boundary
INLET(UPSTREAM,LOW,1,NX,1,NY,1,1,1,1)
VALUE(UPSTREAM,P1,1.0);VALUE(UPSTREAM,U1,0.0)
VALUE(UPSTREAM,V1,0.0);VALUE(UPSTREAM,W1,1.0)
VALUE(UPSTREAM,H1,1.0)
 
  ** South wall
WALL (SOUTHWAL,SOUTH,1,NX,1,1,1,NZ,1,1)
COVAL(SOUTHWAL,U1,1.0,0.0);COVAL(SOUTHWAL,W1,1.0,0.0)
COVAL(SOUTHWAL,H1,1.0,0.0)
 
  ** Open north boundary
PATCH(HIGHY,CELL,1,NX,NY,NY,1,NZ,1,1)
COVAL(HIGHY,P1,FIXP,0.0);COVAL(HIGHY,U1,ONLYMS,0.0)
COVAL(HIGHY,V1,ONLYMS,0.0);COVAL(HIGHY,W1,ONLYMS,1.0)
COVAL(HIGHY,H1,ONLYMS,1.0)
 
  ** West wall
WALL (WESTWALL,WEST,1,1,1,NY,1,NZ,1,1)
COVAL(WESTWALL,V1,1.0,0.0);COVAL(WESTWALL,W1,1.0,0.0)
COVAL(WESTWALL,H1,1.0,0.0)
 
  ** Open east boundary
PATCH(HIGHX,CELL,NX,NX,1,NY,1,NZ,1,1)
COVAL(HIGHX,P1,FIXP,0.0)
COVAL(HIGHX,U1,ONLYMS,0.0);COVAL(HIGHX,V1,ONLYMS,0.0)
COVAL(HIGHX,W1,ONLYMS,1.0);COVAL(HIGHX,H1,ONLYMS,1.0)
 
    GROUP 14. Downstream pressure for PARAB=T
IPARAB=1
 
    GROUP 15. Termination of sweeps
LITHYD=10
 
    GROUP 16. Termination of iterations
LITER(P1)=100;ENDIT(P1)=1.E-15;LITER(W1)=100;LITER(H1)=20
 
    GROUP 22. Spot-value print-out
IYMON=NY/2
 
    GROUP 23. Field print-out and plot control
NXPRIN=3;NYPRIN=3;NZPRIN=10;NPLT=1
PATCH(FIXEDZ,CONTUR,1,NX,1,NY,1,NZ,1,1)
PLOT(FIXEDZ,U1,0.0,20.0);PLOT(FIXEDZ,V1,0.0,20.0)
PLOT(FIXEDZ,W1,0.0,20.0);PLOT(FIXEDZ,H1,0.0,20.0)
 
  ***actdem***
do ii=1,5
+ mesg(
enddo
mesg( Initial data that can be changed :
+ mesga( South wall enthalpy is set to 0.0.
+ mesg( West wall enthalpy is set to 0.0.
+ mesg( Fluid enters with enthalpy of 1.
+ mesg( Fluid velocity at the leading edge is set to 1.m/s
mesga( Do you want to change settings (y/n)? (Default n)
readvdu(ans,char,n)
 
if(:ans:.eq.y) then
+ real(rt1)
+ do ii=1,5
+   mesg(
+ enddo
  ** South wall
+ mesga( South wall enthalpy is 0.0. OK?
+ mesg(If not, insert new value.
+ readvdu(rt1,real,0.0)
+ COVAL(SOUTHWAL,H1,1.0,rt1)
 
+ do ii=1,5
+   mesg(
+ enddo
+ mesga( West wall enthalpy is 0.0. OK?
+ mesg(If not, insert new value.
+ readvdu(rt1,real,0.0)
+ COVAL(WESTWALL,H1,1.0,rt1)
 
+ do ii=1,5
+   mesg(
+ enddo
+ mesga( Fluid enters with enthalpy of 1. OK?
+ mesg(If not, insert new value.
+ readvdu(rt1,real,1.0)
+ VALUE(UPSTREAM,H1,rt1)
 
+ do ii=1,5
+   mesg(
+ enddo
+ mesg( Ffluid velocity at the leading edge is 1.m/s. OK?
+ mesga( If not, insert new value.
+ readvdu(rt1,real,1.)
+ VALUE(UPSTREAM,P1,rt1);VALUE(UPSTREAM,W1,rt1)
endif
 
TSTSWP=-1; IDISPA=1
selref=t;resfac=1.e-2