TEXT(Premixed CH4 Combustion         
TITLE
  DISPLAY
  The problem considered is turbulent reacting flow in a
  cylindrical combustion chamber with central and annular
  coaxial feed injectors supplying premixed methane and
  air. The geometry is axisymmetric with an outer radius
  of 0.21m and an axial length of 2.75m. The reactants are
  supplied at a temperature of 300K, and the composition of
  each inlet stream is identical. The default fuel/air
  equivalence ratio is 1.15, and the operating pressure
  is 1 bar.
  ENDDIS
    GROUP 1. Run title and other preliminaries
REAL(WINF,WINO,KEL,EPL,KEINIT,TWAL,TEMFU,TEMOX)
REAL(YFUIN,YOXIN,YN2IN,RTUBE);CHAR(CTUR,CMOD)
INTEGER(ICOMB,ICASE);BOOLEAN(HSOLV,THRAD);HSOLV=T;THRAD=F
WINF=27.18;WINO=6.418; RTUBE=0.21
TWAL=100.+273.;TEMFU=27.+273.;TEMOX=TEMFU
MESG( Enter required inlet stoichometry: default O2 excess
MESG( The options are:
MESG(  O2  - Excess oxygen supply
MESG(  ST  - Stoichometric supply
MESG(  FU  - Excess fuel supply
READVDU(CTUR,CHAR,O2)
CASE :CTUR: OF
WHEN O2,2
+ MESG(Excess Oxygen supply : Equivalence Ratio = 1.15
+ YFUIN=0.04846;YOXIN=0.22165
+ ICASE=1
WHEN ST,2
+ MESG(Stoichometric supply : Equivalence Ratio = 1.0
+ YFUIN=0.0552;YOXIN=0.21986
+ ICASE=2
WHEN FU,2
+ MESG(Excess Fuel supply   : Equivalence Ratio = 0.8
+ YFUIN=0.0679;YOXIN=0.21625
+ ICASE=3
ENDCASE
YN2IN=1.-YFUIN-YOXIN
    GROUP 2. Transience; time-step specification
STEADY=T
    GROUP 3. X-direction grid specification
CARTES=F;XULAST=0.1
    GROUP 4. Y-direction grid specification
NREGY=4;NY=8
IREGY=1;GRDPWR(Y,2,0.0191,1.0);IREGY=2;GRDPWR(Y,2,0.0286,1.0)
IREGY=3;GRDPWR(Y,2,0.0548,1.0);IREGY=4;GRDPWR(Y,2,0.1048,1.0)
    GROUP 5. Z-direction grid specification
NREGZ=2;NZ=10
IREGZ=1;GRDPWR(Z,4,0.381,1.0);IREGZ=2;GRDPWR(Z,6,2.362,1.3)
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1);STORE(VIST,DEN1,TMP1,SPH1,YSUM)
SOLUTN(P1,P,P,Y,P,P,P);SOLUTN(V1,P,P,P,P,P,N)
SOLUTN(W1,P,P,P,P,P,N);TURMOD(KEMODL)
IF(HSOLV) THEN
+ SOLVE(H1);TERMS(H1,N,P,P,P,P,P)
+ SOLUTN(H1,P,P,Y,P,P,P)
ELSE
+ STORE(H1)
ENDIF
IF(THRAD) THEN
+ REAL(ABSORB,SCAT,SIGMA,EMPW,EMISW,EMISG,EMPG)
+ ABSORB=1.45;SCAT=0.; EMISG=0.07
+ SIGMA=5.6697E-8; EMISW=1.0
+ EMPW=SIGMA*TWAL**4; EMPG=SIGMA*EMISG
+ RADIAT(RADI,ABSORB,SCAT,H1)
+ SOLUTN(SRAD,P,P,Y,P,P,P);SOLUTN(H1,P,P,Y,P,P,P)
ENDIF
    GROUP 8. Terms (in differential equations) & devices
    GROUP 9.  Properties of the medium (or media).
ENUL=4.2E-5
  *** START OF EXTENDED SCRS MODEL SETTINGS
PRESS0=1.0000E+05
INTEGER(NSPEC,NELEM);NSPEC=7;NELEM=4
INTEGER(NCSTEP,NCREAC)
MESG( Enter required combustion model
MESG( Default: 1 step finite rate EBU
MESG( The options are:
MESG(  EBU1  - 1 step finite-rate EBU
MESG(  EBU2  - 2 step 2 reactions finite-rate EBU
MESG(  EBU3  - 2 step 3 reactions finite-rate EBU
READVDU(CMOD,CHAR,EBU1)
CASE :CMOD: OF
WHEN EBU1,4
+ MESG(1 step finite-rate EBU model
+ MESG(2CH4 +  4O2 > 2CO2 + 4H2O
+ NCSTEP=1;NCREAC=1
+ SCRS(SYSTEM,NCSTEP,NCREAC,NELEM,FRATE*)
+ SCRS(SPECIES,CH4,O2,H2,CO,H2O,CO2,N2)
+ SCRS(PROP,CHEMKIN,SCH4)
+ STORE(P1RS);ICOMB=0
WHEN EBU2,4
+ MESG(2 step 2 reactions finite-rate EBU model
+ MESG( 2CH4 + 3O2 > 2CO  + 4H2O
+ MESG( 2CO  + O2  > 2CO2
+ NCSTEP=2;NCREAC=2
+ SCRS(SYSTEM,NCSTEP,NCREAC,NELEM,FRATE*)
+ SCRS(SPECIES,CH4,O2,H2,CO,H2O,CO2,N2)
+ SCRS(PROP,CHEMKIN,STWO)
+ STORE(P1RS,S1RS);ICOMB=1
WHEN EBU3,4
+ MESG(2 step 3 reactions finite-rate EBU model
+ MESG(2CH4 +  O2 > 2CO + 4H2
+ MESG(2CO  +  O2 > 2CO2
+ MESG(2H2  +  O2 > 2H2O
+ NCSTEP=2;NCREAC=3
+ SCRS(SYSTEM,NCSTEP,NCREAC,NELEM,FRATE*)
+ SCRS(SPECIES,CH4,O2,H2,CO,H2O,CO2,N2)
+ SCRS(PROP,CHEMKIN,SCRS)
+ STORE(P1RS,S1RS,S2RS);ICOMB=2
ENDCASE
STORE(MMWT)
   ** Define fuel & oxidiser composition & temperature
SCRS(FUIN,YFUIN,YOXIN,0.0,0.0,0.0,0.0,YN2IN,TEMFU)
SCRS(OXIN,YFUIN,YOXIN,0.0,0.0,0.0,0.0,YN2IN,TEMOX)
  *** END OF EXTENDED SCRS MODEL SETTINGS
    GROUP 11. Initialization of variable or porosity fields
INIADD=F; FIINIT(W1)=WINO
KEINIT=(0.011*WINO)**2; FIINIT(EP)=0.1643*KEINIT**1.5/(0.01*RTUBE)
IF(THRAD) THEN
+ REAL(TGUESS);TGUESS=300.; FIINIT(SRAD)=0.07*SIGMA*TGUESS**4
ENDIF
IF(HSOLV) THEN
+ FIINIT(H1)=1.267E3
ENDIF
FIINIT(KE)=KEINIT; FIINIT(CH4)=0.85*YFUIN
    GROUP 13. Boundary conditions and special sources
   * INLET boundary condition for centre burner
KEL=0.5*(0.2*WINF)**2; EPL=1.643*((KEL)**1.5)/0.0095
INLET(SCRSF,LOW,1,NX,#2,#2,1,1,#1,#NREGT)
VALUE(SCRSF,P1,GRND1); VALUE(SCRSF,W1,WINF)
VALUE(SCRSF,EP,EPL); VALUE(SCRSF,KE,KEL)
VALUE(SCRSF,F,1.); VALUE(SCRSF,CH4,YFUIN)
IF(HSOLV) THEN
+ VALUE(SCRSF,H1,GRND3)
ENDIF
   * INLET boundary condition for outer burner
KEL=0.5*(0.2*WINO)**2; EPL=1.643*((KEL)**1.5)/0.05
INLET(SCRSO,LOW,1,NX,#4,#4,1,1,#1,#NREGT)
VALUE(SCRSO,P1,GRND1); VALUE(SCRSO,W1,WINO)
VALUE(SCRSO,EP,EPL); VALUE(SCRSO,KE,KEL)
VALUE(SCRSO,F,0.); VALUE(SCRSO,CH4,YFUIN)
IF(HSOLV) THEN
+ VALUE(SCRSO,H1,GRND3)
ENDIF
 
PATCH(OUT,HIGH,1,NX,1,NY,#NREGZ,#NREGZ,#1,#NREGT)
COVAL(OUT,P1,1.E2,0.);COVAL(OUT,F,ONLYMS,SAME)
IF(HSOLV) THEN
+ COVAL(OUT,H1,ONLYMS,SAME)
ENDIF
   * WALL boundary condition, name WALL3
PATCH(NWALL3,NWALL,1,NX,#NREGY,#NREGY,#2,NZ,#1,#NREGT)
COVAL(NWALL3,W1,GRND2,0.0);COVAL(NWALL3,KE,GRND2,GRND2)
COVAL(NWALL3,EP,GRND2,GRND2)
 
IF(THRAD) THEN
+ PATCH(NWALL3R,NORTH,1,NX,#NREGY,#NREGY,1,NZ,#1,#NREGT)
+ COVAL(NWALL3R,SRAD,EMISW/(2.0-EMISW),EMPW)
ENDIF
    GROUP 15. Termination of sweeps
LSWEEP=200
    GROUP 16. Termination of iterations
    GROUP 17. Under-relaxation devices
RELAX(P1,LINRLX,1.0); RELAX(V1,FALSDT,5.E-3)
RELAX(W1,FALSDT,5.E-3); RELAX(KE,FALSDT,5.E-3)
RELAX(EP,FALSDT,5.E-3); RELAX(DEN1,LINRLX,0.5)
RELAX(F,LINRLX,0.8); RELAX(CH4,FALSDT,1.E-3)
IF(ICOMB.GT.0) THEN
+ RELAX(CO,FALSDT,1.E-3)
ENDIF
IF(ICOMB.EQ.2) THEN
+ RELAX(H2,FALSDT,1.E-3)
ENDIF
IF(HSOLV) THEN
+ RELAX(H1,FALSDT,1.0)
ENDIF
IF(THRAD) THEN
+ RELAX(SRAD,FALSDT,1.0)
ENDIF
    GROUP 18. Limits on variables or increments to them
VARMIN(TMP1)=1.E-10; VARMIN(DEN1)=1.E-10
OUTPUT(TMP1,P,P,P,P,Y,Y); OUTPUT(DEN1,P,P,P,P,Y,Y)
    GROUP 20. Preliminary print-out
ECHO=T
    GROUP 21. Print-out of variables
    GROUP 22. Spot-value print-out
IXMON=1;IYMON=NY/2;IZMON=6
    GROUP 23. Field print-out and plot control
TSTSWP=-1;ITABL=3;NPLT=1
    GROUP 24. Dumps for restarts