PHOTON USE
  p
 
 
 
  msg             Numerical solution  contours
  con C1 Z 1 fi;0.001
  msg  Press Enter to continue
  PAUSE
  CLEAR
  con EXAC Z 1 fi;0.001
  msg               Exact solution  contours
  msg Press e to END
  ENDUSE
 
    GROUP 1. Run title and other preliminaries

  DISPLAY 
    Two dimensional  convective-diffusion  problem  in  uniform  45
    degree flow field.  The family of exact solutions for one- two-
    and  three-dimensional  convection-diffusion  cases  have  been
    developed at CHAM MEI, Moscow, Russia to test the low-dispersion
    scheme performances.
  ENDDIS 
 
TEXT( 2D CONVECTIVE-DIFFUSION PROBLEM:120
NX=10;NY=10
    GROUP 2. Transience; time-step specification
    GROUP 3. X-direction grid specification
GRDPWR(X,NX,1,1.0)
    GROUP 4. Y-direction grid specification
GRDPWR(Y,NY,1,1.0)
    GROUP 7. Variables stored, solved & named
SOLVE(C1);STORE(U1,V1)
    GROUP 8. Terms (in differential equations) & devices
TERMS(C1,N,Y,Y,P,P,P)
    GROUP 9. Properties of the medium (or media)
RHO1=1.0;PRNDTL(C1)=1.0;ENUL=1.
    GROUP 11.
REAL(UIN,VIN);UIN=sqrt(2.)/2.;VIN=-sqrt(2.)/2.
FIINIT(U1)=UIN;FIINIT(V1)=VIN
    GROUP 13. Boundary conditions and special sources
REAL(LAMBD,PI,RC);LAMBD=1.;PI=3.14159;RC=1.*RHO1/ENUL
LAMBD=(RC-(RC*RC+4.*PI*PI)**0.5)/2.
mesg( LAMBDA=:LAMBD:
RG(1)=LAMBD/sqrt(2.);RG(2)=PI/sqrt(2.)

  PLANTBEGIN 
PATCH(CONWES,WEST,1,1,1,NY,1,NZ,1,LSTEP)
   VAL=EXP(-RG(1)*YG2D)*SIN(RG(2)*YG2D)
COVAL(CONWES,C1,RHO1*1.41/2.,GRND)

PATCH(DIFWES,WWALL,1,1,1,NY,1,NZ,1,LSTEP)
   VAL=EXP(-RG(1)*YG2D)*SIN(RG(2)*YG2D)
COVAL(DIFWES,C1,1.,GRND)
 
PATCH(CONNOR,WEST,1,NX,NY,NY,1,NZ,1,LSTEP)
   VAL=EXP(RG(1)*(XG2D-1.))*SIN(RG(2)*(1.+XG2D))
COVAL(CONNOR,C1,-RHO1*1.41/2.,GRND)
PATCH(DIFNOR,NWALL,1,NX,NY,NY,1,NZ,1,LSTEP)
   VAL=EXP(RG(1)*(XG2D-1.))*SIN(RG(2)*(1.+XG2D))
COVAL(DIFNOR,C1,1.,GRND)
 
PATCH(DIFEAS,EWALL,NX,NX,1,NY,1,NZ,1,LSTEP)
   VAL=EXP(RG(1)*(1.-YG2D))*SIN(RG(2)*(1.+YG2D))
COVAL(DIFEAS,C1,1.,GRND)
 
PATCH(DIFSOU,SWALL,1,NX,1,1,1,NZ,1,LSTEP)
   VAL=EXP(RG(1)*XG2D)*SIN(RG(2)*XG2D)
COVAL(DIFSOU,C1,1.,GRND)
STORE(EXAC)
   EXAC=EXP(RG(1)*(XG2D-YG2D))*SIN(RG(2)*(XG2D+YG2D))
  PLANTEND
 
    GROUP 15. Termination of sweeps
LSWEEP=8
    GROUP 19.
NAMSAT=MOSG
    GROUP 20. Preliminary print-out
    GROUP 21. Print-out of variables
tstswp=-1
dmpstk=t
DISTIL=T
EX(U1)=7.071E-01; EX(V1)=7.071E-01
EX(C1)=8.936E-01; EX(EXAC)=8.916E-01
 LIBREF=119
STOP