GROUP 1. Run title and other preliminaries
TEXT(Steady Free-Convection In Annular Cavity
TITLE
  DISPLAY
  This case deals with the free-convection flow arising in an
  annular cavity the inner cylinder of which is at a constant
  temperature higher than that of the outer cylinder.
  Buoyancy forces are activated via the exemplary subroutine GREX
  with setting of constants so as to activate the Boussinesq
  approximation.
         TEMPERATURE OF THE INNER CYLINDER ----- THOT
         TEMPERATURE OF THE OUTER CYLINDER ----- TCOLD
         THERMAL EXPANSION COEFFICIENT --------- BETA
  ENDDIS
REAL(THOT,TCOLD,BETA); THOT=10.0; TCOLD=0.0; BETA=3.0E-03
    GROUP 2. Transience; time-step specification
    GROUP 3. X-direction grid specification
CARTES=F; GRDPWR(X,10,3.1416,1.5)
    GROUP 4. Y-direction grid specification
GRDPWR(Y,-10,0.1,2.0); RINNER=0.01
    GROUP 5. Z-direction grid specification
    GROUP 6. Body-fitted coordinates or grid distortion
    GROUP 7. Variables stored, solved & named
SOLVE(P1,U1,V1,H1)
    GROUP 8. Terms (in differential equations) & devices
    GROUP 9. Properties of the medium (or media)
RHO1=1.0; ENUL=1.0E-05; PRNDTL(H1)=0.73
    GROUP 10. Inter-phase-transfer processes and properties
    GROUP 11. Initialization of variable or porosity fields
FIINIT(H1)=(THOT+TCOLD)/2.0
FIINIT(U1)=1.0E-02; FIINIT(V1)=1.0E-02
    GROUP 12. Convection and diffusion adjustments
    GROUP 13. Boundary conditions and special sources
     Inner cylinder  -- HOT --
PATCH(INNER,SWALL,1,NX,1,1,1,1,1,1); COVAL(INNER,U1,1.0,0.0)
COVAL(INNER,H1,1.0,THOT)
     Outer cylinder  -- COLD --
PATCH(OUTER,NWALL,1,NX,NY,NY,1,1,1,1); COVAL(OUTER,U1,1.0,0.0)
COVAL(OUTER,H1,1.0,TCOLD)
     Buoyancy force  -- Boussinesq approximation --
#GRAVITY
GRAVACC=9.81; GRAVDIR=2; HREF=TCOLD; DVO1DT=BETA*CP1
#BOUSS
     Reference pressure
PATCH(REFP,CELL,NX,NX,NY,NY,1,1,1,1); COVAL(REFP,P1,FIXVAL,0.0)
COVAL(REFP,H1,ONLYMS,SAME)
    GROUP 15. Termination of sweeps
LSWEEP=150
    GROUP 17. Under-relaxation devices
RELAX(U1,FALSDT,1.0); RELAX(V1,FALSDT,1.0); RELAX(H1,FALSDT,1.0)
    GROUP 18. Limits on variables or increments to them
VARMIN(U1)=-1.0;VARMAX(U1)=1.0
VARMIN(V1)=-1.0; VARMAX(V1)=1.0
VARMIN(H1)=TCOLD; VARMAX(H1)=THOT
    GROUP 22. Spot-value print-out
ITABL=1
IXMON=3; IYMON=5
    GROUP 23. Print-out & plot control
PATCH(CCCC,CONTUR,1,NX,1,NY,1,1,1,1)
PLOT(CCCC,H1,0.0,10.); PLOT(CCCC,H1,1.0,10.)