PHOTON USE
  p
  phi
 
 
  msg        CONVECTIVE COOLING OF A RADIALLY-RIBBED CYLINDER
  msg
  view z;rot 90
  norm
  msg        Velocity vectors:
  gr ou z 1;vec z 1 sh
  msg
  msg Press  to continue
  pause
  vec off;red
  msg        Pressure contours:
  con p1 z 1 sh;int 15
  msg
  msg Press  to continue
  pause
  con off;red
  msg        Temperature contours:
  con temp z 1 fi;.001
  msg
  msg Press e to END
  en7duse
 
    GROUP 1. Run title and other preliminaries
TEXT(Convective Cooling Of Radial Fin  
TITLE
mesg(PC486/50 time last reported as 1.min
  DISPLAY
    Radioactive material generates heat within a  horizontally-
  disposed cylindrical metal container, the outer surface of
  which is ribbed to promote convective cooling. This analysis
  focuses on the heat transfer and air flow in, and around, one
  half of one of the fins.
    Heat is supplied at a constant rate per unit area along the
  inner surface of the cylinder. Most of the heat is transferred
  from the metal to the air, but some is radiated away at a
  constant prescribed flux. A cylindrical domain of integration is
  used, the inner boundary of which corresponds to the inner
  surface of the container. The outer boundary of the domain
  extends well into the air. The coordinate x increases from zero
  at the top to 180 degrees (pi radians) at the bottom, for
  symmetry about the vertical plane through the cylinder is present.
  The large conductivity of the metal is contrived by enlarging the
  porosities for the cell faces in the metal.
    The heating of the air results in its upward motion, ie motion
  in the negative x sense, caused by buoyancy.
  ENDDIS
    The user-defined local variables are:
  NYC is the last radial cell in the metal cylinder;
  NYR is the last radial cell in the metal fin which protrudes from
  the cylinder;
  NZR is the number of axial cells extending from the radial
  symmetry plane in the fin to the edge of the fin;
  COND is the conductivity of the metal divided by the viscosity
  and the specific heat of the air;
  CP is the specific heat of the metal;
  FIXT is the ambient temperature raised to power 4; and
  T4 is the mean metal temperature raised to power 4.
REAL(COND,CP,FIXT,T4);INTEGER(NYC,NYR,NZR)
NYC=1;NYR=9;NZR=3
 
    GROUP 3. X-direction grid specification
CARTES=F
GRDPWR(X,12,3.142,1.0)
 
    GROUP 4. Y-direction grid specification
NY=12;RINNER=1.14
YFRAC(1)=-10.;YFRAC(2)=0.0125
YFRAC(3)=2.0; YFRAC(4)=0.05
 
    GROUP 5. Z-direction grid specification
NZ=7
ZFRAC(1)=-4.0;ZFRAC(2)=0.01/4.0
ZFRAC(3)=3.0; ZFRAC(4)=0.015/3.0
 
    GROUP 7. Variables stored, solved & named
   **For economy, point-by-point solution is used for velocities
     and temperature (the main diffusive links are z-directed in
     this case, and at present there is no means of solving
     simultaneously in z at the linear-equation level, except for
     pressure corrections which are solved whole field).
     Harmonic averaging is selected for the temperature equations
     by the last argument of SOLUTN...
SOLUTN(P1,Y,Y,Y,N,N,N);SOLUTN(U1,Y,Y,N,Y,P,P)
SOLUTN(V1,Y,Y,N,Y,P,P);SOLUTN(W1,Y,Y,N,Y,P,P)
SOLUTN(H1,Y,Y,N,Y,P,Y)
NAME(H1)=TEMP
 
    GROUP 8. Terms (in differential equations) & devices
   **Dissipation of mechanical energy into heat is presumed to be
     insignificant, so the built-in source for temperature is
     de-activated.
TERMS(TEMP,N,Y,Y,N,Y,N);DIFCUT=0.0
 
    GROUP 9. Properties of the medium (or media)
RHO1=1.163;ENUL=1.8E-5;PRNDTL(TEMP)=0.7
 
    GROUP 11. Initialization of variable or porosity fields
FIINIT(U1)=-0.5
   **The following commands provide a realistic initial distribution
     for the temperature field...
PATCH(TALL,LINVLY,1,NX,1,NY,1,NZ,1,1);COVAL(TALL,TEMP,-150.,37.)
PATCH(TCYL,LINVLY,1,NX,1,NYC,1,NZ,1,1);COVAL(TCYL,TEMP,-120.,75.)
PATCH(TFIN,LINVLY,1,NX,NYC+1,NYR,1,NZR,1,1)
COVAL(TFIN,TEMP,-120.,75.)
   **The high conductivity of the metal is contrived by
     appropriately enlarging the cell-face porosities for cell faces
     which have metal on either side. The metal conductivity is
     36.2 Watts per metre per degree. It is divided by the
     the viscosity and specific heat of the air...
CP=1008.0;COND=36.2*PRNDTL(TEMP)/(RHO1*ENUL*CP)
CONPOR(COND,NORTH,1,NX,1,NYR-1,1,NZR)
CONPOR(COND,EAST,1,NX,1,NYC,1,NZ)
CONPOR(COND,EAST,1,NX,NYC+1,NYR,1,NZR)
CONPOR(COND,HIGH,1,NX,1,NYC,1,NZ)
CONPOR(COND,HIGH,1,NX,NYC+1,NYR,1,NZR-1)
   **Cell faces which are located at the metal-air interface require
     porosity factors of 2 to ensure the correct transfer of heat
     and momentum (ie friction) across the interface. The factor of
     2 is a consequence of the uniform spacing used for the cells
     each side of the interface, and of the fact that the large
     metal conductivity results in the temperature at the interface
     being very nearly equal to the local bulk temperature of the
     metal.
CONPOR(2.0,NORTH,1,NX,NYC,NYC,NZR+1,NZ)
CONPOR(2.0,HIGH,1,NX,NYC+1,NYR,NZR,NZR)
CONPOR(2.0,NORTH,1,NX,NYR,NYR,1,NZR)
   **The correctness of the foregoing porosity settings can be
     verified by printing the fields of the porosities.
 
    GROUP 13. Boundary conditions and special sources
   **Fix the velocities to zero within the solid...
PATCH(CYLINDER,CELL,1,NX,1,NYC,1,NZ,1,1)
COVAL(CYLINDER,U1,FIXVAL,0.0);COVAL(CYLINDER,V1,FIXVAL,0.0)
COVAL(CYLINDER,W1,FIXVAL,0.0)
PATCH(FIN,CELL,1,NX,NYC+1,NYR,1,NZR,1,1)
COVAL(FIN,U1,FIXVAL,0.0);COVAL(FIN,V1,FIXVAL,0.0)
COVAL(FIN,W1,FIXVAL,0.0)
   **Prescribed heat flux across inner cylindrical boundary
PATCH(HEATFLX,SOUTH,1,NX,1,1,1,NZ,1,1)
COVAL(HEATFLX,TEMP,FIXFLU,1.811E+3/CP)
   **The pressures are fixed on the outer boundary of the
     domain for the cells where outflow is expected.
PATCH(EXIT,NORTH,1,NX/2,NY,NY,1,NZ,1,1)
COVAL(EXIT,P1,1.E3*FIXP,0.0);COVAL(EXIT,TEMP,ONLYMS,0.0)
COVAL(EXIT,U1,ONLYMS,0.0);COVAL(EXIT,V1,ONLYMS,0.0)
COVAL(EXIT,W1,ONLYMS,0.0)
   **The stagnation pressures are set where inflow is
     expected along the outer boundary of the domain.
PATCH(INLET,NORTH,NX/2+1,NX,NY,NY,1,NZ,1,1)
COVAL(INLET,P1,-2.0*RHO1,0.0);COVAL(INLET,TEMP,0.0,0.0)
COVAL(INLET,U1,ONLYMS,SAME);COVAL(INLET,V1,ONLYMS,SAME)
   **The Boussinesq approximation is used to represent the
     buoyancy force.
BUOYE=0.0;DVO1DT=9.81*10.08/3.;BUOYA=0.0;BUOYB=-1.0
PATCH(BUOYU,PHASEM,1,NX-1,1,NY,1,NZ,1,1)
COVAL(BUOYU,U1,FIXFLU,BOUSS)
PATCH(BUOYV,PHASEM,1,NX,1,NY-1,1,NZ,1,1)
COVAL(BUOYV,V1,FIXFLU,BOUSS)
   **Set the presribed radiation flux...
FIXT=301.0**4;T4=366.0**4-FIXT
PATCH(RADBOT,NORTH,1,NX,NYC,NYC,NZR+1,NZ,1,1)
COVAL(RADBOT,TEMP,FIXFLU,-9.927E-9*T4/CP)
T4=360.0**4-FIXT
PATCH(RADSIDE,HIGH,1,NX,NYC+1,NYR,NZR,NZR,1,1)
COVAL(RADSIDE,TEMP,FIXFLU,-7.90E-9*T4/CP)
T4=354.0**4-FIXT
PATCH(RADTOP,NORTH,1,NX,NYR,NYR,1,NZR,1,1)
COVAL(RADTOP,TEMP,FIXFLU,-3.912E-8*T4/CP)
 
    GROUP 17. Under-relaxation devices
RELAX(U1,FALSDT,1.0);RELAX(V1,FALSDT,1.0)
RELAX(W1,FALSDT,1.0);RELAX(P1,LINRLX,0.3)
 
    GROUP 22. Spot-value print-out
LSWEEP=20;ITABL=3;IPLTL=LSWEEP;NPLT=1
IXMON=NX/2;IYMON=NY/2;IZMON=NZR+1
YZPR=T;NXPRIN=2
 
    GROUP 23. Field print-out and plot control
PATCH(TXEQ1,CONTUR,1,1,1,NY,1,NZ,1,1);COVAL(TXEQ1,TEMP,0.,15.)
PATCH(TXEQ4,CONTUR,4,4,1,NY,1,NZ,1,1);COVAL(TXEQ4,TEMP,0.,15.)
PATCH(TXEQ6,CONTUR,6,6,1,NY,1,NZ,1,1);COVAL(TXEQ6,TEMP,0.,15.)
PATCH(TXEQ9,CONTUR,9,9,1,NY,1,NZ,1,1);COVAL(TXEQ9,TEMP,0.,15.)
IPROF=3
PATCH(45DEG,PROFIL,3,3,2,NY,NZ,NZ,1,1);COVAL(45DEG,TEMP,0.,0.0)
COVAL(45DEG,U1,0.0,0.)
PATCH(90DEG,PROFIL,6,6,2,NY,NZ,NZ,1,1);COVAL(90DEG,TEMP,0.,0.0)
COVAL(90DEG,U1,0.0,0.)
PATCH(120DEG,PROFIL,8,8,2,NY,NZ,NZ,1,1);COVAL(120DEG,TEMP,0.,0.0)
COVAL(120DEG,U1,0.0,0.)
PATCH(165DEG,PROFIL,11,11,2,NY,NZ,NZ,1,1);COVAL(165DEG,TEMP,0.,0.0)
COVAL(165DEG,U1,0.0,0.)
 
  ***actdem***
 
+ do ii=1,5
+   mesg(
+ enddo
mesg( Initial data that can be changed:
+ mesga( The last radial cell in the metal fin which protrudes
+ mesg(  from the cylinder is :NYR:
+ mesg( Conductivity of the metal is set to 36.2 W/m/deg
+ mesg( Specific heat of the metal is :cp: J/kg/deg
mesga( Do you want to change settings (y/n)? (Default n)
readvdu(ans,char,n)
 
if(:ans:.eq.y) then
+ real(rt1);integer(it1)
+ do ii=1,5
+   mesg(
+ enddo
+ mesg( The last radial cell in the metal fin which protrudes
+ mesga(from the cylinder is :NYR:. OK? If not, insert new value.
+ readvdu(NYR,int,:NYR:)
+ if(nyr.gt.ny) then
+   nyr=ny
+ endif
PATCH(TFIN,LINVLY,1,NX,NYC+1,NYR,1,NZR,1,1)
CONPOR(2.0,HIGH,1,NX,NYC+1,NYR,NZR,NZR)
CONPOR(2.0,NORTH,1,NX,NYR,NYR,1,NZR)
PATCH(FIN,CELL,1,NX,NYC+1,NYR,1,NZR,1,1)
PATCH(RADSIDE,HIGH,1,NX,NYC+1,NYR,NZR,NZR,1,1)
PATCH(RADTOP,NORTH,1,NX,NYR,NYR,1,NZR,1,1)
 
+ do ii=1,5
+   mesg(
+ enddo
+ mesg( Conductivity of the metal is 36.2 W/m/deg. OK?
+ mesga( If not, insert new value.
+ readvdu(rt1,real,36.2)
 
+ do ii=1,5
+   mesg(
+ enddo
+ mesg( Specific heat of the metal is :cp:. OK?
+ mesg( If not, insert new value.
+ readvdu(cp,real,:CP:)
COND=rt1*PRNDTL(TEMP)/(RHO1*ENUL*CP)
CONPOR(COND,NORTH,1,NX,1,NYR-1,1,NZR)
CONPOR(COND,EAST,1,NX,1,NYC,1,NZ)
CONPOR(COND,EAST,1,NX,NYC+1,NYR,1,NZR)
CONPOR(COND,HIGH,1,NX,1,NYC,1,NZ)
CONPOR(COND,HIGH,1,NX,NYC+1,NYR,1,NZR-1)
endif
output(p1,y,y,y,y,y,y)
output(u1,y,y,y,y,y,y)
output(v1,y,y,y,y,y,y)
output(w1,y,y,y,y,y,y)
selref=t; resfac=1.e-2
TSTSWP=-1