TALK=T;RUN( 1, 1)
 ** LOAD(x203) from the x Input Library
     **  CHEMKIN - 0D-Transient Reaction
  DISPLAY
 
  0D Transient Fixed Constant Pressure Reactor
  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  A stoichiometric mixture of air and H2 at 298 K reacts
  at constant pressure.
 
  This case is taken from the example
  application given in the CHEMKIN Manual (CONP).
 
  ENDDISPLAY
 
  Parameters for the case are:
 
       Pressure = 1 Atm.
       To       = 1000 K
       Y(H2)o  = 0.020007
       Y(O2)o  = 0.952191
       Y(N2)o  = 0.027802
 
    Species: H2  H  O2  O  OH  HO2  H2O  H2O2 N2 (? reactions)
 
    Reactions:
 
    H+O2 = O+OH            5.1E16   -0.82  16510
    H2+O = H+OH            1.8E10    1.0    8830
    H2+OH = H2O+H          1.2E09    1.3    3630
    OH+OH = H2O+O          6.0E08    1.3    0.0
    H+OH+M = H2O+M         7.5E23   -2.6    0.0
      H2O /20.0/
    O2+M = O+O+M           1.9E11    0.5   95560
    H2+M = H+H+M           2.2E12    0.5   92600
      H2O /6.0/  H   /2.0/ H2  /3.0/
    H2+O2 = OH+OH           1.7E13    0.0   47780
    H+O2+M = HO2+M          2.1E18   -1.0    0.0
      H2O /21.0/ H2  /3.3/ O2  /0.0/ N2  /0.0/
    H+O2+O2 = HO2+O2       6.7E19   -1.42    0.0
    H+O2+N2 = HO2+N2       6.7E19   -1.42    0.0
    HO2+H = H2+O2          2.5E13    0.0     700
    HO2+H = OH+OH          2.5E14    0.0    1900
    HO2+O = OH+O2          4.8E13    0.0    1000
    HO2+OH = H2O+O2        5.0E13    0.0    1000
    HO2+HO2 = H2O2+O2      2.0E12    0.0    0.0
    H2O2+M = OH+OH+M       1.2E17    0.0   45500
    H2O2+H = HO2 + H2      1.7E12    0.0    3750
    H2O2+OH = H2O+HO2      1.0E13    0.0    1800
 
       (where units are gram-mole, cm**3 & Joules)
 
  AUTOPLOT USE
  file
  phi 5
 
 
  clear
  msg H2, O2, H2O & Temp.(/1000) profiles
  data 1
  H2
  data 1
  O2
  data 1
  H2O
  data 1
  TEM1
  multi y 25     1
  multi y 0.0001 4
  scale
  plot 1;blb1 2;blb2 3;blb3 4
  msg Press  to continue
  pause
  clear
  msg H, O, OH & HO2 profiles
  data 1
  H
  data 1
  O
  data 1
  OH
  data 1
  HO2
  multi y 30   1
  multi y 1000 4
  scale
  plot 1;blb1 2;blb2 3;blb3 4
  msg Press  to continue
  pause
  clear
  msg Heat-release rate profile
  data 1
  QDOT
  scale
  plot
 
  enduse
    GROUP 1. Run title and other preliminaries
TEXT( CHEMKIN - 0D-Transient Reaction
TITLE
    GROUP 2. Transience; time-step specification
STEADY=F
LSTEP=118
TFRAC(1)=-100.;TFRAC(2)=3.E-7
TFRAC(3)= 10.;TFRAC(4)=3.E-6
TFRAC(5)=  8.;TFRAC(6)=3.E-5
   TFRAC(5)= 10.;TFRAC(6)=3.E-5
    GROUP 7. Variables stored, solved & named
SOLVE(TEM1);TERMS(TEM1,N,P,P,P,P,N)
  Sets LSG61=T and H2=CHSOB=16
CHEMKIN(SPECIES,H2,H,O2,O,OH,HO2,H2O,N2)
INTEGER(KK,JJ);KK=8
DO II=1,KK
+ JJ=CHSOB+II-1
+ TERMS(:JJ:,N,P,P,P,P,N)
ENDDO
  Store the density, the heat-release rate, the net rates of
  production of H2 and O2, and the rate of reaction 5
STORE(DEN1,QDOT,H2+,O2+,5&)
  Store mole fractions
STORE(MH2,MH,MO2,MO,MOH,MHO2,MH2O,MN2)
    GROUP 9. Properties of the medium (or media)
CP1=GRND9; RHO1=CHEMIST
    GROUP 11. Initialization of variable or porosity fields
DO II=1,KK
+ JJ=CHSOB+II-1
+ FIINIT(:JJ:)=0.0
ENDDO
FIINIT(H2)=0.01984; FIINIT(O2)=0.95232
REAL(SUMY,MDOT);SUMY=0.0
DO II=1,KK
+ JJ=CHSOB+II-1
+ SUMY=SUMY+FIINIT(:JJ:)
ENDDO
FIINIT(N2)=1.-SUMY; FIINIT(TEM1)=1000.
    GROUP 15. Termination of sweeps
LSWEEP=20
  Making RESREF -ve deactivates the inbuilt PHOENICS
  sweep termination control and activates a control
  mechanism in GXCHKI
DO II=1,KK
+ JJ=CHSOB+II-1
+ RESREF(:JJ:)=-1.E-4
+ ENDIT(:JJ:)=1.E-5
ENDDO
RESREF(TEM1)=-1.E-1; ENDIT(TEM1)=1.E-5
    GROUP 17. Under-relaxation devices
DO II=1,KK
+ JJ=CHSOB+II-1
+ RELAX(:JJ:,FALSDT,1.E-5)
ENDDO
RELAX(TEM1,FALSDT,5.E-6)
    GROUP 19. Data communicated by satellite to GROUND
CHSOA=GRND9;CHSOC=1.0;CSG4='ho11'
SPEDAT(SET,GXMONI,TRANSIENT,L,F)
    GROUP 21. Print-out of variables
NTPRIN=20
OUTPUT(QDOT,Y,Y,Y,Y,Y,Y); OUTPUT(H2+,Y,Y,Y,Y,Y,Y)
OUTPUT(O2+,Y,Y,Y,Y,Y,Y); OUTPUT(5&,Y,Y,Y,Y,Y,Y)
IDISPA=1
    GROUP 22. Spot-value print-out
TSTSWP=-1;itabl=2
    GROUP 24. Dumps for restarts