#cls
  DISPLAY
  Start of direct-input-to-EARTH data
  This is an example of the direct Q1-to-EARTH feature, which
  allows extensive text input as well as input of variables.
  The feature is activated by the setting: READQ1 = T.
 
  A few items of frequent use may be inserted directly, namely:
  LSWEEP, LSTEP, ISOLX, ISOLY, ISOLZ, ISOLBK, RHO1, ENUL, ENUT,
  CFIPS, CMDOT, CARTES, STEADY, NONORT
 
  Arrayed variable such as PRNDTL(INDVAR), LITER(INDVAR) and
  NAME(INDVAR) may be entered as: (1) array name, (2) numerical
  value of INDVAR, (3) value, followed by comments if desired.
#pause 
  Others variables may be entered via: (1) SATEAR COMMON block name,
  (2) position in block, (3) value, followed by comments if desired,
  as in the following example.  The complete entry will be printed
  near the top of the RESULT file. The position of the item in the
  block can of course be found by counting. However, GUIDE contains
  a helpful table (see NEWS).
 
  An asterisk at the beginning of the line cause the line to be
  ignored.
 
  This feature must be used with caution, because some resettings of
  data may conflict with settings made in the satellite. For
  example, whole-field solution cannot necessarily be switched ON
  because necessary storage may not be provided; but it may be
  switched OFF (by dividing the relevant ISLN by 5).
#pause 
  READQ1 will first search for the string 'BEGIN' and only then will
  it start to interpret the following lines as data. Note also that
  the lines intended for READQ1 must be entered as comment lines in
  the Q1 or SATELLITE will attempt to interpret them as command
  lines and flag an error.
 
  READQ1_BEGIN
 
  LSWEEP  10
  ISOLZ    1
  CARTES   F
  LITER   14  100       ...liter(H1)
  * ISLN    14    6       ...solution set to whole field for h1
  PRNDTL  14    0.01    ...prndtl(H1)
  NAME     7  aw1       ...name of W1
  LDAT    25    t       ...echo
  READQ1_END
 
  * End of direct-input-to-EARTH data
#pause 
    GROUP 1. Run title and other preliminaries
TEXT(2D Channel Flow                   
TITLE
  DISPLAY
  This run illustrates what happens when a fluid enters a
  rectangular duct, the walls of which are held at a constant
  temperature.
 
  Interesting parameters to vary include:- entry values of scalar
  quantities; the flux boundary conditions on the wall, and length-
  to-width ratio.
  ENDDIS
#pause 
    GROUP 4. Y-direction grid specification
NREGY=1
IREGY=1; GRDPWR(Y,5,1.0,1.0)
 
    GROUP 5. Z-direction grid specification
NREGZ=1
IREGZ=1; GRDPWR(Z,5,2.0,1.0)
 
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1,H1)
NAME(H1)=TEMP
SOLUTN(TEMP,Y,Y,Y,P,P,P)
 
    GROUP 8. Terms (in differential equations) & devices
TERMS(TEMP,N,Y,Y,Y,Y,Y)
 
    GROUP 9. Properties of the medium (or media)
ENUL=1.E-1; PRNDTL(TEMP)=0.7
 
    GROUP 13. Boundary conditions and special sources
  ** Inlet
INLET(IN,LOW,#1,#1,#1,#NREGY,#1,#1,1,1)
VALUE(IN,P1,5.0);VALUE(IN,W1,5.0)
VALUE(IN,V1,0.0);VALUE(IN,TEMP,9.0)
  ** Outlet
PATCH(OUTLET,HIGH,#1,#1,#1,#NREGY,#NREGZ,#NREGZ,1,1)
COVAL(OUTLET,P1,FIXP,0.0)
COVAL(OUTLET,V1,ONLYMS,0.0);COVAL(OUTLET,W1,ONLYMS,0.0)
  ** North wall
WALL (NORTH,NORTH,#1,#1,#NREGY,#NREGY,#1,#NREGZ,1,1)
COVAL(NORTH,W1,1.0,0.0);COVAL(NORTH,TEMP,1.0,0.0)
 
    GROUP 15. Termination of sweeps
LSWEEP=20
RESREF(P1)=1.E-5;RESREF(V1)=1.E-5;RESREF(W1)=1.E-5
RESREF(TEMP)=1.E-5
 
    GROUP 19. Data communicated by satellite to GROUND
    !! Activate the next line if direct Q1-to-EARTH data input
    is desired
    READQ1=T
 
    GROUP 22. Spot-value print-out
IYMON=1;IZMON=NZ-1
 
    GROUP 23. Field print-out and plot control
NPRINT=20;NPLT=2
PATCH(ZEQ3,PROFIL,1,1,1,5,3,3,1,1)
PLOT(ZEQ3,W1,0.0,0.0);PLOT(ZEQ3,TEMP,0.0,0.0)
PATCH(YEQ1,PROFIL,1,1,1,1,1,NZ,1,1)
PLOT(YEQ1,W1,0.0,.0);PLOT(YEQ1,TEMP,0.0,0.0)
PATCH(MAP,CONTUR,1,1,1,NY,1,NZ,1,1)
PLOT(MAP,W1,0.0,10.0);PLOT(MAP,TEMP,0.0,10.0)