TALK=F;RUN(1,1)
#cls
text(In-Form Equivalent Of PLANT Case Z142
title
libref=742
  
  DISPLAY
  
  This In-Form case does what Z142 does, but without fortran coding
  or re-compilation.
  
  First, case z142 is loaded. Then NAMSAT = NONE is set, to 
  deactivate.

  It uses SOURCE In-Form statements.
  
  The Q1 contains PHOTON USE commands
  ENDDIS  
  PHOTON USE
  p
 
 
 
  set ve ref 20;ROT Y ANG 340
  gr ou y 4 z 15 16 col 11;gr ou z 17 y 1 3 col 11
  gr ou y 2 X 9 M z 7 9 col 11;gr ou z 10 y 1 1 col 11
  gr ou y 11 x 6 8 z 7 9 col 11;gr ou z 10 x 6 8 y 2 10 col 11
  GR OU X M Y 1 1 Z 7 9 col 11;GR OU X M Y 1 3 Z 15 16 col 11
  GR OU X 9 Y 2 10 Z 7 9 col 11
  GR OU x 1 1 y 1 1 z 8 9 col 11;rot y ang 355
  red
  msg                FLOW and DISPERSION NEAR TOWER BLOCK
  msg                           Geometry
  msg   Press Enter to continue
  PAUSE
  red
  msg                FLOW and DISPERSION NEAR TOWER BLOCK
  msg                NOx concentration at the road surface
  CON C1 y 1 z 10 14 fil;.001
  msg   Press Enter to continue
  PAUSE
  CON off;red
  set vec ref 40.
  VEc X 7 Z 1 1 sh
  VEc Y 1 sh
  msg                FLOW and DISPERSION NEAR TOWER BLOCK
  MSG                          Velocity field
  msg Press E to end
  ENDUSE

load(z142) 
text(In-Form equivalent of PLANT case Z142
libref=742

  INFORM13BEGIN
    ** The next line de-activates PLANT **
namsat=none
CARSO1=SKIP; CARSO2=SKIP
LSWEEP=250
RELAX(U1,FALSDT,2.)
RELAX(V1,FALSDT,2.)
RELAX(W1,FALSDT,2.)
RELAX(C1,FALSDT,100.)
  
     ** In-Form formulae which are equivalent to the
        PLANT formulae of z142                      **
PATCH(iCARSO1,CELL,1,NX,1,1,11,12,1,1)
(SOURCE of U1 at iCARSO1 is .3*1./2.*4.*10.*((20.-U1)^2$
+V1^2+W1^2)^0.5*(20.-U1))
(SOURCE of V1 at iCARSO1 is .3*1./2.*4.*10.*((20.-U1)^2$
+V1^2+W1^2)^0.5*(0.-V1))
(SOURCE of W1 at iCARSO1 is .3*1./2.*4.*10.*((20.-U1)^2$
+V1^2+W1^2)^0.5*(0.-W1))

PATCH(iCARSO2,CELL,1,NX,1,1,13,13,1,1)
(SOURCE of U1 at iCARSO2 is .3*1./2.*4.*10.*((-20.-U1)^2$
+V1^2+W1^2)^0.5*(-20.-U1))
(SOURCE of V1 at iCARSO2 is .3*1./2.*4.*10.*((-20.-U1)^2$
+V1^2+W1^2)^0.5*(0.-V1))
(SOURCE of W1 at iCARSO2 is .3*1./2.*4.*10.*((-20.-U1)^2$
+V1^2+W1^2)^0.5*(0.-W1))
  INFORM13END
DISTIL=T
EX(U1)=2.772E+00; EX(V1)=1.000E+00
EX(W1)=2.136E+01; EX(C1)=8.786E-02
STORE(PRPS)
EX(PRPS)=2.006E+01
EX(P1)=6.294E+01; EX(HPOR)=9.037E-01; EX(NPOR)=9.037E-01
EX(EPOR)=9.037E-01
STOP