PHOTON USE
  p
  phi;;;;;
 
  set con fi dep 3
  con yo2 x 1 fi;0.05
  gr ou x 1
  gr ou x 1 y 25 32 z 1 5
  te
  1
 
  oxygen mass-fraction contours
   0.13265E+04 0.19215E+04 CR
  msg Press  to continue
  pause
  cl
  con fue x 1 fi;0.05
  gr ou x 1
  gr ou x 1 y 25 32 z 1 5
  te
  1
 
  contours of volume fraction of solid
   0.13265E+04 0.21215E+04 CR
  msg Press  to continue
  pause
  cl
  con yco2 x 1 fi;0.05
  gr ou x 1
  gr ou x 1 y 25 32 z 1 5
  te
  1
 
  carbon dioxide contours
   0.13265E+04 0.21215E+04 CR
  msg Press  to continue
  pause
  cl
  con tmp1 x 1 fi;0.05
  gr ou x 1
  gr ou x 1 y 25 32 z 1 5
  te
  1
 
  gas temperature contours
   0.13265E+04 0.23215E+04 CR
  msg Press  to continue
  pause
  cl
  con tmp2 x 1 fi;0.05
  gr ou x 1
  gr ou x 1 y 25 32 z 1 5
  te
  1
 
  coal temperature contours
   0.13265E+04 0.23215E+04 CR
  msg Press  to continue
  pause
  cl
  con mixf x 1 fi;0.05
  gr ou x 1
  gr ou x 1 y 25 32 z 1 5
  te
  1
 
  mixture fraction contours
   0.13265E+04 0.23215E+04 CR
  msg Press  to continue
  pause
  enduse
    GROUP 1. Run title and other preliminaries
TEXT(2-D Coal Combustion With NOX      
TITLE
  DISPLAY
   The case considered is the 2d turbulent flow of combusting
   pulverised coal particles in the near-field region of a
   power-station burner. The burner comprises 3 air streams,
   tertiary air enters through a central air stream, swirling
   primary air carrying coal particles enters through an inner
   annulus located above the tertiary-air stream, and swirling
   secondary air enters through an outer annulus located above the
   primary air stream. The main combustion process is simulated
   using an IPSA-based 'equilibrium' two-phase combustion model. A
   2nd post-processing run can be performed which computes thermal
   NOx based on CHO equilibrium as determined by the CREK module.
   ===================================================
   Coal-combustion model; solid phase - carbon only
   reactions: C (s) + 0.5 O2  > CO       (exothermic )
            CO    + 0.5 O2  > CO2      (exothermic )
            C(s)  + CO2     > 2CO      (endothermic)
            C(s)  + H2O     > CO  + H2 (endothermic)
            H2    + 0.5 O2  > H2O      (exothermic )
   ===================================================
  ENDDIS
   In this Q1 the suffices 1,2,3 refer to primary,
   secondary, tertiary respectively  -  except for
   radii (rin) and areas (ain) where they refer to
   the inner, middle and outer annuli.
  **
  noxdbegin
    ns   7
    nr   3
  noxdend
  **
  ** control variables
BOOLEAN(NOXCAL,THRAD)
  ** definition of variables
REAL (PI,AIN1,AIN2,AIN3,CONV1,CONV2,CONV3,CONV4)
REAL (DTF)
REAL (ROGIN1,ROGIN2,ROGIN3)
REAL (RIN1, RIN2, RIN3, ROUT, ZLEN, ZQUARL)
REAL (FGIN1, FGIN2, FGIN3, WGIN1, WGIN2, WGIN3, FGINT)
REAL (FVIN1, FVIN2, FVIN3)
REAL (FCOAL,WSIN,ROCOAL,FMCOAL,ROMEAN,GABSR)
REAL (TSIN,TGIN1,TGIN2,TGIN3)
REAL (HSIN,HGIN1,HGIN2,HGIN3)
REAL (OMEGAS,OMEGA1,OMEGA2,OMEGA3)
REAL (TKEIN1,TKEIN2,TKEIN3,EPIN1,EPIN2,EPIN3,DIST1,DIST2,DIST3)
REAL (OUTCO1, GFS)
REAL (HCCO2,HCCO,HHH2O,HCHX)
REAL (CMOL,HMOL,NMOL,OMOL,O2MOL,N2MOL,CH4MOL,H2OMOL,COMOL,CO2MOL)
REAL (NOMOL,OHMOL,OXMOL,H2MOL)
CHAR (ANS2)
       ===========================================================
  ***  Note that SI units are used throughout the calculation  ***
       ===========================================================
  ** conversion factors
PI=3.14159
  -- inches to metres
CONV1=0.0254
  -- pounds to kilograms
CONV2=0.4536
  -- feet to metres
CONV3=CONV1*12.
  -- cu.ft to cu.m
CONV4=CONV3**3
  ** inlet diameters  -  inches
  -- diameter of innermost inlet tube
RIN1= 16.
  -- outer diameter of middle inlet annulus
RIN2= 26.
  -- outer diameter of outer secondary air annulus
RIN3= 53.
  -- quarl depth from inlet plane to furnace wall  -  inches
ZQUARL= 11.313
  -- outer radius of 2-D solution domain  -  m
ROUT=1.
  -- axial length of solution domain  -  m
ZLEN=5.
  -- radii, converted to SI units
RIN1= RIN1*CONV1/2.; RIN2=RIN2*CONV1/2.; RIN3=RIN3*CONV1/2.
ZQUARL=ZQUARL*CONV1
  ** inlet flow areas
AIN1=PI*RIN1*RIN1; AIN2=PI*RIN2*RIN2-AIN1;
AIN3=PI*RIN3*RIN3-AIN2-AIN1
  ** length scales for inlet epsilon
DIST1=(RIN2-RIN1)/10.; DIST2=(RIN3-RIN2)/10.; DIST3=RIN1/10.
  ** inlet mass flow rates  -  lb/s
  -- primary air
FGIN1= 10.48
  -- secondary air
FGIN2= 44.47
  -- tertiary air
FGIN3= 7.97
  ** inlet parameters for coal
  -- coal mass flow rate  -  lb/s
FCOAL= 5.97
  -- velocity of coal particles  -  ft/s
WSIN= 70.06
  -- coal density  -  kg/(m**3)
ROCOAL=1350.
  -- mass-fractions of carbon and hydrogen in coal
REAL(CINCL,HINCL); CINCL=0.95;HINCL=0.05
  -- convert velocity to SI
WSIN=WSIN*CONV3
  -- total gas inlet mass flow rate  -  kg/s
FGINT= (FGIN1+FGIN2+FGIN3)*CONV2
  -- convert inflows to mass flow per unit area in SI units.
     remember - primary is ain2, secondary ain3, tertiary ain1.
FGIN1=FGIN1*CONV2/AIN2; FGIN2=FGIN2*CONV2/AIN3
FGIN3=FGIN3*CONV2/AIN1; FMCOAL=FCOAL*CONV2; FCOAL=FMCOAL/AIN2
  == NOTE: fmcoal is kg/s, fcoal is kg/(m**2.s)
  ** inlet volume flows  -  ft**3/s
  -- primary air
FVIN1=160.5
  -- secondary air
FVIN2=1071.5
  -- tertiary air
FVIN3=192.1
  -- convert to m**3/s
FVIN1=FVIN1*CONV4; FVIN2=FVIN2*CONV4;FVIN3=FVIN3*CONV4
  -- mean inlet density  -  kg/m**3
ROMEAN=FGINT/(FVIN1+FVIN2+FVIN3)
  -- calculate inlet velocities  -  m/s
WGIN1=FVIN1/AIN2; WGIN2=FVIN2/AIN3; WGIN3=FVIN3/AIN1
  ** angular velocities at inlet  -  radians/sec
  ** solid-body rotation assumed
  -- coal
OMEGAS= 10.
  -- primary air
OMEGA1= 10.
  -- secondary air
OMEGA2= 10.
  -- tertiary air
OMEGA3= 0.
  ** inlet temperatures  -  deg F
  -- coal
TSIN = 150.
  -- primary air
TGIN1= 150.
  -- secondary air
TGIN2= 500.
  -- tertiary air
TGIN3= 500.
  -- convert to deg K
TGIN1=273.+(TGIN1-32.)*5./9.;TGIN2=273.+(TGIN2-32.)*5./9.
TGIN3=273.+(TGIN3-32.)*5./9.;TSIN =273.+(TSIN -32.)*5./9.
  -- inlet conditions for turbulence - assume 5% intensity
TKEIN1=0.0025*WGIN1*WGIN1;TKEIN2=0.0025*WGIN2*WGIN2
TKEIN3=0.0025*WGIN3*WGIN3
EPIN1=0.1643*TKEIN1**1.5/DIST1; EPIN2=0.1643*TKEIN2**1.5/DIST2
EPIN3=0.1643*TKEIN3**1.5/DIST3
  ** Molecular masses in kg/kg-mol
CMOL = 12.01115;HMOL =  1.00797;NMOL = 14.0067; OMOL = 15.9994
CH4MOL= CMOL+4.0*HMOL
O2MOL = 2.0*OMOL;N2MOL = 2.0*NMOL
H2OMOL= 2.0*HMOL+OMOL; COMOL = CMOL+OMOL
CO2MOL= 2.0*OMOL+CMOL;NOMOL = NMOL+OMOL
OHMOL = OMOL+HMOL;H2MOL = 2.0*HMOL
  -- Do not alter the above settings.  Change NOXCAL
  -- to T to perform a NOx post-processing run; this
  -- is the only change needed.
CHAR(NOXC)
MESG(
MESG(Main combustion calculation (M) or NOX Post-processing (P)
MESG(  (Default  =  M)
READVDU(NOXC,CHAR,M)
IF(:NOXC:.EQ.P)THEN
TEXT(NOX Post-processing calculation   : C110
+NOXCAL=T
ELSE
+NOXCAL=F
ENDIF
    ===================================
    START OF GROUP-BY-GROUP Q1 SETTINGS
    ===================================
    GROUP 3. X-direction grid specification
CARTES=F; XULAST=0.01
    GROUP 4. Y-direction grid specification
NREGY=4
IREGY=1; GRDPWR(Y,6,RIN1,-1.2)
IREGY=2; GRDPWR(Y,8,RIN2-RIN1,1.)
IREGY=3; GRDPWR(Y,10,RIN3-RIN2,1.2)
IREGY=4; GRDPWR(Y,8,ROUT-RIN3,1.2)
    GROUP 5. Z-direction grid specification
NREGZ=2
IREGZ=1; GRDPWR(Z,5,ZQUARL,1.)
IREGZ=2; GRDPWR(Z,20,ZLEN,1.7)
    GROUP 7. Variables stored, solved & named
  ** Solve for one pressure, two velocities, the volume
     fractions of the 2 phases and the "shadow" volume
     fraction of the second (denser) phase.
ONEPHS=F; SOLVE(P1,W1,W2,R1,R2,RS)
NAME(R1)=GAS;NAME(R2)=FUE;NAME(RS)=SHAD
SOLVE(V1,V2); SOLVE(U1,U2)
SOLUTN(P1,Y,Y,Y,P,P,P)
  ** Provide storage for inter-phase mass transfer.
STORE(MDOT,CFIP)
STORE(YO2,YCO,YCO2,YN2,YH2,YH2O)
  ** store temperature and density
STORE(TMP1,TMP2,RHO1); OUTPUT(RHO1,Y,Y,Y,Y,Y,Y)
  ** enthalpy
SOLVE(H1,H2)
  ** Solve additionally for the mixture fraction, i.e. the quantity
     of phase-2 material which has entered phase 1.
SOLVE(C1,C2); NAME(C1)=MIXF
STORE(ENUT)
  -- NOX solution
IF(NOXCAL) THEN
+ STORE(P1,U1,U2,V1,V2,W1,W2,GAS,FUE,SHAD,H1,H2,MIXF,C2,KE,EP)
+ SOLVE(C3,C5); STORE(C4,C6); NAME(C3)=XN; NAME(C5)=XNO
+ STORE(XO,XO2,XH,XOH,CRKT,PRDT,NOSR,EQUI,DEGF)
+ CINT(XNO)=0.0; CINT(XN)=0.0; CINT(C4)=0.0; CINT(C6)=0.0
+ SOLUTN(XN  ,Y,Y,Y,N,N,N);SOLUTN(XNO ,Y,Y,N,N,N,N)
ENDIF
TERMS(H1,N,P,P,P,P,P);TERMS(H2,N,P,P,P,P,P)
 
IF(NOXCAL) THEN
+ THRAD=F
ELSE
+ MESG( Thermal radiation required ? (default=Y)
+ READVDU(ANS2,CHAR,Y)
IF(:ANS2:.EQ.Y) THEN
+ THRAD=T
ELSE
+ THRAD=F
ENDIF
IF(THRAD) THEN
+ REAL(ABSORB,SCAT,SIGMA,EMPW,EMISW,EMISG,EMPG,TWAL)
+ ABSORB=0.5;SCAT=0.02; EMISG=0.07
+ SIGMA=5.6697E-8; EMISW=1.0;TWAL=680.
+ EMPW=SIGMA*TWAL**4; EMPG=SIGMA*EMISG
+ RADIAT(FLUX,ABSORB,SCAT,H1)
+ SOLUTN(RADZ,P,P,y,P,P,P)
+ SOLUTN(H2,P,P,y,P,P,P)
ENDIF
ENDIF
    GROUP 9. Properties of the medium (or media)
  ** densities and temperatures
  -- take cpsolid=cpgas=1.1e3
CP1=1.1E3; CP2=1.1E3
  ** rho1=grnd7 activates computation of rho1, tmp1, tmp2
          and gas-phase composition in rho section of gxprop.for
RHO1=GRND7
RHO2=ROCOAL; PRESS0=1.E5; TEMP0=0.
RHO1A=CINCL ; RHO1B=1.0-CINCL
  -- evaluate inlet densities - currently only used for fiinit(rho1)
ROGIN1=PRESS0/(287.41*TGIN1)
ROGIN2=PRESS0/(287.41*TGIN2)
ROGIN3=PRESS0/(287.41*TGIN3)
  ** turbulence model
IF (.NOT.NOXCAL) THEN
+ TURMOD(KEMODL); KELIN=3
ENDIF
    GROUP 10. Inter-phase-transfer processes and properties
  ** Set constant interphase friction factor and activate
     the calculation of the interphase mass transfer by:
CFIPS=GRND1; CFIPC=1.E5; CFIPA=1.0E-3; RLOLIM=1.0E-6
  ** grnd3 is an mdot option making the mass-transfer rate
     proportional to (cmdtc-mixf), where cmdtc stands for the
     saturation value of mixf, i.e. the largest value which can
     be attained as a result of mass transfer.
GFS=0.232/(0.232+CINCL*16./12.)
CMDOT=GRND3; CMDTA=1.E4; CMDTC=GFS
CINT(MIXF)=0.; CINT(C2)=0.
PHINT(MIXF)=1.0 ; PHINT(H1)=GRND7;PHINT(H2)=GRND7
    GROUP 11. Initialization of variable or porosity fields
FIINIT(GAS)=0.9999; FIINIT(FUE)=0.0001; FIINIT(SHAD)=0.0001
FIINIT(MDOT)=0.01*FMCOAL*0.5*XULAST/PI
FIINIT(FUE)=1.E-5;FIINIT(GAS)=1.0-FIINIT(FUE)
FIINIT(SHAD)=FIINIT(FUE)
  ** HCCO2 = heat of combustion for  C  +     O2 -> CO2
     HCCO  =  "    "     "       "   C  + 0.5 O2 -> CO
     HHH2O =  "    "     "       "   H2 + 0.5 O2 -> H2O
        H = CP*T + HCHX*YCHX + HCOCO2*YCO * HH2*YH2
HCCO2=32.792E6; HCCO=9.208E6; HHH2O=120.9E6
HCHX=CINCL*HCCO2 + HINCL*HHH2O
HCHX
HGIN1=CP1*(TGIN1-TEMP0);HGIN2=CP1*(TGIN2-TEMP0)
HGIN3=CP1*(TGIN3-TEMP0)
HSIN=CP2*TSIN + HCHX
FIINIT(H1)=HGIN2; FIINIT(H2)=HSIN
FIINIT(RHO1)=ROGIN2;FIINIT(TMP2)=TSIN
  -- initially none of the second phase has entered the first
FIINIT(MIXF)=0.; FIINIT(C2)=1.
  ** flow field initialisation
IF (.NOT.NOXCAL) THEN
INIADD=F; IURINI=-1
FIINIT(W1)=WGIN2; FIINIT(W2)=WSIN; FIINIT(V1)=0.; FIINIT(V2)=0.
FIINIT(U1)=OMEGA2; FIINIT(U2)=OMEGAS
FIINIT(KE)=TKEIN2; FIINIT(EP)=EPIN2
PATCH(INIT1,INIVAL,1,1,#1,#1,1,NZ,1,1)
PATCH(INIT2,INIVAL,1,1,#2,#2,1,NZ,1,1)
INIT(INIT1,W1,ZERO,WGIN3); INIT(INIT2,W1,ZERO,WGIN1)
INIT(INIT1,U1,ZERO,OMEGA3); INIT(INIT2,U1,ZERO,OMEGA1)
INIT(INIT1,U2,ZERO,OMEGA3); INIT(INIT2,U2,ZERO,OMEGA1)
INIT(INIT1,KE,ZERO,TKEIN3); INIT(INIT2,KE,ZERO,TKEIN1)
INIT(INIT1,EP,ZERO,EPIN3); INIT(INIT2,EP,ZERO,EPIN1)
INIT(INIT1,H1,ZERO,HGIN3); INIT(INIT2,H1,ZERO,HGIN1)
INIT(INIT1,RHO1,ZERO,ROGIN3); INIT(INIT2,RHO1,ZERO,ROGIN1)
ENDIF
  ** block region behind furnace wall above quarl
CONPOR (BLOCK1,0.,CELL,1,1,#4,#4,#1,#1)
 ** sas added friction to south wall of blockage.
WALL(WALL1,SOUTH,1,1,#4,#4,#1,#1,1,1)
 **     WALL(WALL2,HIGH,1,1,#4,#4,#1,#1,1,1)
 ** restarts
IF (.NOT.NOXCAL) THEN
  -- for a restart main combustion run (NOT a NOX post-
  -- processing run) activate the next statement.
        RESTRT(ALL)
ENDIF
IF (NOXCAL) THEN
+ RESTRT(P1,U1,U2,GAS,FUE,SHAD,H1,H2,MIXF,C2,TMP1,TMP2)
+ RESTRT(RHO1,RMIX,YH2O,YH2,YN2,YCO2,YO2,YCO,CFIP,MDOT)
+ RESTRT(V1,V2,W1,W2)
ENDIF
    GROUP 13. Boundary conditions and special sources
            =======================================
OUTCO1=1.E3
  ** NOX sources
IF (NOXCAL) THEN
+ PATCH(NOXSR,FREEVL,1,NX,1,NY,1,NZ,1,1)
+ COVAL(NOXSR,XNO,FIXFLU,GRND); COVAL(NOXSR,XN,GRND,GRND)
+ PATCH(NOXIN1,LOW,1,1,#2,#2,1,1,1,1)
+ COVAL(NOXIN1,XNO,FGIN1,0.); COVAL(NOXIN1,XN,FGIN1,0.)
+ PATCH(NOXIN2,LOW,1,1,#3,#3,1,1,1,1)
+ COVAL(NOXIN2,XNO,FGIN2,0.); COVAL(NOXIN2,XN ,FGIN2,0.)
+ PATCH(NOXIN3,LOW,1,1,#1,#1,1,1,1,1)
+ COVAL(NOXIN3,XNO,FGIN3,0.); COVAL(NOXIN3,XN ,FGIN3,0.)
+ PATCH(OUTLET,HIGH,1,NX,1,NY,NZ,NZ,1,1)
+ COVAL(OUTLET,P1,OUTCO1,0.0)
ELSE
  == sources for main calculation
IURVAL=-1
  ** primary air inlet
PATCH(INPRMA,LOW,1,1,#2,#2,1,1,1,1)
COVAL(INPRMA,P1,FIXFLU,FGIN1); COVAL(INPRMA,W1,ONLYMS,WGIN1)
COVAL(INPRMA,U1,ONLYMS,OMEGA1); COVAL(INPRMA,V1,ONLYMS,0.)
COVAL(INPRMA,H1,ONLYMS,HGIN1); COVAL(INPRMA,KE,ONLYMS,TKEIN1)
COVAL(INPRMA,EP,ONLYMS,EPIN1); COVAL(INPRMA,MIXF,ONLYMS,0.)
  remember, mixf=c1 !!
  ** primary coal inlet
PATCH(INPRMC,LOW,1,1,#2,#2,1,1,1,1)
COVAL(INPRMC,P2,FIXFLU,FCOAL); COVAL(INPRMC,W2,ONLYMS,WGIN1)
COVAL(INPRMC,U2,ONLYMS,OMEGAS); COVAL(INPRMC,V2,ONLYMS,0.)
COVAL(INPRMC,H2,ONLYMS,HSIN); COVAL(INPRMC,C2,ONLYMS,1.)
  ** secondary air inlet
PATCH(INSEC,LOW,1,1,#3,#3,1,1,1,1)
COVAL(INSEC,P1,FIXFLU,FGIN2); COVAL(INSEC,W1,ONLYMS,WGIN2)
COVAL(INSEC,U1,ONLYMS,OMEGA2); COVAL(INSEC,V1,ONLYMS,0.)
COVAL(INSEC,H1,ONLYMS,HGIN2); COVAL(INSEC,KE,ONLYMS,TKEIN2)
COVAL(INSEC,EP,ONLYMS,EPIN2); COVAL(INSEC,MIXF,ONLYMS,0.)
  ** tertiary air inlet
PATCH(INTER,LOW,1,1,#1,#1,1,1,1,1)
COVAL(INTER,P1,FIXFLU,FGIN3); COVAL(INTER,W1,ONLYMS,WGIN3)
COVAL(INTER,U1,ONLYMS,OMEGA3); COVAL(INTER,V1,ONLYMS,0.)
COVAL(INTER,H1,ONLYMS,HGIN3); COVAL(INTER,KE,ONLYMS,TKEIN3)
COVAL(INTER,EP,ONLYMS,EPIN3); COVAL(INTER,MIXF,ONLYMS,0.)
  ** Outlet at high end
OUTLET(OUTLET,HIGH,1,1,1,NY,NZ,NZ,1,1)
COVAL(OUTLET,P1,OUTCO1*0.1,0.0)
COVAL(OUTLET,P2,OUTCO1*RHO2,0.0); VALUE(OUTLET,C2,0.0)
  ** Radiative wall loss
IF(THRAD) THEN
+ PATCH(WALNR, NORTH, 1, NX,%3,%3,#1,#1, 1, 1)
+ COVAL(WALNR, RADY,EMISW/(2.0-EMISW),EMPW)
+ PATCH(WALLR, LOW  , 1, NX,#4,#4,$2,$2, 1, 1)
+ COVAL(WALLR, RADZ,EMISW/(2.0-EMISW),EMPW)
ENDIF
ENDIF
    GROUP 15. Termination of sweeps
LSWEEP=350
IF (NOXCAL) THEN
+ LSWEEP=120
ENDIF
    GROUP 16. Termination of iterations
  -- recover inlet mass flow rates in kg/s (not per unit area)
FGIN1=FGIN1*AIN2; FGIN2=FGIN2*AIN3; FGIN3=FGIN3*AIN1
FGIN1=FGIN1*0.5*XULAST/PI; FGIN2=FGIN2*0.5*XULAST/PI
FGIN3=FGIN3*0.5*XULAST/PI
FMCOAL=FMCOAL*0.5*XULAST/PI
  -- set residual normalising factors
    GROUP 17. Under-relaxation devices
  ** relaxations on pressure and density
CONWIZ=T
    GROUP 18. Limits on variables or increments to them
VARMAX(MIXF)=CMDTC; VARMIN(MIXF)=0.
VARMAX(C2)=1.; VARMIN(C2)=0.; VARMIN(FUE)=1.E-12
VARMIN(SHAD)=1.E-12; VARMIN(RHO1)=PRESS0/(287.*5000.)
  ** additional settings for NOX calculation
IF (NOXCAL) THEN
VARMIN(XNO)=0.; VARMAX(XNO)=1.
VARMIN(XN) =0.; VARMAX(XN) =1.
ENDIF
    GROUP 19. Data communicated by satellite to GROUND
LSG62=noxcal
    GROUP 21. Print-out of variables
OUTPUT(C2,N,N,N,N,N,N)
IF(NOXCAL) THEN
+ OUTPUT(C4,N,N,N,N,N,N); OUTPUT(C6,N,N,N,N,N,N)
+ OUTPUT(H1,N,N,N,N,N,N); OUTPUT(H2,N,N,N,N,N,N)
+ OUTPUT(U2,N,N,N,N,N,N); OUTPUT(SHAD,N,N,N,N,N,N)
+ OUTPUT(FUE,N,N,N,N,N,N); OUTPUT(TMP2,N,N,N,N,N,N)
+ OUTPUT(CFIP,N,N,N,N,N,N)
ENDIF
OUTPUT(TMP1,Y,Y,Y,Y,Y,Y); OUTPUT(TMP2,Y,Y,Y,Y,Y,Y)
    GROUP 22. Spot-value print-out
 ** sas changed monitoring point
IZMON=NZ*3/4; IYMON=NY/2
    GROUP 23. Field print-out and plot control
NPLT=10; ORSIZ=0.4;TSTSWP=-1
    GROUP 24. Dumps for restarts
DISTIL=T
IF(NOXCAL) THEN
+ EX(P1  )=5.752E+01; EX(U1  )=2.407E+00; EX(V1  )=1.866E+00
+ EX(V2  )=1.714E+00; EX(W1  )=3.503E+01; EX(W2  )=2.955E+01
+ EX(GAS )=9.500E-01; EX(MIXF)=2.047E-02; EX(NPOR)=9.913E-01
+ EX(VPOR)=9.500E-01; EX(DEGF)=1.429E+03; EX(EQUI)=2.711E-01
+ EX(NOSR)=3.453E+00; EX(CRKT)=1.036E+03
+ EX(XO2 )=1.558E-01; EX(RHO1)=3.856E-01
+ EX(TMP1)=1.042E+03; EX(YN2 )=7.139E-01; EX(TMP2)=6.337E+02
+ EX(YCO2)=7.130E-02; EX(YO2 )=1.556E-01
ELSE
+ EX(P1  )=5.752E+01; EX(U1  )=2.407E+00; EX(U2  )=2.496E+00
+ EX(V1  )=1.866E+00; EX(V2  )=1.714E+00; EX(W1  )=3.503E+01
+ EX(W2  )=2.955E+01; EX(GAS )=9.500E-01; EX(KE  )=1.085E+01
+ EX(EP  )=2.311E+02; EX(H1  )=1.147E+06; EX(H2  )=3.604E+07
+ EX(MIXF)=2.047E-02; EX(NPOR)=9.913E-01; EX(VPOR)=9.500E-01
+ EX(ENUT)=5.748E-02; EX(RHO1)=3.856E-01; EX(TMP2)=6.354E+02
+ EX(TMP1)=1.042E+03; EX(YN2 )=7.139E-01; EX(YCO2)=7.130E-02
+ EX(YO2 )=1.556E-01; EX(RADY)=1.106E+05; EX(RADZ)=2.517E+05
ENDIF
  ** long names for print-out
spedat(longname,epke,c,micro-mixing_rate)  
spedat(longname,rady,c,y-direction_flux_sum)  
spedat(longname,radz,c,z-direction_flux_sum)