TEXT(1D GAS-PARTICLE FLOW WITH HEAT TRANSFER
TITLE
    The problem considered is one-dimensional, steady 2-phase
    flow of gas and particles with interphase momentum and heat
    transfer represented through the dispersed solid-sphere
    interphase transfer laws. The continuous phase ( gas ) enters
    at a lower temperture than the dispersed phase ( solid ), and
    calculations may be performed with either constant and equal
    specific heats for each phase, or constant and different
    specific heats.
 
    If CONPHS=1 phase 1 is taken as the continuous phase, but
    if CONPHS=2 phase 2 is taken as the continuous phase in
    PHOENICS. For calculations with equal specific heats, CONPHS
    may be set to either 1 or 2. However, for different specific
    heats, CONPHS must be set equal to 1, as PHOENICS does not
    support phase 2 as the continuous phase under these conditions.
 
INTEGER(CONPHS);CONPHS=1;REAL(CPH1,CPH2)
    GROUP 1. Run title and other preliminaries
    GROUP 2. Transience; time-step specification
    GROUP 3. X-direction grid specification
GRDPWR(X,10,1,1)
    GROUP 4. Y-direction grid specification
    GROUP 5. Z-direction grid specification
    GROUP 6. Body-fitted coordinates or grid distortion
    GROUP 7. Variables stored, solved & named
ONEPHS=F;SOLVE(P1,U1,U2,R1,R2,H1,H2)
STORE(NUSS,REYN,VREL,CD,APRJ,CFIP)
    GROUP 8. Terms (in differential equations) & devices
TERMS(H1,N,Y,Y,N,Y,Y);TERMS(H2,N,Y,Y,N,N,Y);DIFCUT=0.0
    GROUP 9. Properties of the medium (or media)
ENUL=1.E-3;STORE(TMP1,TMP2);TMP1=LINH;TMP2=LINH
  ** set continuous-phase diffusivity via PRNDTL(H1)=-GRND1,
     STORE(PRL) and FIINIT(PRL)=ENUL/(laminar prandtl number)
STORE(PRL);FIINIT(PRL)=ENUL/0.7
IF(CONPHS.EQ.1) then
+ PRNDTL(H1)=-GRND1;RHO1=2;RHO2=1500;CPH1=1.E3;CP1=CPH1
+ CPH2=2.E3;CP2=CPH2
ELSE
+ PRNDTL(H2)=-GRND1;RHO1=1500;RHO2=2;CPH1=2.E3;CP1=CPH1
+ CPH2=1.E3;CP2=CPH2
ENDIF
    GROUP 10. Inter-phase-transfer processes and properties
  ** activate dispersed solid-sphere interphase momentum and
     heat-transfer correlations
CFIPA=0.01;CFIPB=1.E-3;STORE(SIZE)
IF(CONPHS.EQ.1) then
+ CFIPS=GRND7;CINT(H1)=GRND7;CINT(H2)=1E15
  ** activate the following line for different specific heats
+ PHINT(H1)=CPH1/CPH2
ELSE
+ CFIPS=GRND8;CINT(H2)=GRND7;CINT(H1)=1E15
ENDIF
    GROUP 11. Initialization of variable or porosity fields
    GROUP 12. Unused
    GROUP 13. Boundary conditions and special sources
REAL(UIN1,UIN2,R1IN,R2IN,H1IN,H2IN,TCIN,TDIN)
TCIN=1.0;TDIN=1.E3
IF(CONPHS.EQ.1) then
+ UIN1=20;UIN2=2;R2IN=1.E-3;R1IN=1-R2IN
+ H1IN=CPH1*TCIN;H2IN=CPH2*TDIN
ELSE
+ UIN2=20;UIN1=2;R1IN=1.E-3;R2IN=1-R1IN
+ H1IN=CPH1*TDIN;H2IN=CPH2*TCIN
ENDIF
FIINIT(R1)=R1IN;FIINIT(R2)=R2IN
INLET(IN,WEST,1,1,1,1,1,1,1,1)
VALUE(IN,P1,RHO1*UIN1*R1IN)
VALUE(IN,U1,UIN1);VALUE(IN,H1,H1IN)
VALUE(IN,P2,RHO2*UIN2*R2IN)
VALUE(IN,U2,UIN2);VALUE(IN,H2,H2IN)
OUTLET(OUT,EAST,NX,NX,1,1,1,1,1,1)
IF(CONPHS.EQ.1) then
+ COVAL(OUT,P1,1E3,0);COVAL(OUT,P2,RHO2/(2*RHO1)*1E3,0)
ELSE
+ COVAL(OUT,P2,1E3,0);COVAL(OUT,P1,RHO1/(2*RHO2)*1E3,0)
ENDIF
    GROUP 15. Termination of sweeps
LSWEEP=30
    GROUP 16. Termination of iterations
    GROUP 17. Under-relaxation devices
RELAX(R1,LINRLX,1);RELAX(R2,LINRLX,1)
    GROUP 18. Limits on variables or increments to them
    GROUP 19. Data communicated by satellite to GROUND
    GROUP 20. Preliminary print-out
    GROUP 21. Print-out of variables
NXPRIN=1
    GROUP 22. Spot-value print-out
IXMON=NX/2;TSTSWP=-1;DISTIL=T
EX(P1  )=1.269E+01;EX(U1  )=1.998E+01;EX(U2  )=1.462E+01
EX(R1  )=9.998E-01;EX(R2  )=1.514E-04;EX(H1  )=7.244E+04
EX(H2  )=1.048E+06;EX(SIZE)=1.000E-03;EX(PRL )=1.429E-03
EX(TMP2)=5.242E+02;EX(TMP1)=7.244E+01;EX(CFIP)=8.218E-01
EX(APRJ)=2.270E-01;EX(CD  )=8.201E+00;EX(VREL)=5.584E+00
EX(REYN)=5.584E+00;EX(NUSS)=2.884E+00
    GROUP 23. Field print-out and plot control
    GROUP 24. Dumps for restarts