GROUP 1. Run title and other preliminaries
TEXT(Ricou's Jet In Cylindrical Chamber
TITLE
real(winj,rhoinj,walvel,reyno,jetdiam,denrat)
rhoinj=1.0; winj=50.0
 
  DISPLAY
   F Ricou (London University PhD thesis 1959) injected gases into
   a porous-walled cylindrical chamber with a circular exit opposite
   the injection orifice. He varied the inflow rate of air through
   the porous wall until the pressure in the chamber equalled that
   outside, and took this to be the rate of entrainment of air into
   jet.
 
   When the flow was turbulent, he found that the rate of entrain-
   ment per unit length equalled 0.32 times the mass-injection rate
   divided by the nozzle diameter, if the injected fluid had the
   same density as the surrounding fluid.
 
   Please press RETURN to continue
readvdu(nphi,int,nphi)
 
 
   When the densities differed he found that the 0.32 factor should
   be replaced by:
 
   0.32 * (surrounding-fluid density/injected-fluid density)**0.5
 
   This Q1 file causes PHOENICS to simulate the conditions of the
   experiment. The Reynolds number and density ratio can be varied.
 
   The Prandtl mixing-length model of turbulence is used, with the
   low-Reynolds-Number modification activated by IENUTA=6 .
 
   PHOTON commands are supplied.
 
   ENDDIS
  PHOTON USE
  p
  phi
 
 
  up z
  gr ou x 1
  msg contours of axial velocity
  con w1 x 1 fi;0.001;pause;con off; red
  msg contours of concentration of injected material
  con a x 1 fi;0.001;pause;con off;red
  msg enut contours
  con enut x 1 fi;0.001;pause;con off;red
  msg velocity vectors
  vec x 1 sh;pause;con off;vec off;red
  msg streamlines
  stre 2d x 1 sh;int 20
  enduse
 
  GROUP 3. X-direction grid specification
  ** Activate polar coordinate system
CARTES=F; XULAST=0.01
 
    GROUP 4. Y-direction grid specification
GRDPWR(Y,40,4.5*0.0254,1.0)
JETDIAM=0.2*YVLAST
 
    GROUP 5. Z-direction grid specification
GRDPWR(Z,40,12.75*0.0254,1.0)
 
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1,C1); STORE(ENUT,LEN1); NAME(C1)=A
 
    GROUP 9. Properties of the medium (or media)
RHO1=1.0; ENUL=1.E-5; PRNDTL(A)=0.7; PRT(A)=0.7
REYNO=WINJ*JETDIAM/ENUL
mesg(reynolds number is :reyno: if ok, press return
mesg(otherwise insert desired number
READVDU(REYNO,REAL,REYNO)
WINJ=REYNO*ENUL/JETDIAM
REYNO
DENRAT=RHOINJ/RHO1
mesg( Ratio of injected to surrounding density is :denrat:
mesg( If ok, press return, otherwise insert desired number...
READVDU(denrat,REAL,denrat)
RHOINJ=DENRAT*RHO1
DENRAT
  ENUT=0.016*WINJ*JETDIAM
  ** settings for the Prandtl Mixing Length Model
EL1=MIXLENJET; ENUT=MIXLEN; DWDY=T
  ** EL1A = mixing-length constant for mixing-layer zone
EL1A=0.05
     EL1B =   ''     ''      ''    for jet zone
EL1B=0.075
     EL1C = velocity fraction for jet-width calculation
EL1C=0.01
     EL1D = free-stream velocity for jet-width calculation
EL1D=0.0
     EL1E = jet-discharge velocity ( mixing-length constant
            is switched from EL1A to EL1B, when centre-line
            velocity falls below EL1E )
EL1E=WINJ
 
  ** settings for the Local Reynolds Number Modification
IENUTA=6; ENUTA=0.2; ENUTB=4.0
 
    GROUP 11. Initialization of variable or porosity fields
PATCH(INITIAL,INIVAL,1,1,1,NY/5,1,NZ,1,1)
COVAL(INITIAL,W1,0.0,WINJ); COVAL(INITIAL,A,0.0,1.0)
FIINIT(ENUT)= 0.016*WINJ*JETDIAM
 
    GROUP 13. Boundary conditions and special sources
PATCH(IN,LOW,1,1,1,NY/5,1,1,1,1)
COVAL(IN,P1,FIXFLU,WINJ*RHO1); COVAL(IN,W1,ONLYMS,WINJ)
COVAL(IN,A,ONLYMS,1.0); COVAL(IN,V1,ONLYMS,0.0)
 
  ** the imposed velocity at the cylindrical wall
WALVEL=(0.32/8)*(winj*jetdiam/yvlast)*denrat**(-0.5)
PATCH(WALL,NORTH,1,1,NY,NY,1,NZ,1,1)
COVAL(WALL,P1,FIXFLU,RHO1*WALVEL); COVAL(WALL,W1,ONLYMS,0.0)
COVAL(WALL,A,ONLYMS,0.0)
 
PATCH(OUTLET,HIGH,1,1,1,4*NY/5,NZ,NZ,1,1)
COVAL(OUTLET,P1,1.E5,0.0); COVAL(OUTLET,A,ONLYMS,SAME)
COVAL(OUTLET,V1,ONLYMS,0.0); COVAL(OUTLET,W1,ONLYMS,0.0)
    GROUP 15. Termination of sweeps
LSWEEP=100; SELREF=T; RESFAC=0.01
    GROUP 17. Under-relaxation devices
RELAX(W1,FALSDT,0.001); RELAX(V1,FALSDT,0.1); RELAX(ENUT,LINRLX,0.5)
    GROUP 22. Spot-value print-out
NPRMON=20; IYMON=5
    GROUP 22. Spot-value print-out
IYMON=19; IZMON=10; TSTSWP=-1; itabl=1
    GROUP 23. Field print-out and plot control
NYPRIN=NY/10; NZPRIN=NZ/10; NPLT=1
PATCH(EXIT,PROFIL,1,1,1,NY,NZ-1,NZ-1,1,1)
PLOT(EXIT,W1,0.0,0.0); PLOT(EXIT,A,0.0,0.0)
PATCH(PIPE,CONTUR,1,1,1,NY,1,NZ,1,1)
PLOT(PIPE,W1,0.0,10.0); PLOT(PIPE,A,0.0,10.0)
 LIBREF=281
 **END OF LIBRARY CASE 281