PHOTON USE
  p;;;;
 
  con c1 z 1 fi;0.02
  msg contours of reactedness; x=distorted distance; y=multiplier-1
  pause;con c2 z 1 fi;0.02
  msg contours of reaction rate; x=distorted dist.; y=multiplier-1
  ENDUSE
 
  DISPLAY
 
  This case illustrates the use of PLANT for creating a source which
  is dependent on both the dependent variable (C1) and the
  independent variable (X), which is a requirement for the method of
  simulation of laminar flame propagation which employs
      x = exp(-const * distance)      as the independent variable.
 
  It also illustrates the use of the y dimension as a parametric
  multiplier, thus allowing the multiplying constant of the reaction
  rate to have ten (ie NY) values in a single run.
 
  This device is often useful when parametric studies have to be
  made; for it also permits PHOTON to be used for display purposes.
 
  A PHOTON USE file is supplied in this Q1.
  ENDDIS

  Group 1. Run Title
 TEXT(Steady lam. fl. propagation   :Z251
 TITLE
 ************************************************************
  Group 2. Transience
 STEADY  =    T
 ************************************************************
GRDPWR(X,100,1.0,1.0);GRDPWR(Y,50,1.0,1.0)
 ************************************************************
  Group 7. Variables: STOREd,SOLVEd,NAMEd
 
   C1 is the reactedness, c2 the volumetric reaction rate
   NPOR is stored, and set to zero, in order that there shall
   be no influence of one y-value solution on another.
 
 SOLVE(C1,C2);STORE(NPOR)
 
 TERMS(C1,N,N,Y,P,P,P);TERMS(C2,N,N,N,N,N,N)
 ************************************************************
  Group 9. Properties
ENUL=1.0
 ************************************************************
  Group 11.Initialise Var/Porosity Fields
 ************************************************************
FIINIT(C1)=0.5;FIINIT(NPOR)=0.0
  Group 13. Boundary & Special Sources
 ************************************************************
 
PATCH(MINUSINF,WEST,1,1,1,NY,1,1,1,1);COVAL(MINUSINF,C1,FIXVAL,0.0)
 
PATCH(DOWNSTRM,EAST,NX,NX,1,NY,1,1,1,1);COVAL(DOWNSTRM,C1,1.E5,1.0)
 
  PLANT inserts reaction-rate expression..
  rate = rconst * c1**n * (1-c1) / ((n+1)*(n+2))
  with further division by x**2 because x is a distorted scale
  and multiplication by (1+y) for the purpose of parametric study.
 
REAL(RCONST,EXPO)
RCONST=0.2;EXPO=6.0
 TEXT(Steady lam. fl. prop.; const=(1+y)*:rconst:   :Z251
RCONST=RCONST*(EXPO+1)*(EXPO+2)

    PLANTBEGIN
PATCH(REACRATE,VOLUME,1,NX,1,NY,1,1,1,1)
   CO= :RCONST:*C1**:EXPO:*XG2D**(-2)*(1.0+YG2D)
   VAL=1.0
COVAL(REACRATE,C1,GRND,GRND)
   VAL= :RCONST:*C1**:EXPO:*(1.0+YG2D)*(1-C1)
COVAL(REACRATE,C2,FIXVAL,GRND)
    PLANTEND
 
 ************************************************************
lsweep=400
 ************************************************************
  Group 19. EARTH Calls To GROUND Station
 NAMSAT=MOSG
 ************************************************************
  Group 21. Print-out of Variables
 ************************************************************
  Group 22. Monitor Print-Out
 TSTSWP  =      1;NPLT=1;IXMON=NX/2;IYMON=NY/2
 ************************************************************
  Group 23.Field Print-Out & Plot Control
 PATCH(PROFILE,PROFIL,1,NX,1,1,1,1,1,1)
 COVAL(PROFILE,C1,0.0,00)
 ************************************************************
   No PATCHes used for this Group
  Group 24. Dumps For Restarts
 LIBREF=251

tstswp=-1
dmpstk=t
DISTIL=T
 LIBREF=251
EX(C1)=6.872E-01; EX(C2)=2.961E-01; EX(NPOR)=1.000E-11
STOP