TALK=F;RUN(1,1)
#cls
text(In-Form equivalent of PLANT case Z613
libref=779
title
  DISPLAY
  
  This case shows how In-Form can be used to compute relaxation
  factors (false time steps) as the flow-simulation calculation
  proceeds.
  
  The settings are the same as those used in PLANT library z613.

  It uses the In-Form functions:
      MAKE, STORE1 and SOURCE.
  
  Please inspect the bottom of the Q1 file so see how this is done.
  
  ENDDIS

load(z613) 
text(In-Form equivalent of PLANT case Z613
libref=779
     ** The next line de-activates PLANT **
namsat=none
COVAL(RELAX,U1,0,0)
COVAL(RELAX,V1,0,0)
COVAL(RELAX,W1,0,0)
  
     ** In-Form formulae which are equivalent to the
        PLANT formulae of z613                               **

  INFORM7BEGIN
    ** Global under-relaxation
(MAKE of PARAM)
PATCH(PATCH1,CELL,1,1,2,3,2,2,1,1)
(STORE1 of PARAM at PATCH1 is MIN(XULAST/NX,$
MIN(YVLAST/NY,ZWLAST/NZ))/MAX(U1,:FLO1:/2.))

(MAKE of REL)
PATCH(PATCH2,CELL,1,1,1,1,NZ,NZ,1,1)
(STORE1 of REL at PATCH2 is PARAM)

(STORE1 of DTFALS(U1) is REL with IF(ISWEEP.GT.100.AND.$
ISWEEP.LE.200))
(STORE1 of DTFALS(V1) is REL with IF(ISWEEP.GT.100.AND.$
ISWEEP.LE.200))
(STORE1 of DTFALS(W1) is REL with IF(ISWEEP.GT.100.AND.$
ISWEEP.LE.200))

  INFORM7END

  INFORM13BEGIN
    ** Local self-steering under-relaxation
(STORE1 of TFAL is 1./(SQRT(U1^2+W1^2+V1^2)/MIN(DXU,MIN(DYV,DZ$
))+:ENUL:/MIN(DXU,MIN(DYV,DZ))^2) with IF(ISWEEP.GE.200))
  
  !!!!! note the use of the IF condition !!!!!
PATCH(RELAXU,PHASEM,1,NX-1,1,NY,1,NZ,1,1)
(SOURCE of U1 at RELAXU is 1./TFAL*U1 with IF(ISWEEP.GT.200))
(SOURCE of U1 at RELAXU is -1./TFAL*U1 with LINE!$
IF(ISWEEP.GT.200))
PATCH(RELAXV,PHASEM,1,NX,1,NY-1,1,NZ,1,1)
(SOURCE of V1 at RELAXV is 1./TFAL*V1 with IF(ISWEEP.GT.200))
(SOURCE of V1 at RELAXV is -1./TFAL*V1 with LINE!$
IF(ISWEEP.GT.200))
PATCH(RELAXW,PHASEM,1,NX,1,NY,1,NZ-1,1,1)
(SOURCE of W1 at RELAXW is 1./TFAL*W1 with IF(ISWEEP.GT.200))
(SOURCE of W1 at RELAXW is -1./TFAL*W1 with LINE!$
IF(ISWEEP.GT.200))
  INFORM13END
DISTIL=T
EX(P1)=3.711E+02; EX(U1)=3.000E-01; EX(V1)=2.753E-02
EX(W1)=3.253E-01; EX(TFAL)=2.757E-03
EX(HPOR)=5.000E-01; EX(NPOR)=5.000E-01; EX(EPOR)=   5.000E-01
  PHOTON USE
  p;;;;;
 
  up 1 0 0;vi 0.5 1 0.75
  gr ou x 1;gr ou y 1;gr ou z 1
  gr ou x m;gr ou y m;gr ou z m
  gr ou x 1 y 1 2 z 2 2 col 2
  gr ou x 6 y 1 2 z 7 7 col 2
  gr ou z 4 x 1 4 y 1 3 col 6
  gr ou z 6 x 2 5 y 1 3 col 6
  ve y 2 sh
 
  msg                3D SHELL-AND-TUBE HEAT EXCHANGER
  msg                --------------------------------
  msg                        Velocity vectors
  ENDUSE
STOP