```
GROUP 1. Run title
TEXT(Shallow Sample Cup In Crosswind
TITLE
DISPLAY
A simulation is made of the flow in and around a shallow
open-topped hollow cylinder with a crosswind blowing
across its top, normal to the cylinder axis. The height
of the cup to its radius is 0.4 . This geometry is a design
considered for a sampling cup used for measuring atmospheric
precipitation.

Cylindrical polar coordinates are used in 3 dimensions.
The polar axis points vertically upwards from the ground
surface, and the vertical extent of the domain extends well
beyond the top of the sampling cup. The radial extent of the
domain extends beyond the rim of the cup.

The subroutine GXPOLR called from GREX3 is used to set
boundary conditions at the cylindrical outer surface of the
domain of integration, where a uniform stream of air is
present. This is done in GXPOLR by resolving the inflow
velocity along the radial and tangential directions of the
grid, and fixing the U1 and V1 values at the boundary cells
to these resolutes.
ENDDIS

REAL(PI,DY,AA);PI=3.14159
INTEGER(XFLOW1,XFLOW2,JJ1);XFLOW1=6;XFLOW2=15

GROUP 3. X-direction grid specification
** The domain is extended over 360 degrees in this example.
CARTES=F;XCYCLE=T;GRDPWR(X,20,2.0*PI,1.0)

GROUP 4. Y-direction grid specification
YVLAST=0.1;NY=21
**Inside the cup 10 radial layers of cells are used, and
beyond the rim of the cup 11 radial layers of cells are
used.  A geometric-progression grid spacing distribution
is employed both sides of the cup wall to ensure adequate
resolution of the flow at the exterior- and interior-side
of the cup wall.
YFRAC(10)=1.0;DY=.03;AA=1.2
DO JJ=9,1,-1
+ JJ1=JJ+1
+ YFRAC(JJ)=YFRAC(JJ1)-DY;DY=DY*AA
ENDDO
DY=.03;AA=1.4
DO JJ=11,19
+ JJ1=JJ-1;YFRAC(JJ)=YFRAC(JJ1)+DY;DY=DY*AA
ENDDO
YFRAC(20)=3.5;YFRAC(21)=4.0

GROUP 5. Z-direction grid specification
GRDPWR(Z,9,0.12,1.)

GROUP 7. Variables stored, solved & named
SOLVE(P1,U1,V1,W1);SOLUTN( P1,Y,Y,Y,N,N,N )

GROUP 9. Properties of the medium (or media)
RHO1=1.205;ENUL=1.8E-5/RHO1;ENUT=ENUL*10.

GROUP 11. Initialization of variable or porosity fields
**The wall of the cup is represented by setting zero
porosities at the cylindrical surface IY=10 . The minus
signs preceding the number 10 flag the activation of wall
friction at the inner and outer surface of the cup wall.
CONPOR(0.0,NORTH,1,NX,-10,-10,1,NZ/3)

GROUP 13. Boundary conditions and special sources
** The inlet region extends from pi/2 to 3pi/2. The wind-
speed at the cylindrical inlet surface is set in POLRA
which is resolved in subroutine GXPLOR into the
POLRA=4.0
PATCH(UPOL,CELL,XFLOW1-1,XFLOW2,NY,NY,1,NZ,1,1)
COVAL(UPOL,U1,FIXVAL,GRND1)
PATCH(VPOL,CELL,XFLOW1,XFLOW2,NY-1,NY-1,1,NZ,1,1)
COVAL(VPOL,V1,FIXVAL,GRND1)
** The pressure is fixed to zero around the entire outer
boundary of the domain...
PATCH(PINF,CELL,1,NX,NY,NY,1,NZ,1,1)
COVAL(PINF,P1,1.0E6,0.0 )

GROUP 15. Termination of sweeps
LSWEEP=100;selref=t;resfac=0.1

GROUP 16. Termination of iterations
LITER(P1) = 12;LITER(U1)=1;LITER(V1)=1

GROUP 17. Under-relaxation devices
RELAX(U1,FALSDT,0.003);RELAX(V1,FALSDT,0.003)
RELAX(W1,FALSDT,0.003)

GROUP 21. Print-out of variables

GROUP 22. Spot-value print-out
IXMON=2;IYMON=12;IZMON=4

GROUP 23. Field print-out and plot control
NPLT=2;NXPRIN=NX/5;NYPRIN=NY/5
PATCH(MAP,CONTUR,1,NX,1,NY,3,3,1,1)
PLOT(MAP,P1,1.0,10.0);PLOT(MAP,U1,1.0,10.0)
PLOT(MAP,V1,1.0,10.0);PLOT(MAP,W1,1.0,10.0)
```