GROUP 1. Run title and other preliminaries
TEXT(2D 2-PHASE TRONDHEIM BUBBLE COLUMN
TITLE
  DISPLAY
    The case considered is 2-phase turbulent air-water flow in
    the bubble column studied by Svendsen et al ( Chem.Eng.Sci.,
    Vol.47, No.13, p3297, 1992 ). The column is 4.25m high and
    0.288m in diameter. The air and liquid enter uniformly at the
    base of the column with an inlet superficial velocities of
    0.08m/s and 0.01m/s for the air and liquid, respectively. Both
    phases leave at the top of the column. The experimental data
    reveal clockwise liquid circulation, with upflow at the column
    centre and downflow at the outer wall. The inlet void fraction
    is taken as 0.2, and the two-phase model accounts for
    interfacial drag, lift and virtual-mass forces. The calculation
    may be performed with either the Petersen SGS turbulence model,
    the Rice-Geary model, or a modified k-e model which accounts for
    bubble-induced turbulence production.
  ENDDIS
  PHOTON USE
    P
 
  10 1
   0.20443E+04 0.15633E+04 CR
  UP Z
  CON R2 X 1 FI;.1
  VEC X 1 SH
  ENDUSE
REAL(DIAMC,RADC,ZLENT,PI,GRAVAC,STEN,DTT,AREA,WSLIQ,FLOWL)
REAL(DIAMB,DTF,WSGAS,FLOWG,VSLIPM,EMULIQ,RGAS,RLIQ,RGINIT)
INTEGER(TMODEL);REAL(TKEIN,EPIN);BOOLEAN(LIFT,VMAS);CHAR(CTURB)
LIFT=T;VMAS=T
MESG( Enter the required turbulence model:
MESG(  SGS   - Petersen subgrid-scale model
MESG(  RICE  - Rice-Geary mixing-length model
MESG(  KE    - k-e model (default)
READVDU(CTURB,CHAR,KE)
DIAMC=0.288;RADC=0.5*DIAMC;ZLENT=4.25;RGAS=0.2;RLIQ=1.-RGAS
PI=3.14159;GRAVAC=-9.81;STEN=0.072;EMULIQ=1.E-3;RGINIT=1.E-4
WSGAS=0.08;WSLIQ=0.01;DIAMB=10.0E-3
TKEIN=(0.1*WSLIQ)**2;EPIN=0.1643*TKEIN**1.5/(0.1*RADC)
    GROUP 2. Transience; time-step specification
    GROUP 3. X-direction grid specification
CARTES=F;XULAST=0.1;AREA=XULAST*0.5*RADC*RADC
    GROUP 4. Y-direction grid specification
NY=15;GRDPWR(Y,NY,RADC,1.0)
    GROUP 5. Z-direction grid specification
NZ=30;GRDPWR(Z,-NZ,ZLENT,1.4)
    GROUP 6. Body-fitted coordinates or grid distortion
    GROUP 7. Variables stored, solved & named
ONEPHS=F;SOLVE(P1,V1,V2,W1,W2,R1,R2)
SOLUTN(P1,Y,Y,Y,P,P,P)
  ** deactivate harmonic averaging
SOLUTN(V1,P,P,P,P,P,N);SOLUTN(V2,P,P,P,P,P,N)
SOLUTN(W1,P,P,P,P,P,N);SOLUTN(W2,P,P,P,P,P,N)
SOLUTN(R1,P,P,P,P,P,N);SOLUTN(R2,P,P,P,P,P,N)
STORE(VREL,CFIP,ENUT,LEN1,CD,REYN,WEB)
    GROUP 8. Terms (in differential equations) & devices
DIFCUT=0.5
    GROUP 9. Properties of the medium (or media)
RHO1=1.E3;RHO2=1.0
CASE :CTURB: OF
WHEN SGS,3
+ MESG(Petersen sgs turbulence model
+ TURMOD(SGSMOD);TMODEL=1
+ TEXT(TRONDHEIM BUBBLE COLUMN- SGS turb.
   ! Switch to older, more stable grid filter based on
   ! sqrt(dx^2+dy^2+dz^2)/3. Default filter is vol^(1/3)
+ EL1A=-EL1A
WHEN RICE,4
+ MESG(Rice-Geary mixing-length turbulence model
+ TURMOD(MIXLEN-RICE);TMODEL=2
+ TEXT(TRONDHEIM BUBBLE COLUMN- Rice-Geary turb.
WHEN KE,2
+ MESG(k-e turbulence model
+ TURMOD(KEMODL);TMODEL=3;FIINIT(KE)=TKEIN;FIINIT(EP)=EPIN
+ PRT(R1)=1.5;PRT(R2)=1.5
+ TEXT(TRONDHEIM BUBBLE COLUMN- K-E turb.
ENDCASE
ENUL=EMULIQ/RHO1
    GROUP 10. Inter-phase-transfer processes and properties
CFIPS=GRND7
CFIPD=4.0;VSLIPM=1.E-4;CFIPA=VSLIPM;CFIPB=DIAMB;CFIPC=STEN
RLOLIM=1.E-3
IF(VMAS) THEN
+ CVM=0.5;STORE(VMSV,VMSW)
+ OUTPUT(VMSW,N,P,Y,P,Y,P);OUTPUT(VMSV,N,P,Y,P,Y,P)
ENDIF
IF(LIFT) THEN
+ CLIFT=-0.5;INTSOR(LIFT,CLIFT,RELAX,0.1)
+ OUTPUT(LISW,N,P,P,P,Y,P);OUTPUT(LISV,N,P,P,P,Y,P)
ENDIF
    GROUP 11. Initialization of variable or porosity fields
FIINIT(R1)=RLIQ;FIINIT(R2)=RGAS;FIINIT(W1)=WSLIQ/RLIQ
FIINIT(W2)=WSGAS/RGAS;FIINIT(V1)=0.1
   FIINIT(W2)=0.6;FIINIT(W1)=0.6
    GROUP 12. Patchwise adjustment of terms
    GROUP 13. Boundary conditions and special sources
FLOWL=RHO1*WSLIQ
   ** Liquid inlet boundary condition
PATCH(INL,LOW,1,NX,1,NY,1,1,1,LSTEP)
COVAL(INL,P1,FIXFLU,FLOWL);COVAL(INL,W1,ONLYMS,WSLIQ/RLIQ)
IF(TMODEL.EQ.3) THEN
+ COVAL(INL,KE,ONLYMS,TKEIN);COVAL(INL,EP,ONLYMS,EPIN)
ENDIF
FLOWG=RHO2*WSGAS
   ** Gas inlet boundary condition
PATCH(ING,LOW,1,NX,1,NY,1,1,1,LSTEP)
COVAL(ING,P2,FIXFLU,FLOWG);COVAL(ING,W2,ONLYMS,WSGAS/RGAS)
   ** Gas outlet boundary condition
PATCH(OUTG,HIGH,1,NX,1,NY,NZ,NZ,1,LSTEP)
COVAL(OUTG,P2,RHO2*1.E4,0.0)
   ** Liquid outlet boundary condition
PATCH(OUTL,HIGH,1,NX,1,NY,NZ,NZ,1,LSTEP)
COVAL(OUTL,P1,RHO1*1.E4,0.0)
 
PATCH(GRAVITY,PHASEM,1,NX,1,NY,1,NZ,1,LSTEP)
COVAL(GRAVITY,W2,FIXFLU,GRAVAC*(1.-RHO1/RHO2))
 
WALL(NWALL,NORTH,1,NX,NY,NY,1,NZ,1,LSTEP)
COVAL(NWALL,W2,1.0,0.0)
  ** Bubble-induced turbulence production
IF(TMODEL.EQ.3) THEN
+ KELIN=1
+ PATCH(KEDI,CELL,1,NX,1,NY,1,NZ,1,LSTEP);EL1A=0.1
+ COVAL(KEDI,KE,FIXFLU,GRND3);COVAL(KEDI,EP,FIXFLU,GRND3)
ENDIF
    GROUP 15. Termination of sweeps
   ** 3000 sweeps are required for a converged solution
LSWEEP=1250;TSTSWP=-10
    GROUP 16. Termination of iterations
SELREF=T;RESFAC=0.01
    GROUP 17. Under-relaxation devices
DTF=7.E-3
RELAX(P1,LINRLX,0.5)
RELAX(V1,FALSDT,DTF);RELAX(V2,FALSDT,DTF)
RELAX(W1,FALSDT,DTF);RELAX(W2,FALSDT,DTF)
RELAX(R1,LINRLX,0.3);RELAX(R2,LINRLX,0.3)
RELAX(CFIP,LINRLX,0.3)
IF(TMODEL.EQ.3) THEN
+ RELAX(KE,LINRLX,0.3);RELAX(EP,LINRLX,0.3)
ENDIF
    GROUP 18. Limits on variables or increments to them
VARMIN(R1)=1.E-6;VARMIN(R2)=1.E-6
    GROUP 19. Data communicated by satellite to GROUND
    GROUP 20. Preliminary print-out
    GROUP 21. Print-out of variables
OUTPUT(LEN1,N,N,N,N,N,N);OUTPUT(WEB,N,N,N,N,N,N)
OUTPUT(CD,N,N,N,N,N,N);OUTPUT(REYN,N,N,N,N,N,N)
OUTPUT(CFIP,Y,N,N,N,N,N)
    GROUP 22. Spot-value print-out
IYMON=2;IZMON=28
    GROUP 23. Field print-out and plot control
NPRINT=LSWEEP;NZPRIN=2;NYPRIN=2;NPLT=50;ITABL=3
WALPRN=T
    GROUP 24. Dumps for restarts