PHOTON USE
   p
 
 
 
   vec x 1 sh
   con temp x 1 sh;int 30
   msg             Velocity vectors and temperaturee
   msg  Press Enter to continue
   ENDUSE
 
    GROUP 1.  Run title and other preliminaries
TEXT(CONJUGATE HEAT TRANSFER IN THICK-WALLED PIPE:123
 
  DISPLAY
  The flow  in  a  thick-walled  pipe  is  considered.  In order to
  account for the conductive heat transfer through  the  wall,  the
  velocities are fixed to zero in the solid portions of the domain.
  A constant heat flux is prescribed at the outer wall, and uniform
  temperature  and  velocity  profiles  are  prescribed at the pipe
  inlet.  The problem is similar to the one from  PHOENICS  library
  but  no  porosity  technique  but  PLANT  facilities  are used to
  simulate the conjugate heat transfer.
 
    The locally-defined variables are:
      WIN           Inlet velocity.
      QDOT          Heat flux at outer wall
      CP            Specific heat of water
      IYMET         First cell inside solid
      IYWAT         Last cell in the water
      CONDM         Metal conductivity
      CONDW         Water conductivity
  ENDDIS

REAL(WIN,QDOT,CP,CONDM,CONDW);INTEGER(IYMET,IYWAT)
WIN=.01;QDOT=1000.;CP=4184.0;IYMET=21;IYWAT=IYMET-1
CONDM=36.2;CONDW=0.6
    GROUP 2. Transience; time-step specification
    GROUP 3. X-direction grid specification
CARTES=F
    GROUP 4. Y-direction grid specification
NY=30;YVLAST=0.024;YFRAC(1)=-20.0;YFRAC(2)=4.166E-02
YFRAC(3)=10.0;YFRAC(4)=1.6666E-02
    GROUP 5. Z-direction grid specification
GRDPWR(Z,20,0.4,2.0)
    GROUP 6. Body-fitted coordinates or grid distortion
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1,TEMP)
STORE(VISC,DIFS)
    Activate harmonic averaging
SOLUTN(V1,P,P,P,P,P,Y);SOLUTN(W1,P,P,P,P,P,Y)
SOLUTN(TEMP,P,P,P,P,P,Y)
    GROUP 8. Terms (in differential equations) & devices
    GROUP 9. Properties of the medium (or media)
RHO1=1000.0
ENUL=GRND
PRNDTL(TEMP)=-GRND

     PLANTBEGIN
   VISL=VISC
   LAMPR(TEMP)=DIFS
     PLANTEND

    GROUP 10. Inter-phase-transfer processes and properties
    GROUP 11. Initialization of variable or porosity fields
FIINIT(W1)=WIN
     Viscosity
PATCH(VISCW,INIVAL,1,1,1,IYWAT,1,NZ,1,1)
INIT(VISCW,VISC,0.0,1.e-6)
PATCH(VISCM,INIVAL,1,1,IYMET,NY,1,NZ,1,1)
INIT(VISCM,VISC,0.0,1.e10)
     Diffusivity
PATCH(KOVRW,INIVAL,1,1,1,IYWAT,1,NZ,1,1)
INIT(KOVRW,DIFS,0.0,CONDW/RHO1/CP)
PATCH(KOVRM,INIVAL,1,1,IYMET,NY,1,NZ,1,1)
INIT(KOVRM,DIFS,0.0,CONDM/RHO1/CP)
    GROUP 13. Boundary conditions and special sources
PATCH(INLET,LOW,1,1,1,IYWAT,1,1,1,1)
COVAL(INLET,P1,FIXFLU,1000.0*WIN);COVAL(INLET,W1,ONLYMS,WIN)
COVAL(INLET,TEMP,ONLYMS,0.0)
     Pipe material:  set velocities to zero.
PATCH(SOLIDW,CELL,1,1,IYMET,NY,1,NZ,1,1)
COVAL(SOLIDW,W1,FIXVAL,0.0)
PATCH(SOLIDV,CELL,1,1,IYWAT,NY,1,NZ,1,1)
COVAL(SOLIDV,V1,FIXVAL,0.0)
     Outer pipe wall:  uniform heat flux
PATCH(OUTER,NORTH,1,1,NY,NY,1,NZ,1,1)
COVAL(OUTER,TEMP,FIXFLU,QDOT/CP)
     Exit condition on water pressure
PATCH(EXIT,HIGH,1,1,1,IYWAT,NZ,NZ,1,1)
COVAL(EXIT,P1,1000.,0.0)
    GROUP 15. Termination of sweeps
LSWEEP=120
    GROUP 16. Termination of iterations
    GROUP 17. Under-relaxation devices
RELAX(V1,FALSDT,ZWLAST/WIN);RELAX(W1,FALSDT,ZWLAST/WIN)
    GROUP 18. Limits on variables or increments to them
    GROUP 19. Data communicated by satellite to GROUND
NAMSAT=MOSG
    GROUP 20. Preliminary print-out
    GROUP 21. Print-out of variables
    GROUP 22. Spot-value print-out
IYMON=6;IZMON=NZ-1
    GROUP 23. Field print-out and plot control
NYPRIN=1;NZPRIN=1
dmpstk=t
tstswp=-1
DISTIL=T
EX(P1)=5.036E+07; EX(V1)=7.972E-05; EX(W1)=7.603E-03
EX(DIFS)=2.980E-06; EX(VISC)=3.333E+09; EX(TEMP)=1.913E+00
 LIBREF=123
STOP