READQ1_BEGIN
  DISPLAY
  The problem is similar to library case 110; but the heat
  loss is proportional to the fourth power of the temperature.
  This is effected by the "STAR-NAME" kind of PATCH in Group 13.
  READQ1_END
  ENDDIS
    GROUP 1. Run title and other preliminaries
TEXT(Transient Radiation From Fin     
TITLE
REAL(COEF,COND1,SPHT1); COND1=400.0; COEF=1.0E1; SPHT1=500.0
    GROUP 2. Transience; time-step specification
    ** The transient lasts for 20 seconds
STEADY=F; GRDPWR(T,10,20.0,1.0)
    GROUP 3. X-direction grid specification
    ** The fin length is 0.1 meters; grid is non-uniform
GRDPWR(X,20,0.1,2.0)
    GROUP 4. Y-direction grid specification
    ** The fin thickness is twice YVLAST
YVLAST=0.001
    GROUP 7. Variables stored, solved & named
SOLVE(TEMP)
    GROUP 8. Terms (in differential equations) & devices
    ** Built-in source and convection terms are cut out
TERMS(TEMP,N,N,Y,Y,P,P)
    GROUP 9. Properties of the medium (or media)
ENUL=1.0; RHO1=1.E4; PRNDTL(TEMP)=SPHT1*ENUL*RHO1/COND1
    GROUP 11. Initialization of variable or porosity fields
FIINIT(TEMP)=1.0
    GROUP 13. Boundary conditions and special sources
    ** Heat loss per unit area = coef * temp * temp**3.0
PATCH(*TEMP,FREEN,1,NX,1,1,1,1,1,LSTEP)
COVAL(*TEMP,TEMP,COEF,3.0)
    ** Fixed temperature at the fin root
WALL (ROOT,WEST,1,1,1,1,1,1,1,LSTEP)
COVAL(ROOT,TEMP,1.0/PRNDTL(TEMP),FIINIT(TEMP))
    GROUP 15. Termination of sweeps
    ** The non-linear heat-loss term entails necessitates use
    of more than one sweep at each time step.
LSWEEP=10
    GROUP 17. Under-relaxation devices
    ** Under-relaxation is needed to procure convergence
RELAX(TEMP,LINRLX,0.5)
    GROUP 19. Data communicated by satellite to GROUND
    ** GREX3 is used solely to print out the message at
    the top of the file, above "end". READQ1 effects this.
READQ1=T;USEGRD=F
SPEDAT(SET,GXMONI,TRANSIENT,L,F)
    GROUP 21. Print-out of variables
OUTPUT(TEMP,Y,Y,Y,Y,Y,Y)
    GROUP 22. Spot-value print-out
ITABL=1; TSTSWP=5;UWATCH=T
    GROUP 23. Field print-out and plot control
NXPRIN=NX/10; NTPRIN=LSTEP/2; ORSIZ=0.4
PATCH(FIXEDTIM,PROFIL,1,NX,1,1,1,1,1,LSTEP)
PLOT(FIXEDTIM,TEMP,0.0,1.0)
PATCH(FINTIP,PROFIL,NX,NX,1,1,1,1,1,LSTEP)
PLOT(FINTIP,TEMP,0.0,1.0)
    GROUP 24. Dumps for restarts