TEXT(CHEN KIM K-E MODEL_PARAB ROUND JET :T105
TITLE
  DISPLAY
  The problem considered is the submerged free heated
  turbulent round jet in stagnant surroundings. The calculations 
  are started at the jet discharge, and the parabolic marching
  integration is carried out until both the mean flow and
  turbulence profiles become self similar.
 
  The calculations are made with 80 grid cells across the jet
  and a forward step size of 2% (DZW1) of the local jet width.
  The y-extent of the grid is set equal to the diameter at z=0,
  thereafter being caused to increase linearly with downstream
  distance so as to accommodate the radial spread of the jet. The
  number of forward steps NZ is set equal to 520, so that the 
  marching integration is terminated at an axial distance of 
  about 50 diameters from the jet discharge.
  ENDDIS
 
  Calculations may be performed with the standard, Chen-Kim, RNG and
  Realisable k-e models, and also with the Wilcox k-w model. The
  turbulent Prandtl number is set equal to 0.7.
 
  The experimental data indicate velocity and temperature half-
  width spreading rates of dyw/dz=0.086 and dyt/dz=0.11 in the
  self-similar region of the jet. The present calculations predict
  the following spreading rates:
 
             data    k-e   chen-kim    RNG     k-w    Real.k-e
     dyw/dz  0.086  0.116   0.117     0.169   0.248     0.088
     dytdz   0.11   0.127   0.134     0.213   0.323     0.106
 
  All models with the exception of the realisable k-e model seriously
  overpredict the measured spreading rates,and the Wilcox k-w
  model fares the worst producing excessive values. The k-W model 
  solution is known to be fairly sensitive to the free-stream value 
  of w. 
 
  AUTOPLOT USE
  file                                                                            
  iy1.csv 2                                                                       
                                                                                
  d 1 z yhlf;d 1 z yhlt;col3 1;colf 2   
  redr
  msg half-width spreading rates
  msg Press e to END
  ENDUSE
  PHOTON USE
     P
   PARADA
 
 
    0.20443E+04 0.15633E+04 CR
   GR OU X 1;VEC X 1 SH;
   PAUSE
   CL;GR OU X 1;CON ENUT X 1 FI;1
   PAUSE
  ENDUSE
CHAR(CTURB,TLSC)
INTEGER(JKO);JKO=0
REAL(WJET,REYNO,DIAM,TJET,TFREE,TKEIN,EPSIN,EPSFRE,ENULAM)
REAL(TKEFRE,WFREE)
REYNO=5.E5;DIAM=0.1;WJET=10.0;TJET=1.0;TFREE=0.0
ENULAM=WJET*DIAM/REYNO
WFREE=1.E-4*WJET
TKEFRE=(0.01*WFREE)**2;EPSFRE=0.09*TKEFRE**2/ENULAM
TKEIN=(0.05*WJET)**2;EPSIN=TKEIN**1.5/(0.035*DIAM*.1643)
    GROUP 3. X-direction grid specification
CARTES=F;XULAST=0.1
    GROUP 4. Y-direction grid specification
NY=80;YVLAST=DIAM;YFRAC(1)=-80;YFRAC(2)=1.0/80.0
   *** Linear grid expansion of DYGDZ
REAL(DYGDZ);DYGDZ=0.086*3.0;AZYV=1.0;ZWADD=DIAM/DYGDZ
    GROUP 5. Z-direction grid specification
PARAB=T;NZ=520;AZDZ=PROPY
  ** set DZW1=DZ/YVLAST value for AZDZ option
DZW1=0.02
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1,H1);NAME(H1)=TEMP;STORE(ENUT,LEN1)
SOLUTN(V1,P,P,P,P,P,N);SOLUTN(W1,P,P,P,P,P,N)
MESG( Enter the required turbulence model:
MESG(  CHEN -  Chen-Kim k-e model (default)
MESG(  KE   -  Standard k-e model
MESG(  KO   -  Wilcox   k-o model
MESG(  RNG  -  RNG      k-e model
MESG(  RKE  -  Realisable k-e model
MESG(
READVDU(CTURB,CHAR,CHEN)
CASE :CTURB: OF
WHEN CHEN,4
+ MESG(Chen-Kim k-e model
+ TURMOD(KECHEN);TLSC=EP
WHEN KE,2
+ TEXT(K-E MODEL_PARAB ROUND JET :T105
+ MESG(Standard k-e model
+ TURMOD(KEMODL);TLSC=EP
WHEN KO,2
+ TEXT(K-OMEGA MODEL_PARAB ROUND JET :T105
+ MESG(k-omega model
+ TURMOD(KOMODL);TLSC=OMEG;JKO=1
+ STORE(EP);EPSIN=EPSIN/(0.09*TKEIN);EPSFRE=EPSFRE/(0.09*TKEFRE)
WHEN RNG,3
TEXT(RNG K-E MODEL_PARAB ROUND JET :T105
+ MESG(RNG k-e model
+ TURMOD(KERNG);TLSC=EP
WHEN RKE,3
TEXT(Realisable K-E_PARAB ROUND JET :T105
+ MESG(Realisable k-e model
+ TURMOD(KEREAL);TLSC=EP
+ STORE(C1E);OUTPUT(CMU,Y,Y,Y,Y,Y,Y)
+ OUTPUT(C1E,Y,Y,Y,Y,Y,Y)
ENDCASE
    GROUP 8. Terms (in differential equations) & devices
DIFCUT=0.0;TERMS(TEMP,N,Y,Y,Y,Y,Y)
    GROUP 9. Properties of the medium (or media)
ENUL=ENULAM;PRT(TEMP)=0.7
    GROUP 13. Boundary conditions and special sources
    1. Outer Boundary-- free stream
PATCH(HIGHY,NORTH,1,1,NY,NY,1,NZ,1,1);COVAL(HIGHY,P1,1.0E4,0.0)
COVAL(HIGHY,V1,ONLYMS,0.0);COVAL(HIGHY,TEMP,ONLYMS,TFREE)
COVAL(HIGHY,W1,ONLYMS,0.0);COVAL(HIGHY,KE,ONLYMS,TKEFRE)
COVAL(HIGHY,:TLSC:,ONLYMS,EPSFRE)
    2. Inlet Boundary-- uniform flow
PATCH(NOZZLE,LOW,1,1,1,NY/2,1,1,1,1)
COVAL(NOZZLE,P1,FIXFLU,RHO1*WJET);COVAL(NOZZLE,W1,ONLYMS,WJET)
COVAL(NOZZLE,TEMP,ONLYMS,TJET)
COVAL(NOZZLE,KE,ONLYMS,TKEIN);COVAL(NOZZLE,:TLSC:,ONLYMS,EPSIN)
    GROUP 14. Downstream pressure for PARAB=T
IPARAB=1
    GROUP 16. Termination of iterations
LITHYD=50; RESREF(P1)=1.E-8; RESREF(V1)=1.E-8; RESREF(W1)=1.E-8
RESREF(TEMP)=1.E-8; RESREF(KE)=1.E-8; RESREF(:TLSC:)=1.E-8
    GROUP 17. Under-relaxation devices
RELAX(V1,FALSDT,10.); RELAX(W1,FALSDT,10.); RELAX(TEMP,FALSDT,10.)
RELAX(KE,FALSDT,1.0); RELAX(:TLSC:,FALSDT,1.0)
IF(JKO.EQ.1) THEN
+ RELAX(KE,FALSDT,0.1);RELAX(:TLSC:,FALSDT,0.1)
ENDIF
    GROUP 18. Limits on variables or increments to them
VARMIN(V1)=-1.E3;VARMAX(V1)=1.E3
    GROUP 19. Data communicated by SATELLITE to GROUND
DWDY=T
    GROUP 22. Monitor print-out
IZMON=NZ/2;IYMON=NY/2;ITABL=1;NPLT=1;IPLTL=LITHYD;TSTSWP=-1
  ** parabolic file dumping
IDISPA=1;IDISPB=1;IDISPC=NZ

  ** compute half-width velocity spreading rate
(stored of wh is 0.5*W1[&1&] )
(stored of th is 0.5*TEMP[&1&] )
(stored of ygp is YG)
PATCH(HWIDTH,CELL,1,NX,2,NY-1,1,NZ,1,LSTEP)
(stored of YH is 0.0)
(stored of YH at HWIDTH is YGP with IF(W1.GT.WH.AND.W1[,+1,].LT.WH))
(make1 YH1)
(store1 of YH1 at HWIDTH is MAX(YH,1.1E-10))
(print YH1 is YH1)
(stored of YHLF is YH1)

  ** compute half-width temperature spreading rate
(stored of YHT is 0.0)
(stored of YHT at HWIDTH is YGP with IF(TEMP.GT.TH.AND.TEMP[,+1,].LT.TH))
(make1 YHT1)
(store1 of YHT1 at HWIDTH is MAX(YHT,1.1E-10))
(print YHT1 IS YHT1)
(stored of YHLT is YHT1)

    GROUP 23. Field print-out and plot control
	   ** generate profile .csv file named IZNZ.csv
ORSIZ=0.4;PATCH(IZNZ,PROFIL,1,1,1,NY,NZ,NZ,1,1)
PLOT(IZNZ,W1,0.0,0.0);PLOT(IZNZ,TEMP,0.0,0.0)
PLOT(IZNZ,ENUT,0.0,0.0);NZPRIN=NZ
   ** generate axial .csv file named IY1.csv
PATCH(IY1,PROFIL,1,1,1,1,1,NZ,1,1)
PLOT(IY1,W1,0.0,0.0);PLOT(IY1,TEMP,0.0,0.0)
PLOT(IY1,YHLF,0.0,0.0);PLOT(IY1,YHLT,0.0,0.0)
NZPRIN=NZ
   NZPRIN=1;NYPRIN=1
NPLT=1;ITABL=2
DISTIL=T
CASE :CTURB: OF
WHEN CHEN,4
+EX(P1  )=1.166E-03;EX(V1  )=3.168E-02
+EX(W1  )=4.413E-01;EX(KE  )=6.393E-02
+EX(EP  )=2.908E-02;EX(TEMP)=4.437E-02
+EX(YHLT)=6.085E-01;EX(YHT )=7.606E-03
+EX(YHLF)=4.813E-01;EX(YH  )=6.017E-03
+EX(YGP )=7.266E-01;EX(TH  )=4.786E-02
+EX(WH  )=5.770E-01;EX(LEN1)=1.347E-01
+EX(ENUT)=1.548E-02
WHEN KE,2
+EX(P1  )=1.054E-03;EX(V1  )=3.131E-02
+EX(W1  )=4.302E-01;EX(KE  )=5.711E-02
+EX(EP  )=2.300E-02;EX(TEMP)=4.290E-02
+EX(YHLT)=6.811E-01;EX(YHT )=8.514E-03
+EX(YHLF)=5.540E-01;EX(YH  )=6.925E-03
+EX(YGP )=7.266E-01;EX(TH  )=4.396E-02
+EX(WH  )=5.202E-01;EX(LEN1)=1.141E-01
+EX(ENUT)=1.393E-02 
WHEN KO,2
EX(P1  )=1.571E-03;EX(V1  )=2.549E-02
EX(W1  )=4.141E-01;EX(KE  )=7.115E-02
EX(EP  )=1.545E-02;EX(TEMP)=3.969E-02
EX(YHLT)=1.190E+00;EX(YHT )=1.487E-02
EX(YHLF)=8.446E-01;EX(YH  )=1.056E-02
EX(YGP )=7.266E-01;EX(TH  )=2.787E-02
EX(WH  )=3.391E-01;EX(OMEG)=2.043E+00
EX(LEN1)=2.870E-01;EX(ENUT)=3.802E-02
WHEN RNG,3
+EX(P1  )=1.518E-03;EX(V1  )=2.839E-02 
+EX(W1  )=4.224E-01;EX(KE  )=7.378E-02 
+EX(EP  )=1.817E-02;EX(TEMP)=4.158E-02 
+EX(YHLT)=9.173E-01;EX(YHT )=1.147E-02 
+EX(YHLF)=7.538E-01;EX(YH  )=9.422E-03 
+EX(YGP )=7.266E-01;EX(TH  )=3.335E-02 
+EX(WH  )=3.915E-01;EX(LEN1)=1.821E-01 
+EX(ENUT)=2.622E-02 
WHEN RKE,3
+EX(P1  )=9.277E-04;EX(V1  )=3.086E-02 
+EX(W1  )=4.232E-01;EX(KE  )=4.557E-02 
+EX(EP  )=2.488E-02;EX(TEMP)=4.222E-02 
+EX(YHLT)=6.085E-01;EX(YHT )=7.606E-03 
+EX(YHLF)=4.995E-01;EX(YH  )=6.244E-03
+EX(YGP )=7.266E-01;EX(TH  )=4.938E-02
+EX(WH  )=5.715E-01;EX(C1E )=4.300E-01 
+EX(DWDY)=7.870E-01;EX(DVDY)=1.000E-10 
+EX(DUDX)=1.000E-10;EX(EPKE)=5.113E-01; 
+EX(CMU )=1.424E-01;EX(LEN1)=6.327E-02; 
+EX(ENUT)=1.058E-02 
ENDCASE