GROUP 1. Run title and other preliminaries
TEXT(CHEN-KIM K-E_1D PLANE COUETTE FLOW :T100
TITLE
mesg(PC486/50 time last reported as appx. 30.sec
  DISPLAY
  The problem considered is turbulent couette flow in a plane
  channel with one moving wall. The shear stress is uniform
  across the flow and hence the axial pressure-gradient is zero.
  The velocity profile has an S-shape and is symmetrical about
  the central plane, and so the average velocity is one half of
  the velocity of the moving wall. In the calculation made here
  the Reynolds number is 1.E5 and it is based on the channel
  height and the average velocity.
  ENDDIS
 
  Calculations with the standard k-e model plus wall functions
  show that the turbulent kinetic energy k is essentially
  uniform across the flow. This result is in accordance with the
  exact solution of the k-e model equations reported by Henry
  and Reynolds [1984], but not with the experimental data reported
  in the literature, which shows that k is about 70% larger near
  the walls than it is at the centre plane. Gibson [1988] and
  Schneider [1988] have demonstrated that the inclusion of a
  counter-gradient diffusion term in the k-equation leads to very
  good agreement the measured k profiles.
 
  Calculations may be made with the high-Re forms of either
  the k-e model, the Chen-Kim k-e model, the RNG k-e model,
  and the Wilcox k-omega model. For this case all models produce
  similar results.
 
   The following AUTOPLOT use file produces two plots;
   the first is the axial velocity profile; and the
   second is the turbulence energy profile.
 
   AUTOPLOT USE
   file; phi 5
 
   cl; da 1 w1; col9 1
   msg        Velocity (W1) profile; Press RETURN to continue
   pause; cl; da 1 ke; col9 1; scale y 0. 2.e-3; redraw
   msg        KE profile. Press RETURN, then e to END
   pause
   ENDUSE
 
CHAR(CTURB,TLSC)
REAL(HEIGHT,WTOP,REY,TKEIN,EPSIN,MIXL,DTF,WAV,WSTAR,MASIN)
HEIGHT=0.1;WTOP=1.0; REY=1.E5;WAV=0.5*WTOP
  ** wstar from data of El Telbany & Reynolds [1982]
WSTAR=WAV*0.196/LOG10(REY);TKEIN=WSTAR*WSTAR/.3
MIXL=0.045*HEIGHT;EPSIN=TKEIN**1.5/MIXL*0.1643
    GROUP 4. Y-direction grid specification
ENUL=WAV*HEIGHT/REY;NY=30;YVLAST=HEIGHT;GRDPWR(Y,NY,YVLAST,1.0)
DTF=20.*ZWLAST/WAV
    GROUP 7. Variables stored, solved & named
SOLVE(W1);STORE(ENUT,LEN1);SOLUTN(W1,P,P,P,P,P,N)
MESG( Enter the required turbulence model:
MESG(  CHEN -  Chen-Kim k-e model (default)
MESG(  KE   -  Standard k-e model
MESG(  KO   -  Wilcox   k-o model
MESG(  RNG  -  RNG      k-e model
MESG(
READVDU(CTURB,CHAR,CHEN)
CASE :CTURB: OF
WHEN CHEN,4
+ MESG(Chen-Kim k-e model
+ TURMOD(KECHEN);KELIN=1;TLSC=EP
WHEN KE,2
+ TEXT(K-E_1D PLANE COUETTE FLOW :T100
+ MESG(Standard k-e model
+ TURMOD(KEMODL);KELIN=1;TLSC=EP
WHEN KO,2
+ TEXT(K-OMEGA_1D PLANE COUETTE FLOW :T100
+ MESG(k-omega model
+ TURMOD(KOMODL);TLSC=OMEG
+ STORE(EP);EPSIN=EPSIN/(0.09*TKEIN)
WHEN RNG,3
+ TEXT(RNG K-E_1D PLANE COUETTE FLOW :T100
+ MESG(RNG k-e model
+ TURMOD(KERNG);KELIN=1;TLSC=EP
+ STORE(ETA,ALF,GEN1)
+ OUTPUT(ALF,Y,N,P,Y,Y,Y);OUTPUT(ETA,Y,N,P,Y,Y,Y)
+ DTF=2.*ZWLAST/WAV
ENDCASE
    GROUP 8. Terms (in differential equations) & devices
  Deactivate convection
TERMS(W1,N,N,P,P,P,P);TERMS(KE,Y,N,P,P,P,P)
TERMS(:TLSC:,Y,N,P,P,P,P)
    GROUP 11. Initialization of variable or porosity fields
FIINIT(W1)=0.5*WTOP;FIINIT(:TLSC:)=EPSIN;FIINIT(KE)=TKEIN
    GROUP 13. Boundary conditions and special sources
  ** moving upper wall
WALL(WALLN,NORTH,1,1,NY,NY,1,NZ,1,1);COVAL(WALLN,W1,LOGLAW,WTOP)
  ** stationary bottom wall
WALL(WALLS,SOUTH,1,1,1,1,1,NZ,1,1)
    GROUP 15. Termination of sweeps
LSWEEP=10;LITHYD=20
    GROUP 16. Termination of iterations
MASIN=RHO1*WAV*HEIGHT; RESREF(W1)=1.E-12*MASIN*WAV
RESREF(KE)=RESREF(W1)*TKEIN; RESREF(:TLSC:)=RESREF(W1)*EPSIN
    GROUP 17. Under-relaxation devices
VARMIN(W1)=1.E-10;WALPRN=T
    GROUP 22. Spot-value print-out
IYMON=NY-2;NPLT=1;NZPRIN=1;NYPRIN=1;IYPRF=1;TSTSWP=-1
    GROUP 24. Dumps for restarts
RELAX(W1,FALSDT,DTF); RELAX(KE,FALSDT,DTF); RELAX(EP,FALSDT,DTF)