PHOTON USE
  p
 
 
 
 
  text
  1
  1
  Particles with different
   0.18841E+04 0.23725E+04 CR
  text
  1
  1
  size and init. velocity
   0.18841E+04 0.22422E+04 CR
  text
  1
  1
  are introduced into a radial
   0.18841E+04 0.21119E+04 CR
  text
  1
  1
  impellar in a rotating BFC
   0.18841E+04 0.19817E+04 CR
  text
  1
  1
  coordinate system.
   0.18841E+04 0.18514E+04 CR
  upause 4
  gr out z 1
  gr out z m
  gr out y 1
  gr out y m
  upause 2
  GEOMETRY READ
  T00001
  GEOMETRY READ
  T00002
  GEOMETRY READ
  T00003
  GEOMETRY READ
  T00004
  GEOMETRY READ
  T00005
  GEOMETRY READ
  T00006
  GEOMETRY READ
  T00007
  GEOMETRY READ
  T00008
  GEOMETRY READ
  T00009
  GEOMETRY READ
  T00010
  GEOMETRY READ
  T00011
  upause 5
  vec y 3
  upause 2
  text
  3
 
  Press e to end
   0.18841E+04 0.14265E+04 CR
  enduse
 
 
   GROUP 1. Run title
TEXT(Particles in radial impeller: G204
TITLE
  DISPLAY
    The continuous-phase set-up is that of PHOENICS Library Case
  524.The geometry is that of the B-type impeller tested by Mizuki
  et al. (1974). The solution domain represents the
  passage between two blades and a 'vaneless space' beyond the outer
  radius of the impeller, which is represented by applying cyclic
  boundary conditions on the East and West surfaces at IZ=11 and 12.
  The grid given in file GRID1 was generated by linear
  interpolation from boundary values using a conical coordinate
  system, and is non-orthogonal.
    Particles of several sizes are introduced at the inlet.
  Since the coordinate system is a rotating one, Coriolis and
  centrifugal forces acting on the particles are automatically
  introduced by GENTRA-Earth.
  ENDDIS
  =============================================================
REAL(RTIP,FLCO,VRM,RPM,UTIP,WTIP,OMEGA,WIN,PI,RHUB,RSHRO,HDY)
PI=3.14159
    GROUP 3. X-direction grid specification
NX=5
    GROUP 4. Y-direction grid specification
NY=5
    GROUP 5. Z-direction grid specification
NZ=12
   ** Number of Z-slabs beyond rotor tip
IG(4)=2
    GROUP 6. Body-fitted coordinates or grid distortion
BFC=T;NONORT=T;READCO(GRID1)
    GROUP 7. Variables stored, solved & named
SOLVE(P1,U1,V1,W1);SOLUTN(P1,Y,Y,Y,N,N,N)
ISOLX=1;ISOLY=1;ISOLZ=1
    GROUP 9. Properties of the medium (or media)
RHO1=1.24;ENUL=1.8E-5/1.24;ENUT=.0128*.1/1.24
    Pass incoming density to GXBFC through RHO1A
RHO1A=RHO1
    GROUP 11. Initialization of variable or porosity fields
   ** Flow Coefficient: ratio of radial velocity at rotor exit
    to tip speed.
FLCO=.4
   ** Ratio of inlet area to outlet area
VRM=1.
   ** Rotational speed RPM....
RPM= 6000.;RTIP=.135;OMEGA=RPM*PI/30.;UTIP=OMEGA*RTIP
WTIP=UTIP*FLCO;WIN= WTIP/VRM
FIINIT(W1)=WIN
   ** Radii of hub and shroud at inlet...
RHUB=0.0405;RSHRO=0.0785;HDY=(RSHRO-RHUB)/(2*NY)
    GROUP 13. Boundary conditions and special sources
   ** The inlet flow is dealt with by means of NY concentric
      rings in each of which the azimuthal velocity relative to
      the rotating coordinate frame is omega times the radius of
      the centre of the ring...
DO II=1,NY
+ PATCH(BFC:II:,LOW,1,NX,NY-II+1,NY-II+1,1,1,1,1)
+ COVAL(BFC:II:,P1,FIXFLU,RHO1*WIN)
+ COVAL(BFC:II:,U1,ONLYMS,GRND1)
+ COVAL(BFC:II:,W1,ONLYMS,GRND1)
+ COVAL(BFC:II:,UCRT,0.0,0.0)
+ COVAL(BFC:II:,VCRT,0.0,-OMEGA*(RHUB+(II*2-1)*HDY))
+ COVAL(BFC:II:,WCRT,0.0,WIN)
ENDDO
PATCH(GXIN,LOW,1,NX,1,NY,1,1,1,1)
   ** Uniform pressure boundary at outer circumference of domain
PATCH(GXOUT,HIGH,1,NX,1,NY,NZ,NZ,1,1)
COVAL(GXOUT,P1,1.E2,0.);COVAL(GXOUT,U1,ONLYMS,0.0)
COVAL(GXOUT,V1,ONLYMS,0.0);COVAL(GXOUT,W1,ONLYMS,0.0)
   ** Whole-domain patch for Rotational sources. Patch name ROTA
      is the signal for GREX3 to call subroutine GXROTA. The
      following 6 parameters specify the cartesian coordinates
      of two points on the axis of rotation...
ROTAXA=0.0;ROTAYA=0.0;ROTAZA=0.0
ROTAXB=0.0;ROTAYB=0.0;ROTAZB=-1.0
ANGVEL=OMEGA;IROTAA=0
PATCH(ROTA,PHASEM,1,NX,1,NY,1,NZ,1,1)
COVAL(ROTA,V1,FIXFLU,GRND1)
COVAL(ROTA,U1,FIXFLU,GRND1)
COVAL(ROTA,W1,FIXFLU,GRND1)
WALL (WFUN1,SOUTH,1,NX,1,1,1,NZ,1,1)
COVAL(WFUN1,U1,GRND2,-.8*UTIP)
COVAL(WFUN1,W1,GRND2,0.)
WALL (WFUN2,NORTH,1,NX,NY,NY,1,NZ,1,1)
COVAL(WFUN2,U1,GRND2,0.)
COVAL(WFUN2,W1,GRND2,0.)
WALL (WFUN3,WEST,1,1,1,NY,1,NZ-2,1,1)
COVAL(WFUN3,V1,GRND2,0.)
COVAL(WFUN3,W1,GRND2,0.)
WALL (WFUN4,EAST,NX,NX,1,NY,1,NZ-2,1,1)
COVAL(WFUN4,V1,GRND2,0.)
COVAL(WFUN4,W1,GRND2,0.)
   ** Cyclic boundary beyond impeller tip
XCYIZ(NZ-1,NZ,T)
    GROUP 15. Termination of sweeps
LSWEEP=15
LITER(P1)=10;LITER(U1)=1;LITER(V1)=1;LITER(W1)=1
    GROUP 17. Under-relaxation devices
RELAX(P1,LINRLX,.4)
RELAX(U1,FALSDT,.5E-3);RELAX(V1,FALSDT,.5E-3)
RELAX(W1,FALSDT,.5E-3)
    GROUP 21. Print-out of variables
OUTPUT(P1,Y,Y,Y,Y,Y,Y)
    GROUP 22. Spot-value print-out
IXMON=NX/2;IYMON=NY/2;IZMON=NZ/2
    GROUP 23. Field print-out and plot control
NPRINT=LSWEEP;NPLT=1;NXPRIN=2;NYPRIN=2;NZPRIN=2
PATCH(SUCTION,CONTUR,NX,NX,1,NY,1,NZ,1,1)
PLOT(SUCTION,P1,0.0,20.0)
PATCH(PRESSURE,CONTUR,1,1,1,NY,1,NZ,1,1)
PLOT(PRESSURE,P1,0.0,20.0)
PATCH(MIDWAY,CONTUR,1,NX,NY/2,NY/2,1,NZ,1,1)
PLOT(MIDWAY,P1,0.0,20.0)
TRACE=F
#GENTRA
  *-------------------------------------------------------
  * GENTRA GROUP 1: Particle physics
  *-------------------------------------------------------
  * Particle type - 30 - ISOTHERMAL_PARTICLES
GPTYPE=30
  * Gravity components in GENTRA Cartesian system/buoyancy
GGRAX=0;GGRAY=0;GGRAZ=0;GBUOYA=F
  * Stochastic model of turbulence
GSTOCH=F
  * Data for isothermal particles
GDRAG=GRND1
  *-------------------------------------------------------
  * GENTRA GROUP 2: Boundary conditions for particles
  *-------------------------------------------------------
  * Inlet-data file-name
GINFIL=Q1
  * Use this space for inlet-data table if GINFIL=Q1
  
  *__XP  __YP__ZP__UP__VP__WP__DIAM _DENSTY_FRATE
   0.057 0.015 0.0 0.0 -1.0 10.0 7.0E-05 1000.0 1.E-06
   0.057 0.015 0.0 0.0 -2.0 10.0 6.5E-05 1000.0 1.E-06
   0.057 0.015 0.0 0.0 -3.0 10.0 6.0E-05 1000.0 1.E-06
   0.057 0.015 0.0 0.0 -4.0 10.0 5.5E-05 1000.0 1.E-06
   0.057 0.015 0.0 0.0 -5.0 10.0 5.0E-05 1000.0 1.E-06
   0.057 0.015 0.0 0.0 -6.0 10.0 4.5E-05 1000.0 1.E-06
   0.057 0.015 0.0 0.0 -7.0 5.0 4.0E-05 1000.0 1.E-06
   0.057 0.015 0.0 0.0 -8.0 5. 3.5E-05 1000.0 1.E-06
   0.057 0.015 0.0 0.0 -9.0 5.0 3.0E-05 1000.0 1.E-06
   0.057 0.015 0.0 0.0 -10.0 5.0 2.5E-05 1000.0 1.E-06
   0.057 0.015 0.0 0.0 -11.0 5.0 2.0E-05 1000.0 1.E-06
  
  * Wall treatment, and rest coefficient if appropriate
GWALLC=3;GWREST=1
  * Porosity threshold
GPOROS=0
  *-------------------------------------------------------
  * GENTRA GROUP 3: Numerical controls
  *-------------------------------------------------------
  * 1st GENTRA sweep; frequency of calls
GSWEP1=LSWEEP;GSWEPF=1
  * Maximum Lagrangian time-step
GDTMAX=1
  * Min # of t-steps per cell; max # of t-steps; timeout
GLAGTS=5;GSTEMX=1000;GTIMMX=10000
  *-------------------------------------------------------
  * GENTRA GROUP 4: Output controls
  *-------------------------------------------------------
  * Trajectory-file identifier, history-file identifier
    and frequency for output
  * Particle number for residence-time calculation
GT1STC=T;GSWOUT=10;NGWSTR=1;NGWEND=20;NGWINT=1
GRESTI=0
  *-------------------------------------------------------
  * GENTRA GROUP 5: Provisions for the GENTRA-Earth run
  *-------------------------------------------------------
  * Storage of Cartesian components in BFC cases
STORE(UCRT,VCRT,WCRT)
NCRT=1
  * Storage for interphase sources of momentum
STORE(MOMX);STORE(MOMY);STORE(MOMZ)
  * Interphase sources of heat and momentum
PATCH(GENPAT,CELL,1,NX,1,NY,1,NZ,1,LSTEP)
COVAL(GENPAT,3,FIXFLU,GRND)
COVAL(GENPAT,5,FIXFLU,GRND)
COVAL(GENPAT,7,FIXFLU,GRND)
  * Relaxation of interphase sources
RELAX(MOMX,LINRLX,7.0000E-01)
RELAX(MOMY,LINRLX,7.0000E-01)
RELAX(MOMZ,LINRLX,7.0000E-01)
  * Activation of GENTRA GROUND-station
L(GENSET
  * ----------------------------------------------------------
  * GENTRA GROUP 7: GENTRA test
  * ----------------------------------------------------------
   * GENTRA auto test  RG(51)--RG(56) are reserved
RG(51)= 7.31E-02;RG(52)= 9.42E+02;RG(53)= 8.65E-04
RG(54)= 1.76E+00;RG(55)=-2.06E-01;RG(56)= 9.00E-01
RG(57)= 1.10E+17;RG(58)= 4.95E-01
 EX(P1)=2.029E+03;EX(U1)=1.219E+01;EX(V1)=6.146E+00
 EX(W1)=3.456E+01;EX(WCRT)=1.817E+01;EX(VCRT)=1.374E+01
 EX(UCRT)=2.267E+01