```
GROUP 1. Run title and other preliminaries
TEXT(Heat Transfer In Pipe; Pr No Effect
TITLE
DISPLAY
This example is similar to that of case 170; but the
solution procedure is elliptic rather than parabolic.

Because the flow is nearly parabolic, economy is achieved by
not using the whole=field solver for scalars and by setting:

lithyd = 10, so that few sweeps are needed.

Further economies come from setting:

ISWC1 = LSWEEP and LITHC1 = LITHYD,

which entail that the scalars are solved only on the last sweep
and slab-wise iteration.

PHOTON commands are supplied.
ENDDIS
PHOTON USE
p
phi
4 1

view -x
msg picture is enlarged 4 times in y direction
gr ou x 1
msg contours of concentration of material with Pr = 10.0
con c x 1 fi;0.001;pause;con off; red
msg contours of concentration of material with Pr = 0.1
con b x 1 fi;0.001;pause;
msg velocity vectors
vec x 1
enduse
GROUP 2. Transience; time-step specification
GROUP 3. X-direction grid specification
** Activate polar coordinate system
CARTES=F; xulast=0.01

GROUP 4. Y-direction grid specification
IREGY=1; GRDPWR(Y,20,0.01,1.0)

GROUP 5. Z-direction grid specification
IREGZ=1; GRDPWR(Z,20,0.20,1.0)

GROUP 6. Body-fitted coordinates or grid distortion
GROUP 7. Variables stored, solved & named
** Solve three extra variables as temperatures with
different Prandtl numbers.
SOLVE(P1,V1,W1,H1,C1,C2,C3)
NAME(C1)=A; NAME(C2)=B; NAME(C3)=C

GROUP 8. Terms (in differential equations) & devices
** De-activate the built-in source term
TERMS(H1,N,Y,Y,Y,Y,Y)

GROUP 9. Properties of the medium (or media)
ENUL=1.E-5; PRNDTL(H1)=0.7
PRNDTL(A)=1.0; PRNDTL(B)=0.1; PRNDTL(C)=10.0

GROUP 10. Inter-phase-transfer processes and properties
GROUP 11. Initialization of variable or porosity fields
FIINIT(W1)=0.1

GROUP 13. Boundary conditions and special sources
WALL (WALL,NORTH,#1,#1,#NREGY,#NREGY,#1,#NREGZ,1,1)
COVAL(WALL,W1,1.0,0.0); COVAL(WALL,H1,1.0,1.0)
COVAL(WALL,A,1.0,1.0); COVAL(WALL,B,1.0,1.0); COVAL(WALL,C,1.0,1.0)

INLET(IN,LOW,#1,#1,#1,#NREGY,#1,#1,1,1)
VALUE(IN,P1,0.1); VALUE(IN,W1,0.1); VALUE(IN,H1,0.0)
VALUE(IN,A,0.0)
VALUE(IN,V1,0.0); VALUE(IN,B,0.0); VALUE(IN,C,0.0)

PATCH(OUTLET,HIGH,#1,#1,#1,#NREGY,#NREGZ,#NREGZ,1,1)
COVAL(OUTLET,P1,FIXVAL,0.0)
COVAL(OUTLET,V1,ONLYMS,0.0); COVAL(OUTLET,W1,ONLYMS,0.0)

GROUP 15. Termination of sweeps
LSWEEP=10; ISWC1=LSWEEP; SELREF=T; LITHYD=10
ITHC1=LITHYD ! This setting would ony work if LITC>=LITHYD
GROUP 17. Under-relaxation devices
RELAX(W1,FALSDT,0.1); RELAX(V1,FALSDT,0.1)
GROUP 22. Spot-value print-out
NPRMON=20; IYMON=5
GROUP 22. Spot-value print-out
IYMON=19; IZMON=10; TSTSWP=-1

GROUP 23. Field print-out and plot control
NYPRIN=2; NZPRIN=5; NPLT=1
PATCH(EXIT,PROFIL,1,1,1,NY,NZ-1,NZ-1,1,1)
PLOT(EXIT,W1,0.0,0.0); PLOT(EXIT,A,0.0,0.0)
PLOT(EXIT,B,0.0,0.0); PLOT(EXIT,C,0.0,0.0)
PATCH(PIPE,CONTUR,1,1,1,NY,1,NZ,1,1)
PLOT(PIPE,W1,0.0,10.0); PLOT(PIPE,H1,0.0,10.0)
PLOT(PIPE,A,0.0,10.0); PLOT(PIPE,B,0.0,10.0)
PLOT(PIPE,C,0.0,10.0)
REAL(REYNO)
REYNO=2.0*YVLAST/ENUL
MESG(REYNOLDS NUMBER IS :REYNO: IF OK, PRESS RETURN
MESG(OTHERWISE INSERT DESIRED NUMBER