TALK=f;RUN(1,1)
  DISPLAY
  similar to s208
  Problem: Plate is composed of two Horizontal materials with ten-fold difference
           in Young's modulus. 
   Case 1: 'plane stress', z-surface free
   Case 2:  'plane strain', z-surface fixed
   Used Boundary Flow-Layers  

  PHOTON USE
  p;;;;
  
  

  set prop off
  cl
  msg x-displacement fields
  gr ou z 1
  cont U1 z 1 x 1 19 y 2 19 fil;.0001
  pause
  cl
  msg y-displacement fields
  gr ou z 1
  cont V1 z 1 x 2 19 y 1 19 fil;.0001
  vec z 1 x 1 20 y 1 20 col 0
  pause


  ENDDIS

 ************************************************************
  Group 1. Run Title and Number
 ************************************************************
 TEXT(Plate of two Horizontal materials; 2D[xy])
integer(caseno)     
mesg(caseno = 1 : z free
mesg(caseno = 2 : z fixed
caseno=1
label ask
mesg(caseno=:caseno: Enter 1, 2 or blank
readvdu(caseno,int,1)
if(caseno.lt.1) then
 goto ask
endif  
if(caseno.gt.2) then
 goto ask
endif 
caseno
libref=caseno 
  Declarations and settings
REAL(FY,LX,LY,POISSON,YOUNG) 
FY= 40.0e6  ! H/m^2 = 40 N/mm^2
LX=90.e-3
LY=120.e-3 
INTEGER(NXBODY,NYBODY)

 ************************************************************
  Group 2. Time dependence
 STEADY  =    T
 ************************************************************
  Group 3. X-Direction Grid Spacing
 CARTES  =    T
 NXBODY = 18
 NREGX=3                             ! 3 regions
 IREGX=1;GRDPWR(X,1,0.01*LX,1.0)     ! single inner fluid cell
 IREGX=2;GRDPWR(X,NXBODY,LX,1)  
 IREGX=3;GRDPWR(X,1,0.01*LX,1.0)     ! single outer fluid cell 

 ************************************************************
  Group 4. Y-Direction Grid Spacing
 NYBODY = 18
 NREGY=3                             ! 3 regions
 IREGY=1;GRDPWR(Y,1,0.01*LY,1.0)     ! single inner fluid cell
 IREGY=2;GRDPWR(Y,NYBODY,LY,1)  
 IREGY=3;GRDPWR(Y,1,0.01*LY,1.0)     ! single outer fluid cell 
 ************************************************************
  Group 5. Z-Direction Grid Spacing
 NZ=1
 ZWLAST  = 0.001
 ************************************************************
  Group 7. Variables: STOREd,SOLVEd,NAMEd
 ONEPHS  =    T
 SOLVE(P1,V1,U1)
 SOLUTN(P1  ,Y,Y,Y,N,N,N)
 SOLUTN(U1  ,Y,Y,Y,N,N,Y)
 SOLUTN(V1  ,Y,Y,Y,N,N,Y)
 
 STORE(PRPS)
 STORE(STRX,STRY,STRZ,STXY)
 STORE(EPSY,EPSX,EPSZ)
 ************************************************************
  GROUP 8. ITERATION NUMBERS ETC
RESFAC=1.e-7
RESREF(V1)=0.0 
RESREF(U1)=0.0
LITER(V1) = 50
LITER(U1) = 50 
LITER(P1) = 50 

 ************************************************************
  GROUP 9. PROPERTIES
  
 CSG10='Q1'                  ! materials with various POISSON ratios
  MATFLG=T;NMAT=2         
  160    7800.0    0.3       473.0   43.0      1.0e-5   0.5e-11 
  161    7800.0    0.3       473.0   43.0      1.0e-5   0.5e-10
 
 ************************************************************
  GROUP 11. INITIAL VALUES
fiinit(p1)=0.0
fiinit(u1)=0.0
fiinit(v1)=0.0
 
 FIINIT(PRPS)=0
 PATCH(BODY1,INIVAL,2,NX-1,2,NY/2,1,1,1,1)
 INIT(BODY1,PRPS,FIXVAL,160)
 PATCH(BODY2,INIVAL,2,NX-1,NY/2+1,NY-1,1,1,1,1)
 INIT(BODY2,PRPS,FIXVAL,161)
 ************************************************************
  GROUP 13. BOUNDARY & SPECIAL SOURCES
 
PATCH(UP,north,1,NX,NY-1,NY-1,1,1,1,1) ! top - fixed V1
COVAL(UP,V1,FIXVAL,0.0)
PATCH(POINTU,CELL,1,1,NY-1,NY-1,1,1,1,1)  !  top-left - fixed U1
COVAL(POINTU,U1,FIXVAL,0)

   *** bottom - upward force
PATCH(FORC01,NORTH,2,NX-1,1,1,1,1,1,1)
COVAL(FORC01,V1,FIXFLU,FY)

PATCH(PRESS,CELL,1,NX,1,NY,1,NZ,1,1)
COVAL(PRESS,P1,FIXVAL,0)


IF(CASENO.EQ.2) THEN
SPEDAT(BOUNDARY,ZCONST,R,1.e20)
ELSE
SPEDAT(BOUNDARY,ZCONST,R,0.0)
ENDIF 
 ************************************************************
  GROUP 15. TERMINATE SWEEPS
 LSWEEP  =      1800
 ISG21=LSWEEP
 ************************************************************
  GROUP 17. RELAXATION
     #CONPROM
 RELAX(P1  ,LINRLX, 1.000000E+00)

      spedat(rlxfac,rlxu1d,r,0.3)  
      spedat(rlxfac,rlxv1d,r,0.3)  
 
 ************************************************************
  GROUP 19. DATA TRANSMITTED TO GROUND
 STRA    =    T
 PARSOL  =    F
 ISG52   =    3   !   probe & res

 ************************************************************
  GROUP 23.FIELD PRINT-OUT & PLOT CONTROL
TSTSWP = - 1   ! graphic-mode
NYPRIN = 1
IXMON = NX-2
IYMON = 2
IZMON = 1
      #conprom 


STOP