TALK=F;RUN(1,1)                                           
  DISPLAY
  The steep propagating 1DY wave.
  ENDDIS

  PHOTON USE 
  p;parphi 
  1 1 4000
  
  clear
  set prop off
  view x
  gr ou x 1
  con disy x 1 fi;0.0001
  msg DISY(Y,Z=Time)
  pause
  
  
  autoplot 
  FILE 
  parphi 5 

  clear
  data 1                                                                          
  DISY Z 10 Y 1 m                                                                 
  col1 1          
  data 1                                                                          
  DISY Z 20 Y 1 m                                                                   
  colA 2          
  data 1                                                                          
  DISY Z 40 Y 1 m                                                                   
  colF 3          
  scale
  plot 1 2 3                                                                      
  msg DISY(Y) for Time=10(W),20(Y),40(R)
  pause

  clear
  data 1                                                                          
  DISY Y 50 Z 1 m                                                                    
  col1 1          
  scale
  plot 1                                                                      
  msg DISY(Time) for Y=LY/2
  pause

  ENDUSE 

 ************************************************************
  Group 1. Run Title and Number
 ************************************************************
TEXT(The steep propagating 1DY wave; S674
libref=674
TITLE
 
  Declarations and settings
REAL(LXZ,LY,POISSON,YOUNG) 
LXZ=40.e-3
LY=120.e-3 
YOUNG   = 1/0.5E-11   ! Young's modulus used for exact solutions
POISSON=0.3           ! Poisson's ratio used for exact solutions
                      ! The above must correspond to the data
                      ! below MATFLG
INTEGER(NYBODY)
 NYBODY = 120

real(D0,SSound,V0,DY00, TimeMax)
D0 = 1.e-6
SSound = (YOUNG/7800.0)**0.5
DY00 = LY/NYBODY
V0 = SSound*D0/(2.0*DY00)
TimeMax = 2.0*LY/SSound


 ************************************************************
  Group 2. Time dependence
 STEADY  =    F
 RSET(U,0,TimeMax,100)

 ************************************************************
  Group 3. X-Direction Grid Spacing
 CARTES  =    T
 GRDPWR(Y,NYBODY,LY,1)  

 ************************************************************
  Group 4. Y-Direction Grid Spacing
 NX = 1
 XULAST = LXZ 
 
 ************************************************************
  Group 5. Z-Direction Grid Spacing
 NZ=1
 ZWLAST  = LXZ
 ************************************************************
  Group 7. Variables: STOREd,SOLVEd,NAMEd
 ONEPHS  =    T
 SOLVE(DISY)
 TERMS (DISY,N,N,Y,Y,Y,N)
 STORE(VDSY)
 
 STORE(PRPS,DEN1,ENUL,DVO1,DRH1)
 STORE(EPSY,EPSX,EPSZ)

 ************************************************************
  GROUP 8. ITERATION NUMBERS ETC

 ************************************************************
  GROUP 9. PROPERTIES
  
 CSG10='Q1'                  ! materials with various POISSON ratios
  MATFLG=T;NMAT=1         
  160    7800.0    0.3       473.0   43.0      1.0e-5   0.5e-11 
   
 ************************************************************
  GROUP 11. INITIAL VALUES

FIINIT(DISY)=0.0
FIINIT(VDSY)=0.0
FIINIT(PRPS)=160

RELAX(DISY,LINRLX, 1.000000E+00)

  *** Initial Conditions *** 
PATCH(InBl10,INIVAL,1,1,1,10,1,1,1,1)
INIT(InBl10,DISY,FIXVAL,D0)

PATCH(InBl11,INIVAL,1,1,11,11,1,1,1,1)
INIT(InBl11,DISY,FIXVAL,D0/2.0)
INIT(InBl11,VDSY,FIXVAL,V0)

PATCH(InBl12,INIVAL,1,1,12,12,1,1,1,1)
INIT(InBl12,VDSY,FIXVAL,V0)


 ************************************************************
  GROUP 13. BOUNDARY & SPECIAL SOURCES
 
PATCH(Bottom,SWALL,1,1,1,1,1,1,1,LSTEP)    ! Bottom end fixed 
COVAL(Bottom,DISY,1,D0)
PATCH(Top,NWALL,1,1,NY,NY,1,1,1,LSTEP)    ! top end fixed 
COVAL(Top,DISY,1,0.0)

 ************************************************************
  GROUP 15. TERMINATE SWEEPS
 LSWEEP  =    60  
 ISG21=LSWEEP
  
 
 ************************************************************
  GROUP 17. RELAXATION
 RELAX(P1  ,LINRLX, 1.000000E+00)
 ************************************************************
  GROUP 19. DATA TRANSMITTED TO GROUND
 STRA    =    T
 PARSOL  =    F
 ISG52   =    3   !   probe & res

 ************************************************************
  GROUP 23.FIELD PRINT-OUT & PLOT CONTROL
TSTSWP = - 1   ! graphic-mode
IXMON = NY/2
IYMON = 1
IZMON = 1

IDISPA = 1

  inform7begin
 
  inform7end
  
  
STOP