```

GROUP 1. Run title and other preliminaries

TEXT(Bingham Fluid_2D Ellip. Lam Pipe
TITLE

The problem concerns the steady laminar flow of a Bingham-plastic
non-Newtonian fluid in a pipe. This type of fluid remains rigid
when the shearing stress is less than the yield stress tauy and
flows somewhat like a Newtonian fluid when the shearing stress
exceeds tauy. For fully-developed flow the approximate analytical
solution for the pressure drop is given by:

dp/dz = 32.*rho*win**2*[1+Y/6]/Re/D

where D is the pipe diameter, win the mean velocity, Re the
Bingham Reynolds number, defined by:

Re = rho*win*D/n

and Y the yield number, defined by:

Y = D*tauy/(win*n)

The problem is solved by use of the 2d y-z elliptic solver for a
Reynolds number of 10 and a Yield number of 2.5. For these
conditions in fully developed flow, the expected pressure drop
and centre-line axial velocity are about 22 N/m**3 and 1.65m/s,
respectively. The PHOENICS predictions show fairly good
agreement with these results.

REAL(RIN,DIN,WIN,AIN,DPDZ);RIN=0.1;DIN=2.*RIN
WIN=1.0
GROUP 2. Transience; time-step specification
CARTES=F;XULAST=0.1
AIN=XULAST*RIN*RIN/2.
GROUP 4. Y-direction grid specification
NY=12;GRDPWR(Y,NY,RIN,-1.5)
GROUP 5. Z-direction grid specification
NZ=15;GRDPWR(Z,NZ,10.*RIN,1.9)
GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1);STORE(VISL,BTAU,GEN1)
SOLUTN(P1,Y,Y,Y,P,P,P)
GROUP 9. Properties of the medium (or media)
RHO1=1.0;ENUT=0.
REAL(REY,YIELDN);REY=10.;YIELDN=2.5
ENULA=DIN*WIN/(REY*RHO1)
ENULB=YIELDN*WIN*ENULA/DIN
ENUL=BINGHAM;GENK=T
DPDZ=32.*RHO1*WIN**2*(1.+YIELDN/6.)/REY/DIN
DPDZ
REY
YIELDN
GROUP 11. Initialization of variable or porosity fields
FIINIT(W1)=WIN
GROUP 13. Boundary conditions and special sources

PATCH(INLET,LOW,1,NX,1,NY,1,1,1,LSTEP)
COVAL(INLET,P1,FIXFLU,WIN*RHO1);COVAL(INLET,W1,ONLYMS,WIN)

PATCH(OUTL,HIGH,1,NX,1,NY,NZ,NZ,1,LSTEP)
COVAL(OUTL,P1,1.E2,0.0);COVAL(OUTL,W1,ONLYMS,SAME)

PATCH(WALL,NWALL,1,NX,NY,NY,1,NZ,1,LSTEP)
COVAL(WALL,W1,1.0,0.0)

GROUP 15. Termination of sweeps
LSWEEP=100
GROUP 16. Termination of iterations
RESREF(P1)=1.E-12*WIN*AIN
RESREF(W1)=RESREF(P1)*RHO1*WIN;RESREF(V1)=RESREF(W1)
GROUP 17. Under-relaxation devices
REAL(DTF);DTF=0.1*ZWLAST/WIN/NZ
RELAX(P1,LINRLX,1.0)
RELAX(W1,FALSDT,DTF);RELAX(V1,FALSDT,DTF)
RELAX(VISL,LINRLX,1.0)
GROUP 22. Spot-value print-out
IYMON=NY/2;IZMON=NZ/2;TSTSWP=-1
GROUP 23. Field print-out and plot control
NPLT=5;NYPRIN=1;NZPRIN=1
GROUP 24. Dumps for restarts
ENULA
ENULB
```