** LOAD(951) from the PHOENICS Input Library
TEXT(Couette Flow, Reynolds Number = 10.0     
TITLE
#cls
  DISPLAY
  
  This case illustrates the use of PIL to set up a "Couette flow",
  i.e. that which arises between extensive surfaces, separated by a
  constant distance, and sliding relative to one another. 
  
  The flow is laminar, and the flow has uniform properties.
  
  Four equations are solved, namely for velocity, W1, and for three
  scalar quantities A, B and C which are distinguished only by 
  having Prandtl Numbers of 1.0, 0.1 and 10.0 respectively.
  
  Each variable is given the value 0.0 at the lower (south) wall
  and the value 1.0 at the upper (north wall).
  
  The computed profiles are, of course, linear; and the only
  differences between the solutions for the four variables lie in
  the sources and sinks at the walls. These are largest in magnitude
  for C and smallest for B.
  ENDDIS
#pause
    GROUP 4. Y-direction grid specification
NY=20; GRDPWR(Y,NY,1.0,1.0)
    GROUP 7. Variables stored, solved & named
SOLVE(W1,A,B,C)
    GROUP 8. Terms (in differential equations) & devices
TERMS(W1,N,N,Y,Y,Y,Y)
TERMS(A,N,N,Y,Y,Y,Y); TERMS(B,N,N,Y,Y,Y,Y); TERMS(C,N,N,Y,Y,Y,Y)
    GROUP 9. Properties of the medium (or media)
RHO1=1.0; ENUL=0.1
PRNDTL(A)=1.0; PRNDTL(B)=0.1; PRNDTL(C)=10.0
    
    GROUP 13. Boundary conditions and special sources
PATCH(NORTH,NWALL,1,1,NY,NY,1,1,1,1)
COVAL(NORTH,W1,1.0,1.0); COVAL(NORTH,A,1.0,1.0)
COVAL(NORTH,B,1.0,1.0);  COVAL(NORTH,C,1.0,1.0)

PATCH(SOUTH,SWALL,1,1,1,1,1,1,1,1)
COVAL(SOUTH,W1,1.0,.0); COVAL(SOUTH,A,1.0,0.0)
COVAL(SOUTH,B,1.0,0.0); COVAL(SOUTH,C,1.0,0.0)


    GROUP 15. Termination of sweeps
LSWEEP=100
            
    GROUP 22. Monitor print-out
IYMON=NY/2
    GROUP 23. Field print-out and plot control
PATCH(Profiles,PROFIL,1,1,1,NY,NZ,NZ,1,1)
PLOT(Profiles,W1,0.0,1.0); PLOT(Profiles,A,0.0,1.0)
PLOT(Profiles,B,0.0,1.0);  PLOT(Profiles,C,0.0,1.0)

DISTIL=T
EX(W1)=0.5; EX(A)=0.5; EX(B)=0.5; EX(C)=0.5
LIBREF=951