DISPLAY
  
  This In-Form case does what Z101 does, but without fortran coding
  or re-compilation.
  
  First, case z101 is loaded. Then NAMSAT = NONE is set, to 
  deactivate. 

  Q1 uses the In-Form statements:
      PROPERTY, LONGNAME and STORED.

  The Q1 contains PHOTON USE commands
  ENDDIS  
load(z101) 
libref=760
namsat=none
rho1=1        ! these de-activate the rho1=grnd etc statements
enul=1        ! inserted by plant
prndtl(h1) =grnd2
text(In-Form Equivalent Of PLANT Case Z101
  Note: z101 uses the names visl and den1, which
        are not (yet) recognised as enul and rho1
name(visl)=enul
name(den1)=rho1
  Note: the following settings have been chosen as being
        preferable to those of z101, in respect of convergence 
        and printout
relax(u1,falsdt,1.0);relax(w1,falsdt,1.0)
nxprin=-1;nzprin=-1

  Note also that the PHOTON_USE commands which come with z101
  contain the names VISL and DEN1. These will need to be changed.
     
     ** In-Form property formulae which are equivalent to the
        PLANT formulae of z101                               **
  INFORM9BEGIN
(property var rho1 is POL3(t1,1.1386e3,1.0388,5.81149E-4$
,-6.7765E-7))
(LONGNAME of RHO1 is POL3(t1,1.1386e3,1.0388,5.81149E-4$
,-6.7765E-7))

(PROPERTY ENUL is EMU/RHO1)
(LONGNAME ENUL is EMU/RHO1)
(PROPERTY PRNDTL(H1) is EMU*CP/COND)
  INFORM9END
   ** Property correlations
     * Temperature
  INFORM7BEGIN
(STORED of T1 is H1/CP)
     * Heat capacity
(STORED of CP is 4186.8*(.616-.0040428*T1$
+1.8333e-5*T1^2-2.38E-08*T1^3))

     * Dynamic viscosity
(STORED of EMU is 4.1868E-04*(69.647-0.5278*T1$
+1.358e-3*T1^2-1.16E-06*T1^3))
     * Thermal conductivity
(STORED of COND is 1.163*(-0.1909+.003155*T1$
-1.0341e-5*T1^2+1.0666E-8*T1^3))
  INFORM7END
DISTIL=T
EX(P1)=1.163E-01; EX(U1)=1.163E-03; EX(W1)=2.308E-02
EX(H1)= 5.252E+05; EX(CP)=1.723E+03; EX(COND)=1.298E-01
EX(T1)=3.041E+02; EX(ENUL)=6.442E-07;  EX(RHO1)=1.489E+03
EX(EMU)=9.519E-04; EX(UCRT)=1.149E-03; EX(WCRT)=2.281E-02
libref=760
tstswp=1 
  PHOTON USE
  P;;;;

  gr ou y 1
  msg             Duct geometry
  msg  Press Enter to continue
  pause;  set vec ref .04;  red;  vec y 1 sh
  msg             Xylene velocity distribution, m/s
  msg Press ENTER to continue
  pause;  vec off;red;  con H1 y 1 fil;.000001
  msg             Enthalpy contours, J/kg
  msg Press ENTER to continue
  pause;  con off;red;  con T1 y 1 fil;.000001
  msg             Temperature contours, K
  msg Press ENTER to continue
  pause;  con off;red;  con rho1 y 1 fil;.000001
  msg             Density contours, kg/m^3
  msg Press ENTER to continue
  pause;  con off;red;  con EMU y 1 fil;.000001
  msg             Dynamic viscosity contours, N.s/m^2
  msg Press ENTER to continue
  pause;  con off;red;  con enul y 1 fil;.000001
  msg             Kinematic viscosity contours, m^2/s
  msg Press ENTER to continue
  pause;  con off;red;  con COND y 1 fil;.000001
  msg             Thermal conductivity contours, W/(m.K)
  msg Press ENTER to continue
  pause;  con off;red;  con CP y 1 fil;.000001
  msg             Heat capacity contours, J/(kg.K)
  msg Press E to finish
  ENDUSE
RELAX(P1,LINRLX,0.2)
STOP