text(Valve Motion Into 2D chamber By In-Form
title
libref=784
DISPLAY
This In-Form case set moving In-Form object for simulation
the valve.
First four In-Form objects (1, 2, 3 and 4) describe
the geometry of blading sections of the chamber.
Two next In-Form objects (5 and 6) describe the geometry of a valve.
MARK is used by PHOTON for marks of borders of a paddle.
The Q1 uses the In-Form functions:
STORED, SOURCE and INFOB.
The Q1 contains PHOTON USE commands
ENDDIS
Group 1. Run Title
TEXT(Valve motion into 2D Chamber by In-Form)
Initial data of problem
-----------------------
*** Velocity of movement of a valve
REAL(VEL); VEL=1.
*** Whole throw of a valve
REAL(THROW); THROW=.03
*** X and Y coordinates of a valve in the first time step
REAL(XVAL,YVAL); XVAL=0.065; YVAL=0.035
*** X and Y coordinates of the valve holder in the first time step
REAL(DXH,DYH); DXH=0.0113; DYH=0.0252
*** Quantity of intervals of a time (should be odd)
LSTEP=9
*** Operating time of a valve
TLAST=THROW/VEL
Auxiliary data
--------------
*** PI number
REAL(PI); PI=3.14159
*** Rotation angle of In-Form figure relatively of Z axis
REAL(ANGL)
*** Moving of a valve during one time step
REAL(DMOV); DMOV=THROW/LSTEP
*** X and Y projections of valve moving during one time step
DMOV=DMOV/1.414
*** X and Y projections of valve velocity
REAL(UVEL,VVEL); UVEL=VEL/1.414; VVEL=VEL/1.414
*** Auxiliary integer variables
INTEGER(HLS,HLS1,HLS2); HLS=LSTEP/2; HLS1=HLS+1; HLS2=HLS+2
Group 2. Transience
STEADY=F; GRDPWR(T,LSTEP,TLAST,1.0)
GROUP 3. X-direction grid specification
GRDPWR(X,80,0.1,1.0)
GROUP 4. Y-direction grid specification
GRDPWR(Y,80,0.1,1.0)
GROUP 5. Z-direction grid specification
GRDPWR(Z,1,1.0,1.0)
Group 7. Variables: STOREd,SOLVEd,NAMEd
SOLVE(P1,U1,V1); STORE(VPOR,MARK)
Group 9. Properties
ENUL=0.0001
Group 11.Initialise Var/Porosity Fields
INIADD=F
FIINIT(VPOR)=1.; FIINIT(MARK)=0.
Group 13. Boundary & Special Sources
*** Description of free boundaries
PATCH(EAST,EAST,NX,NX,1,NY,1,NZ,1,LSTEP)
COVAL(EAST,P1,FIXP,0.0)
PATCH(WEST,WEST,1,1,1,NY,1,NZ,1,LSTEP)
COVAL(WEST,P1,FIXP,0.0)
PATCH(NORTH,NORTH,1,NX,NY,NY,1,NZ,1,LSTEP)
COVAL(NORTH,P1,FIXP,0.0)
PATCH(SOUTH,SOUTH,1,NX,1,1,1,NZ,1,LSTEP)
COVAL(SOUTH,P1,FIXP,0.0)
INFORM13BEGIN
In-Form statements
------------------
*** First block
PATCH(WHOLE,CELL,1,NX,1,NY,1,NZ,1,LSTEP)
(INFOB at WHOLE is BOX(0.,.07,0.,.04,.03,1.,0.,0.,0.$
) with INFOB_1)
(STORED of VPOR at WHOLE is 0. with INFOB_1)
*** Velocities zeroising
(SOURCE of U1 at WHOLE is 0. with INFOB_1!FIXV)
(SOURCE of V1 at WHOLE is 0. with INFOB_1!FIXV)
*** Second block
(INFOB at WHOLE is BOX(.07,0.,0.,.03,.04,1.,0.,0.,0.$
) with INFOB_2)
(STORED of VPOR at WHOLE is 0 with INFOB_2)
*** Velocities zeroising
(SOURCE of U1 at WHOLE is 0. with INFOB_2!FIXV)
(SOURCE of V1 at WHOLE is 0. with INFOB_2!FIXV)
*** Third block
ANGL=-PI/4
(INFOB at WHOLE is BOX(.04,.07,0.,.05,.03,1.,0.,0.,:ANGL:$
) with INFOB_3)
(STORED of VPOR at WHOLE is 0. with INFOB_3)
*** Velocities zeroising
(SOURCE of U1 at WHOLE is 0. with INFOB_3!FIXV)
(SOURCE of V1 at WHOLE is 0. with INFOB_3!FIXV)
*** Fourth block
ANGL=PI/4
(INFOB at WHOLE is BOX(.07,.04,0.,.03,.05,1.,0.,0.,:ANGL:$
) with INFOB_4)
(STORED of VPOR at WHOLE is 0. with INFOB_4)
*** Velocities zeroising
(SOURCE of U1 at WHOLE is 0. with INFOB_4!FIXV)
(SOURCE of V1 at WHOLE is 0. with INFOB_4!FIXV)
*** Formulas for account of X and Y coordinates of the valve position
CHAR(CXP,CYP)
CXP=:XVAL:-:DMOV:*(:HLS:-ABS(ISTEP-:HLS1:))
CYP=:YVAL:-:DMOV:*(:HLS:-ABS(ISTEP-:HLS1:))
*** Description of a geometry of a valve
ANGL=-PI/4
(INFOB at WHOLE is BOX(:CXP:,:CYP:,0.,.01,.042,1.,$
0.,0.,:ANGL:) with INFOB_5)
*** Description of a geometry of the valve holder
ANGL=PI/4
(INFOB at WHOLE is BOX(:CXP:-:DXH:,:CYP:+:DYH:,0.,.01,.11,1.,$
0.,0.,:ANGL:) with INFOB_6)
*** Formulas for account of X and Y velocities components of the valve
CHAR(UP,VP)
UP=(2*(ISTEP/:HLS2:-1)+1)*:UVEL:
VP=(2*(ISTEP/:HLS2:-1)+1)*:VVEL:
** Fixation of the valve velocities
(SOURCE of U1 at WHOLE is :UP: with INFOB_5!FIXV)
(SOURCE of V1 at WHOLE is :VP: with INFOB_5!FIXV)
(SOURCE of U1 at WHOLE is :UP: with INFOB_6!FIXV)
(SOURCE of V1 at WHOLE is :VP: with INFOB_6!FIXV)
*** MARK variable is used for the image of the valve position.
*** Initialization of MARK variable
(STORED of MARK at WHOLE is 0. with IF(ISWEEP.EQ.1))
*** Image of a geometry of the valve
(STORED of MARK at WHOLE is 1. with INFOB_5!IF(ISWEEP.EQ.1))
*** Image of a geometry of the valve holder
(STORED of MARK at WHOLE is 1. with INFOB_6!IF(ISWEEP.EQ.1))
INFORM13END
Group 15. Terminate Sweeps
LSWEEP=50; RESFAC=1.E-03; SELREF=F
Group 22. Monitor Print-Out
IXMON=NX/10+1; IYMON=NY/10+1; IZMON=1
TSTSWP=-1
Group 24. Dumps For Restarts
IDISPA=1; CSG1='P'
DISTIL=T
EX(P1)=1.081E+02; EX(U1)=3.112E-01; EX(V1)=3.117E-01;
EX(MARK)=1.055E-01; EX(VPOR)=6.731E-01
libref=784
PHOTON USE
p
p1;
gr ou z 1
ve z 1 sh
surf mark z .99
msg Time = 3.3E-3 sec.
msg Velocity vectors and pressure field
upause 2
p
p2;
gr ou z 1
ve z 1 sh
surf mark z .99
msg Time = 6.7E-3 sec.
msg Velocity vectors and pressure field
upause 2
p
p3;
gr ou z 1
ve z 1 sh
surf mark z .99
msg Time = 1.E-2 sec.
msg Velocity vectors and pressure field
upause 2
p
p4;
gr ou z 1
ve z 1 sh
surf mark z .99
msg Time = 1.3E-2 sec.
msg Velocity vectors and pressure field
upause 2
p
p5;
gr ou z 1
ve z 1 sh
surf mark z .99
msg Time = 1.7E-2 sec.
msg Velocity vectors and pressure field
upause 2
p
p6;
gr ou z 1
ve z 1 sh
surf mark z .99
msg Time = 2.E-2 sec.
msg Velocity vectors and pressure field
upause 2
p
p7;
gr ou z 1
ve z 1 sh
surf mark z .99
msg Time = 2.3E-2 sec.
msg Velocity vectors and pressure field
upause 2
p
p8;
gr ou z 1
ve z 1 sh
surf mark z .99
msg Time = 2.7E-2 sec.
msg Velocity vectors and pressure field
upause 2
p
p9;
gr ou z 1
ve z 1 sh
surf mark z .99
msg Time = 3.E-2 sec.
msg Velocity vectors and pressure field
ENDUSE