#$r002
   PHOTON USE
   AUTOPLOT
   file
   phi 5
 
   cl
   da 1 tem1
   col3 1
   blb2 1
   le y 843
   sca y 840 1000                                                               
   k                                                                            
   13                                                                             
   0.61220E+03 0.28080E+04  a                                                   
   0.38150E+04 0.46800E+03                                                      
   0.38150E+04 0.46800E+03  x
   r
   msg Temperature profile
   msg Analytical solution shows that TW=843K (right side)
   msg Orange line - analytical solution                                               
   msg Blue squares- PHOENICS solution                                                 
   ENDUSE
 
   *  GROUP 1.  Run identifiers and other preliminaries.
TEXT(1-D Y-DIRECTION SHELL SURFACE: R108
TITLE
  DISPLAY
   The features tested are:
   * Internal surface-to-surface radiation
   * External radiation of a surface
   * Heat conduction
        __________________________
      /|                         |/   Text=293K
      /|                         |/
      /|       AIR               |/
      /|       PRPS=0            |/
      /|                         |/
      /|<---Radiative zone 1     |/
      /|                         |/
      /|<---TL=1000K             |/<----TW
       |________________________ |
        ----------> Y
        length of domain = 1.0 m, height of domain = 1.0m
 
   The problem is steady, one-dimensional and convection is absent.
   The surface temperature at the left side is 1000K
   The surface at the right side radiates to an external temperature
   of 293K. The surface temperature of the right side, Tw, is
   calculated.

   The PHOENICS solution can be compared with the analytical
   solution which shows that TW=843K, and the net radiative flux
   at zone 2 = 28.12kW/m2
  ENDDIS
   ************************************************************
   *  User declared Real variables
   *  GROUP 4.  y-direction grid specification.
GRDPWR(Y,4,1.,-1.60)
   ************************************************************
   *  GROUP 7.  Variables (including porosities) named,
   *            stored & solved.
SOLVE(TEM1);SOLUTN(TEM1,Y,Y,Y,N,N,Y)
STORE(PRPS)
   ************************************************************
   *  GROUP 8.  Terms (in differential equations) and devices.
   ************************************************************
   *  GROUP 9.  Properties of the medium (or media).
   *  Fluid/medium is constant-property air
SETPRPS(1,0)
PRESS0=1.0000E+05;TEMP0=0
 
 
FIINIT(TEM1)=293.
   ************************************************************
   *  GROUP 13. Boundary conditions and special sources
   * WALL boundary condition, name TFIXR to set the fixed TR
     for the conductive boundary condition
PATCH(TFIXR,SWALL,#1,#1,#1,#1,#1,#1,#1,#NREGT)
COVAL(TFIXR,TEM1,1.,1000.)
   * Radiative zones have PATCH name of the form @RI###, ###
     are digits indicating the zone number. @RI indicates
     that the PATCH is for an internal radiating zone.
   * Radiation zone 1. This zone is located at the left
     wall and has a fixed temperature boundary condition.
     The COefficient is set to 0.0 and VALue to the
     required surface temperature.
PATCH(@RI001,SOUTH,#1,#1,1,1,#1,#1,#1,#NREGT)
COVAL(@RI001,TEM1,0.0,1000.)
   * Radiation zone 2. This zone is located at the right
     wall and has a calculated temperature.
     The COefficient is set to GRND2 and VALue set to
     the imposed heat flux.
PATCH(@RI002,NORTH,#1,#1,#1,#1,#1,#1,#1,#nregt)
COVAL(@RI002,TEM1,GRND2,0.0)
   * Radiation zone 2 also radiates to an external temperature
     The PATCH name for the external radiation heat transfer
     must start with @ER, and has to be of type area
     CO is set to the radiative exchange coefficient and
     VAL is set to the external temperature.
PATCH(@ER001,NORTH,#1,#1,#1,#1,#1,#1,#1,#1)
COVAL(@ER001,TEM1,SIGMA,293)
   ************************************************************
   *  GROUP 15. Termination criteria for sweeps and
   *            outer iterations.
LSWEEP=9;TSTSWP=-1
   ************************************************************
   *  GROUP 16. Termination criteria for inner iterations.
RESREF(TEM1)=1.E-12*55000.
S2SR=t
spedat(set,cvd,radcvd,l,t)
 LIBREF  =       108
STOP