```
** MB-FGE Test: Laminar axisymmetric flow with conjugate heat
transfer in a pipe with the partially blocked
core region (heat source).
**************************************************************
DISPLAY
----------------------------------------------------------
The case concerns laminar axisymmetric flow with conjugate
heat transfer in a partially blocked pipe. The blockage in
the middle of the pipe is heated by the constant heat flux.

The case is set in X-Y plane with two domains. First block
represents only the air occupied region; while  the second
includes both aluminium heater and adjacent air region.
----------------------------------------------------------
ENDDIS
L(PAUSE
**************************************************************
PHOTON USE
p ; ; ; ; ;

msg Computational Domain:
mgrid 1 k 1 col 2
mgrid 2 k 1 col 5
msg Press Any Key to Continue...
pause
cl
set vec av off
msg Velocity Vectors:
mgrid 1 out k 1
mgrid 2 out k 1
mvec 1 k 1 sh
mvec 2 k 1 sh
msg Press Any Key to Continue...
pause
cl
msg Contours of Pressure:
mgrid 1 out k 1
mgrid 2 out k 1
mcon 1 p1 k 1 fi
0.0001
mcon 2 p1 k 1 fi
0.0001
msg Press Any Key to Continue...
pause
cl
msg Contours of Temperature:
mgrid 1 out k 1
mgrid 2 out k 1
mcon 1 tem1 k 1 fi
0.0001
mcon 2 tem1 k 1 fi
0.0001
msg Press E  to exit PHOTON ...
PAUSE
ENDUSE
**************************************************************
GROUP 1. Run title and other preliminaries
TEXT(MBFGE: Laminar axisymmetric flow.
TITLE
INTEGER(NX1,NY1,NZ1,NX11,NX12,NX13,NX14,NX2,NY2,NZ2,NX21,NX22)
INTEGER(NY21,NY22)
REAL(REYNU,UIN,HINL,TCOLD,THOT,ROIN,DTHYD)
UIN  = 1.;    HINL= 0.015-0.0135;  REYNU= UIN*HINL/1.569E-5
TCOLD= 300.;  THOT= 400.
NX11 = 10;    NX12= 5;   NX13= 5;  NX14 = 10
NX1  = NX11+NX12+NX13+NX14;        NY1  = 10;  NZ1= 1
NX21 = NX11;  NX22= NX12+NX13;     NX2  = NX21+NX22
NY21 = 4;     NY22= 2;   NY2 = NY21+NY22;      NZ2= 1
GROUP 6. Body-fitted coordinates or grid distortion
*** Create 1st domain:
BFC= T;  GSET(D,NX1,NY1,NZ1,1.3E-2,1.5E-2,0.01)
GSET(P,P1, -0.0922,  0.0135,0.0); GSET(P, P2,    0.0,0.0135,0.0)
GSET(P,P3,     0.0,   0.015,0.0); GSET(P, P4,-0.0922, 0.015,0.0)
GSET(P,P5,0.009546,0.009546,0.0); GSET(P, P6,  0.012, 0.015,0.0)
GSET(P,P7,  0.0135,     0.0,0.0); GSET(P, P8,0.01946, 0.015,0.0)
GSET(P,P9,    0.04,     0.0,0.0); GSET(P,P10,   0.04, 0.015,0.0)
GSET(L,L12,P1,P2,NX11,1.0);  GSET(L,L23,P2,P3,NY1,1.0)
GSET(L,L34,P3,P4,NX11,1.0);  GSET(L,L41,P4,P1,NY1,1.0)
GSET(F,F1,P1,-,P2,-,P3,-,P4,-); GSET(M,F1,+I+J,1,1,1)
GSET(L,L25,P2,P5,NX12,1.0,ARC,  0.007,0.01154,0.0)
GSET(L,L56,P5,P6, NY1,1.0,ARC,0.01097,0.01139,0.0)
GSET(L,L63,P6,P3,NX12,1.0)
GSET(F,F2,P2,-,P5,-,P6,-,P3,-); GSET(M,F2,+I+J,NX11+1,1,1)
GSET(L,L57,P5,P7,NX13,1.0,ARC,0.011,0.007826,0.0)
GSET(L,L78,P7,P8, NY1,1.0,ARC,0.018,0.007061,0.0)
GSET(L,L86,P8,P6,NX13,1.0)
GSET(F,F3,P5,-,P7,-,P8,-,P6,-); GSET(M,F3,+I+J,NX11+NX12+1,1,1)
GSET(L, L79, P7,P9,NX14,1.0);  GSET(L,L910,P9,P10,NY1,1.0)
GSET(L,L108,P10,P8,NX14,1.0)
GSET(F,F4,P7,-,P9,-,P10,-,P8,-);GSET(M,F4,+I+J,NX11+NX12+NX13+1,1,1)
GSET(C,K:NZ1+1:,F,K1,1,NX1,1,NY1,RX,0.1,0.0,0.0,INC,1.0)
DUMPC(MBGR1)
*** Create 2nd domain:
GSET(D,NX2,NY2,NZ2,0.1,0.4E-3,0.01)
GSET(P,P1,-0.0922,0.0093,0.0); GSET(P,P2,    0.0,0.0093,0.0)
GSET(P,P3,    0.0, 0.013,0.0); GSET(P,P4,    0.0,0.0135,0.0)
GSET(P,P5,-0.0922,0.0135,0.0); GSET(P,P6,-0.0922, 0.013,0.0)
GSET(P,P7, 0.0093,   0.0,0.0); GSET(P,P8,  0.013,   0.0,0.0)
GSET(P,P9, 0.0135,   0.0,0.0)
GSET(L,L12,P1,P2,NX21,1.0); GSET(L,L23,P2,P3,NY21,1.0)
GSET(L,L34,P3,P4,NY22,1.0); GSET(L,L45,P4,P5,NX21,1.0)
GSET(L,L56,P5,P6,NY22,1.0); GSET(L,L61,P6,P1,NY21,1.0)
GSET(F,F1,P1,-,P2,P3,P4,-,P5,P6); GSET(M,F1,+I+J,1,1,1)
GSET(L,L27,P2,P7,NX22,1.0,ARC,0.005,0.007842,0.0)
GSET(L,L78,P7,P8,NY21,1.0)
GSET(L,L83,P8,P3,NX22,1.0,ARC,0.007, 0.01095,0.0)
GSET(F,F2,P2,-,P7,-,P8,-,P3,-); GSET(M,F2,+I+J,NX21+1,1,1)
GSET(L,L89,P8,P9,NY22,1.0)
GSET(L,L94,P9,P4,NX22,1.0,ARC,0.009546,0.009546,0.0)
GSET(F,F3,P3,-,P8,-,P9,-,P4,-); GSET(M,F3,+I+J,NX21+1,NY21+1,1)
GSET(C,K:NZ2+1:,F,K1,1,NX2,1,NY2,RX,0.1,0.0,0.0,INC,1.0)
DUMPC(MBGR2)
** Assemble blocks:
** To set up LINKS you can use MBLINK or MPATCH commands
GROUP 7. Variables stored, solved & named
STORE(VPOR,PRPS); SOLVE(P1,U1,V1,TEM1)
L(\$F150)
GROUP 8. Terms (in differential equations) & devices
TERMS(TEM1,N,Y,Y,P,P,P)
GROUP 9. Properties of the medium (or media)
RHO1  = FILE;  ENUL= FILE;  PRNDTL(TEM1)= CONDFILE
PRESS0= 1.E5;    ROIN= 3.1147E-4*PRESS0**0.71429
GROUP 11. Initialization of variable or porosity fields
INIADD= F;  FIINIT(PRPS)= 1.0;  FIINIT(TEM1)= TCOLD
MPATCH(2,SOLID,INIVAL,1,NX2,1,NY21,1,NZ2,1,1)
INIT(SOLID,PRPS,0.0,100.0)
GROUP 13. Boundary conditions and special sources
MPATCH(1,INL1,WEST,1,1,1,NY1,1,NZ1,1,LSTEP)
COVAL(INL1, P1,FIXFLU,ROIN*UIN); COVAL(INL1,TEM1,ONLYMS,TCOLD)
COVAL(INL1,UC1,ONLYMS,     UIN); COVAL(INL1, VC1,ONLYMS,  0.0)
MPATCH(2,INL2,WEST,1,1,NY21+1,NY2,1,NZ2,1,LSTEP)
COVAL(INL2, P1,FIXFLU,ROIN*UIN); COVAL(INL2,TEM1,ONLYMS,TCOLD)
COVAL(INL2,UC1,ONLYMS,     UIN); COVAL(INL2, VC1,ONLYMS,  0.0)
MPATCH(1,NW,NWALL,1,NX1,NY1,NY1,1,NZ1,1,LSTEP)
COVAL(NW,TEM1,1./0.7,TCOLD)
COVAL(NW, UC1,   1.0,  0.0); COVAL(NW,VC1,1.0,0.0)
MPATCH(2,SW,SWALL,1,NX2,NY21+1,NY21+1,1,NZ2,1,LSTEP)
COVAL(SW,UC1,1.0,0.0); COVAL(SW,VC1,1.0,0.0)
MPATCH(2,HEATSR,VOLUME,1,NX2,1,1,1,NZ2,1,LSTEP)
COVAL(HEATSR,TEM1,FIXFLU,2.E6)
MPATCH(1,OUT,EAST,NX1,NX1,1,NY1,1,NZ1,1,LSTEP)
COVAL(OUT, P1,  1.E4, 0.0); COVAL(OUT,TEM1,ONLYMS,SAME)
COVAL(OUT,UC1,ONLYMS,SAME); COVAL(OUT, VC1,ONLYMS,SAME)
GROUP 15. Termination of sweeps
LSWEEP= 300;  TSTSWP= -1
GROUP 16. Termination of iterations
SELREF= T;    RESFAC= 1.E-5
GROUP 17. Under-relaxation devices
VARMIN(TEM1)= TCOLD
RELAX(P1,LINRLX,0.25); DTHYD= 0.09/NX11/UIN
RELAX( UC1,FALSDT,DTHYD); RELAX(VC1,FALSDT,DTHYD)
RELAX(TEM1,FALSDT,1000.)
GROUP 19. Data communicated by satellite to GROUND
* LSG3 = T, activates curvilinearity treatment;
* LSG4 = T, activates nonorthogonality treatment.
LSG3= T;  LSG4= T
GROUP 22. Spot-value print-out
IXMON= NX1/2+1;  IYMON= NY1/2+1;  IZMON= 1
```