PHOTON USE
p
gr ou z 1
gr ou z 1 x 5 9 y 1 6
gr ou z 1 x 15 19 y 1 9
gr ou z 1 x 6 6 y 5 5
gr ou z 1 x 8 8 y 5 5
gr ou z 1 x 6 6 y 2 3
gr ou z 1 x 8 8 y 2 3
gr ou z 1 x 16 16 y 2 3
gr ou z 1 x 16 16 y 5 5
gr ou z 1 x 16 16 y 7 7
gr ou z 1 x 18 18 y 2 3
gr ou z 1 x 18 18 y 5 5
gr ou z 1 x 18 18 y 7 7
VEC z 1 sh
red
msg VEHICULAR EXHAUST DISPERSION
msg Velocity vectors
msg Press Enter to continue
pause
vec off;red
con h1 z 1 fil;.5
msg VEHICULAR EXHAUST DISPERSION
msg NOx concentration
VEC z 1 sh
msg Press E to end
ENDUSE
***************************************************************
*
* GROUP 1. Run title and other preliminaries.
*
TEXT(EXHAUST DISPERSION IN THE STREET:141
*
DISPLAY
This case shows how to apply PLANT to introduce the traffic
induced turbulent diffusion for the problem of vehicular
exhaust dispersion in the street canyon.
It is assumed that by the order of magnitude the traffic
caused turbulent kinematic viscosity is the length scale
squared times relative velocity divided by car size. The
length scale is choosed as smallest of Prandtl mixing length
and constant times the car size as set in Group 9 ( see the
line marked PRPT1 ).
The layer under influence is located in a few slabs over the
ground of street canyon.
ENDDIS
***************************************************************
* GROUP 3. X-direction grid specification.
CARTES=T
NX=23
SUBGRD(X,1,4, 2.000E+01, 1.000E+00)
INTEGER(NXF01,NXL01); NXF01=1; NXL01=4
SUBGRD(X,5,9, 1.000E+01, 1.000E+00)
INTEGER(NXF02,NXL02); NXF02=5; NXL02=9
SUBGRD(X,10,14, 2.000E+01, 1.000E+00)
INTEGER(NXF03,NXL03); NXF03=10; NXL03=14
SUBGRD(X,15,19, 1.000E+01, 1.000E+00)
INTEGER(NXF04,NXL04); NXF04=15; NXL04=19
SUBGRD(X,20,23, 2.000E+01, 1.000E+00)
INTEGER(NXF05,NXL05); NXF05=20; NXL05=23
***************************************************************
* GROUP 4. Y-direction grid specification.
NY=14
SUBGRD(Y,1,3, 5.000E+00, 1.000E+00)
INTEGER(NYF01,NYL01); NYF01=1; NYL01=3
SUBGRD(Y,4,6, 1.000E+01, 1.000E+00)
INTEGER(NYF02,NYL02); NYF02=4; NYL02=6
SUBGRD(Y,7,9, 1.000E+01, 1.000E+00)
INTEGER(NYF03,NYL03); NYF03=7; NYL03=9
SUBGRD(Y,10,14, 2.500E+01, 1.000E+00)
INTEGER(NYF04,NYL04); NYF04=10; NYL04=14
***************************************************************
* GROUP 7. Variables stored, solved & named.
SOLVE(P1,U1,V1)
SOLVE(H1,EDDY)
STORE(PRPS)
***************************************************************
* GROUP 8. Terms (in differential equations) & devices.
TERMS(H1,N,Y,Y,N,Y,N)
TERMS(EDDY,N,N,N,N,Y,N)
***************************************************************
* GROUP 9. Properties of the medium (or media).
RHO1= 1.0;ENUL= 1.5E-05
REAL(CP1); CP1= 1.0E+03
REAL(KCOND1); KCOND1= 1.0E-02
PRNDTL(H1)=CP1*ENUL*RHO1/KCOND1
* Set Turbulent Kinematic Viscosity Value
ENUT=GRND
***************************************************************
* GROUP 11. Initialization of variable or porosity fields.
FIINIT(U1)= 2.000E+00
FIINIT(H1)= 0.000E+00
FIINIT(EDDY)=1.
* Obstructed Region, Number 1
CONPOR(0.0,CELL,-NXF02,-NXL02,-NYF01,-NYL02,1,1)
* Obstructed Region, Number 2
CONPOR(0.0,CELL,-NXF04,-NXL04,-NYF01,-NYL03,1,1)
***************************************************************
* GROUP 13. Boundary conditions and special sources.
* INLET Boundary Condition, Named INLET
PATCH(INLET,WEST,NXF01,NXF01,NYF01,NYL04,1,1,1,1)
COVAL(INLET,P1,FIXFLU,RHO1* 2.000E+00)
COVAL(INLET,U1,ONLYMS, 2.000E+00)
COVAL(INLET,V1,ONLYMS, 0.000E+00)
COVAL(INLET,H1,ONLYMS, 0.000E+00)
* OUTLET Boundary Condition, Named OUTLET
PATCH(OUTLET,EAST,NXL05,NXL05,NYF01,NYL04,1,1,1,1)
COVAL(OUTLET,P1,FIXP, 0.000E+00)
COVAL(OUTLET,H1,ONLYMS,SAME)
* OUTLET Boundary Condition, Named OUTUP
PATCH(OUTUP,NORTH,NXF01,NXL05,NYL04,NYL04,1,1,1,1)
COVAL(OUTUP,P1,FIXP, 0.000E+00)
COVAL(OUTUP,H1,ONLYMS,SAME)
* VEHICULAR EXHAUST SOURCE Boundary Condition, Named ROAD
PATCH(ROAD,CELL,NXF03,NXL03,NYF01,NYL01,1,1,1,1)
COVAL(ROAD,H1,FIXFLU, 1.000E-02)
***************************************************************
* GROUP 15. Termination of sweeps.
LSWEEP=50
RESREF(P1)= 1.000E-06
RESREF(U1)= 1.000E-06
RESREF(V1)= 1.000E-06
RESREF(H1)= 1.000E-06
***************************************************************
* GROUP 17. Under-relaxation devices.
RELAX(P1,LINRLX, 5.000E-01)
RELAX(U1,FALSDT, 1.000E+01)
RELAX(V1,FALSDT, 1.000E+01)
RELAX(H1,FALSDT, 1.000E+03)
***************************************************************
* GROUP 19. Data communicated by satellite to GROUND.
NAMSAT=MOSG
***************************************************************
* GROUP 20. Preliminary print-out.
***************************************************************
* GROUP 21. Print-out of variables.
OUTPUT(P1,Y,N,N,Y,Y,Y)
OUTPUT(U1,Y,N,N,Y,Y,Y)
OUTPUT(V1,Y,N,N,Y,Y,Y)
OUTPUT(H1,Y,N,N,Y,Y,Y)
OUTPUT(EDDY,Y,N,N,N,N,N)
***************************************************************
* GROUP 22. Spot-value print-out.
IXMON=12;IYMON=3
***************************************************************
* GROUP 23. Field print-out and plot control.
ITABL=3
PATCH(PROFVEL,PROFIL,1,26,6,6,1,1,1,1)
PLOT(PROFVEL,U1, 0.000E+00, 0.000E+00)
PATCH(CONTEMP,CONTUR,1,26,1,13,1,1,1,1)
PLOT(CONTEMP,H1, 0.000E+00, 1.000E+01)
PLANTBEGIN
* Set Turbulent Kinematic Viscosity Value
VIST=6.7*EDDY
* EDDY viscosity function, Named EDVIS
PATCH(EDVIS,CELL,10,14,1,3,1,1,1,1)
VAL=(AMIN1(0.4*YG2D,0.6*2.))**2$
*(400.+V1**2)**0.5/(1.8*2.*6.7)
COVAL(EDVIS,EDDY,FIXVAL,GRND )
PLANTEND
tstswp=-1
dmpstk=t
DISTIL=T
EX(P1)=1.308E+00; EX(U1)=1.057E+00; EX(V1)=4.446E-01
EX(H1)=3.413E-03; EX(PRPS)=4.689E+01
EX(VPOR)=7.671E-01; EX(EDDY)=7.533E-01
LIBREF=141
STOP