AUTOPLOT USE
  file
  phi 5
 
 
  da 1 u2;screen;msg 2nd-phase velocity;pl 1
  msg press  to continue
  pause
  cl;screen;msg 2nd-phase volume fraction;da 1 r2;pl 1
  msg press  to continue
  pause
  cl
  msg press e to END
  enduse
 
TEXT(1D PARTICLE FLOW IN UNIFORM GAS STREAM
TITLE
  DISPLAY
  The case considered is the acceleration of particles by a uniform
  flowing gas stream. The flow is steady, one dimensional and it is
  assumed that there is no particle interaction. The analytical
  solution for this case has been given by Morsi and Alexander (JFM,
  Vol.55, p193, 1972). The free-stream velocity is not affected by
  the particles owing to their very low concentration. The density
  ratio is taken as 2000, the particle diameter as 500 microns, and
  the particle Reynolds number as 3,000. The calculation may be
  performed in the x-, y- or z-direction with phase 1 as carrier
  (gas) and phase 2 as dispersed (solid) or vice versa (CONPHS=2).
  ENDDIS
  The analytical solution does not provide an explicit expression
  for the particle velocity field as a function of distance, even
  when it is simplified, as in the present case, by presuming that
  the interphase drag coefficient is constant. Therefore, PHOENICS
  is validated by performing the calculation over a domain length
  computed analytically (2m) for a given value of the outlet
  particle velocity. The predicted particle outlet velocity compares
  very well with the value (3m/s) selected for the analytical
  calculation of the domain length.
 
  * CONPHS=1 selects 1st phase as the continuous ( gas ) phase
             and thus CFIPS=GRND7
  *       =2 selects 2nd phase as the continuous ( gas ) phase
             and thus CFIPS=GRND8
  * VARLAM=T tests coding in GXCFIP when ENUL is variable
  * VARDEN=T tests coding in GXCFIP when carrier RHO is variable
BOOLEAN(VARLAM,VARDEN);INTEGER(CONPHS);VARLAM=T;CONPHS=1;VARDEN=T
  * for 1dx calculation set: CH1=X;CH2=U1;CH3=U2
  * for 1dy calculation set: CH1=Y;CH2=V1;CH3=V2
  * for 1dz calculation set: CH1=Z;CH2=W1;CH3=W2
CHAR(CH1,CH2,CH3);CH1=X;CH2=U1;CH3=U2
   CH1=Y;CH2=V1;CH3=V2
   CH1=Z;CH2=W1;CH3=W2
REAL(XLEN,UGAS,UINP,UIN1,UIN2,R1IN,R2IN,REYP,DIAMP,DENRAT)
DIAMP=5.E-4;REYP=3000;XLEN=2.0;UGAS=5.0;UINP=1.0;DENRAT=2000.
  ** select uoutp and compute xlen
REAL(UOUTP,CD,VREL,ETA,AONE,TERM1,TERM2,FLOW1,FLOW2)
UOUTP=3.0;VREL=UGAS-UINP
CD=24.*(1.+.15*REYP**.687)/REYP+.42/(1.+4.25E4/(REYP**1.16))
AONE=3.*CD/(4.*DIAMP*DENRAT);TERM1=(UOUTP-UGAS)/(UINP-UGAS)
TERM1=(UOUTP-UGAS)/(UINP-UGAS)
TERM2=UGAS*(UINP-UOUTP)/((UOUTP-UGAS)*(UINP-UGAS))
XLEN=(LOG(TERM1)-TERM2)/AONE
reyp
cd
xlen
IF(CONPHS.EQ.1) THEN
+ UIN1=UGAS;UIN2=UINP;R2IN=1.E-5;R1IN=1-R2IN
ELSE
+ UIN1=UINP;UIN2=UGAS;R1IN=1.E-5;R2IN=1-R1IN
ENDIF
    GROUP 1. Run title and other preliminaries
    GROUP 2. Transience; time-step specification
    GROUP 3. X-direction grid specification
GRDPWR(:CH1:,-20,XLEN,1.4)
    GROUP 4. Y-direction grid specification
    GROUP 5. Z-direction grid specification
    GROUP 6. Body-fitted coordinates or grid distortion
    GROUP 7. Variables stored, solved & named
ONEPHS=F;SOLVE(P1,:CH2:,:CH3:,R1,R2)
  Activate storage for printout of interphase drag properties
STORE(REYN,VREL,CD,APRJ,CFIP,SIZE)
    GROUP 8. Terms (in differential equations) & devices
    GROUP 9. Properties of the medium (or media)
IF(CONPHS.EQ.1) THEN
+ RHO1=1.0;RHO2=DENRAT*RHO1
ELSE
+ RHO2=1.0;RHO1=DENRAT*RHO2
ENDIF
ENULA=VREL*DIAMP/REYP
IF(VARLAM) THEN
    Use ENUL=ENULA+ENULB*TMP1
+ STORE(TMP1);ENUL=LINTEM;ENULB=0.0;TMP1=CONST;TEMP0=273
ELSE
+ ENUL=ENULA
ENDIF
    GROUP 10. Inter-phase-transfer processes and properties
IF(CONPHS.EQ.1) THEN
+ CFIPS=GRND7
ELSE
+ CFIPS=GRND8
ENDIF
  ** CFIPA = minimum slip velocity  CFIPB = particle size
CFIPA=0.01;CFIPB=DIAMP
    GROUP 11. Initialization of variable or porosity fields
FIINIT(:CH2:)=UIN1;FIINIT(:CH3:)=UIN2
FIINIT(R1)=R1IN;FIINIT(R2)=R2IN
    GROUP 12. Unused
    GROUP 13. Boundary conditions and special sources
FLOW1=RHO1*UIN1*R1IN;FLOW2=RHO2*UIN2*R2IN
INLET(IN,CELL,$1,$1,$1,$1,$1,$1,1,1)
VALUE(IN,P1,FLOW1);VALUE(IN,:CH2:,UIN1)
VALUE(IN,P2,FLOW2);VALUE(IN,:CH3:,UIN2)
OUTLET(OUT,CELL,%1,%1,%1,%1,%1,%1,1,1)
  ** estimate particle outflow velocity, and then use value
     so as to allow for slip in exit cell outflow
UOUTP=3.0
IF(CONPHS.EQ.1) THEN
+ COVAL(OUT,P1,RHO1*1.E2,0);COVAL(OUT,P2,RHO2*1.E2*UOUTP/UIN1,0)
ELSE
+ COVAL(OUT,P1,RHO1*1.E2*UOUTP/UIN2,0);COVAL(OUT,P2,RHO2*1.E2,0)
ENDIF
    GROUP 15. Termination of sweeps
LSWEEP=60
RESREF(P1)=1.E-12*(FLOW1+FLOW2)
RESREF(R1)=1.E-12*FLOW1;RESREF(R2)=1.E-12*FLOW2
RESREF(:CH2:)=RESREF(R1)*UIN1;RESREF(:CH3:)=RESREF(R2)*UIN2
    GROUP 16. Termination of iterations
    GROUP 17. Under-relaxation devices
RELAX(R1,LINRLX,1.0);RELAX(R2,LINRLX,1.0)
    GROUP 18. Limits on variables or increments to them
    GROUP 19. Data communicated by satellite to GROUND
    GROUP 20. Preliminary print-out
    GROUP 21. Print-out of variables
NXPRIN=1;NYPRIN=1;NZPRIN=1
    GROUP 22. Spot-value print-out
IF(:CH1:.EQ.X) THEN
+ IXMON=NX/2;IZMON=1;IYMON=1
ELSE
+ IZMON=NZ/2;IXMON=1;IYMON=1
ENDIF
IF(:CH1:.EQ.Y) THEN
+ IYMON=NY/2;IXMON=1;IZMON=1
ENDIF
TSTSWP=-1
    GROUP 23. Field print-out and plot control
    GROUP 24. Dumps for restarts
IF(VARDEN) THEN
IF(CONPHS.EQ.1) THEN
+ RHO1A=RHO1;RHO1B=0.0;RHO1=LINTEMP
ELSE
+ STORE(TMP2);TMP2=CONST;RHO2A=RHO2;RHO2B=0.0;RHO2=LINTEMP
ENDIF
ENDIF