TEXT(RNG K-E FLOW IN TURNAROUND DUCT :T106
TITLE
 
  DISPLAY
  This case concerns plane, two-dimensional, incompressible flow
  through a 180 degree turnaround duct. The flow exhibits large
  streamline curvature together with flow separation near the bend
  exit next to the inner surface of the duct.
 
  Calculations are made with the high-re k-e model and the high-Re
  RNG k-e model. The latter is selected by setting RNGM=T in the Q1
  file. The fine-mesh calculation employs a non-uniform mesh of
  NY=25 and NZ=80, for which the solution is not as yet grid
  independent. However, the results of this calculation demonstrate
  that the RNG model predicts flow separation whereas the standard
  k-e model does not. Even calculations with a mesh of NY=40 and
  NZ=180 indicate that grid independence has not yet been achieved.
 
  For speed of computation, this library case has been set up to run
  for 20 sweeps only on a coarse mesh of NY=20 by NZ=40. About 250
  sweeps are required for complete convergence.
  ENDDIS
 
  This AUTOPLOT USE file produces a cross stream plot of the W1
  velocity resolute just downstream of the bend exit. The blue line
  is the RNG solution, which shows backflow near the inner wall, and
  the red line is the solution obtained with the standard k-e model,
  which shows no backflow.
 
  AUTOPLOT USE
  file
  phi 5
  xyz
 
 
 
  da 1 w1 z 51
  col3 1
  level y 0
  msg Velocity (W1) profile
  msg Press e to END
  ENDUSE
 
    GROUP 1. Run title
CHAR(CTURB,TLSC);BOOLEAN(FINEG);FINEG=F
REAL(REYNO,WIN,TKEIN,EPSIN,WIDTH,LENGTH,YAXIS)
REYNO=1.E5;WIDTH=.0381;WIN=26.25;YAXIS=1.5*WIDTH;LENGTH=3.5*WIDTH
TKEIN=(0.05*WIN)**2;EPSIN=TKEIN**1.5*0.1643/(0.09*WIDTH)
    GROUP 6. Body-fitted coordinates or grid distortion
BFC=T;NONORT=T;NX=1
IF(FINEG) THEN
+ NY=25;NZ=80
+ GSET(D,NX,NY,NZ,1.0,WIDTH,LENGTH)
+ GSET(P,A,0.0,0.0,LENGTH);GSET(P,B,0.0,WIDTH,LENGTH)
+ GSET(P,C,1.0,0.0,LENGTH);GSET(P,D,1.0,WIDTH,LENGTH)
+ GSET(L,LAB,A,B,NY,S1.7);GSET(L,LBD,B,D,NX,1.0)
+ GSET(L,LCD,C,D,NY,S1.7);GSET(L,LCA,C,A,NX,1.0)
+ GSET(F,FABCD,A,-,B,-,D,-,C,-)
+ GSET(M,FABCD,+J+I,1,1,1,TRANS)
+ GSET(C,K81,F,K1,+,0.0,0.0,0.0)
+ GSET(C,K81,F,K81,+,0.0,(YAXIS+0.5*WIDTH),0.0)
  ** k71-k51 cells in the outlet length
+ GSET(C,K51,F,K81,+,0.0,0.0,-LENGTH,INC,0.8)
  ** k51-k21 cells in the bend
+ GSET(C,K21,F,K51,RX,-3.14159,YAXIS,0.0,INC,1.0)
  ** k21-k1 cells in the inlet length
+ GSET(C,K1,F,K21,+,0.0,0.0,LENGTH,INC,1.2)
ELSE
+ NY=20;NZ=40
+ GSET(D,NX,NY,NZ,1.0,WIDTH,LENGTH)
+ GSET(P,A,0.0,0.0,LENGTH);GSET(P,B,0.0,WIDTH,LENGTH)
+ GSET(P,C,1.0,0.0,LENGTH);GSET(P,D,1.0,WIDTH,LENGTH)
+ GSET(L,LAB,A,B,NY,S1.7);GSET(L,LBD,B,D,NX,1.0)
+ GSET(L,LCD,C,D,NY,S1.7);GSET(L,LCA,C,A,NX,1.0)
+ GSET(F,FABCD,A,-,B,-,D,-,C,-)
+ GSET(M,FABCD,+J+I,1,1,1,TRANS)
+ GSET(C,K41,F,K1,+,0.0,0.0,0.0)
+ GSET(C,K41,F,K41,+,0.0,(YAXIS+0.5*WIDTH),0.0)
  ** k41-k31 cells in the outlet length
+ GSET(C,K31,F,K41,+,0.0,0.0,-LENGTH,INC,0.8)
  ** k31-k11 cells in the bend
+ GSET(C,K11,F,K31,RX,-3.14159,YAXIS,0.0,INC,1.0)
  ** k11-k1 cells in the inlet length
+ GSET(C,K1,F,K11,+,0.0,0.0,LENGTH,INC,1.2)
ENDIF
   ** Set wup=t to account better for the high curvature of
      the w resolute...
WUP=T
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1);SOLUTN(P1,Y,Y,Y,N,N,N);STORE(ENUT,LEN1)
SOLUTN(V1,P,P,P,P,P,N);SOLUTN(W1,P,P,P,P,P,N)
MESG( Enter the required turbulence model:
MESG(  CHEN -  Chen-Kim k-e model
MESG(  KE   -  Standard k-e model
MESG(  KO   -  Wilcox   k-o model
MESG(  RNG   - RNG      k-e model (default)
MESG(
READVDU(CTURB,CHAR,RNG)
CASE :CTURB: OF
WHEN CHEN,4
+ TEXT(CHEN KIM K-E FLOW IN TURNAROUND DUCT :T106
+ MESG(Chen-Kim k-e model
+ TURMOD(KECHEN);TLSC=EP
WHEN KE,2
+ TEXT(K-E FLOW IN TURNAROUND DUCT    :T106
+ MESG(Standard k-e model
+ TURMOD(KEMODL);TLSC=EP
WHEN KO,2
+ TEXT(K-OMEGA FLOW IN TURNAROUND DUCT    :T106
+ MESG(k-omega model
+ TURMOD(KOMODL);TLSC=OMEG
+ STORE(EP);EPSIN=EPSIN/(0.09*TKEIN)
WHEN RNG,3
+ MESG(RNG k-e model (default)
+ TURMOD(KERNG);TLSC=EP
+ STORE(ETA,ALF,GEN1);KELIN=1
+ OUTPUT(ALF,Y,N,P,Y,Y,Y);OUTPUT(ETA,Y,N,P,Y,Y,Y)
ENDCASE
    GROUP 9. Properties of the medium (or media)
ENUL=WIN*WIDTH/REYNO
    GROUP 11. Initialization of variable or porosity fields
FIINIT(P1)=1.E-10;FIINIT(W1)=WIN
FIINIT(KE)=TKEIN;FIINIT(:TLSC:)=EPSIN
    GROUP 13. Boundary conditions and special sources
INLET(BFCIN,LOW,#1,#1,#1,#NREGY,#1,#1,1,1)
VALUE(BFCIN,P1,GRND1);VALUE(BFCIN,W1,GRND1)
VALUE(BFCIN,WCRT,-WIN);VALUE(BFCIN,KE,TKEIN)
VALUE(BFCIN,:TLSC:,EPSIN)
  *  Transfer density for GXBFC subroutine
BFCA=RHO1
PATCH(OUTLET,HIGH,#1,#1,#1,#NREGY,#NREGZ,#NREGZ,1,1)
COVAL(OUTLET,P1,1.E4,0.0)
COVAL(OUTLET,V1,ONLYMS,0.0);COVAL(OUTLET,W1,ONLYMS,0.0)
  **    N-wall
WALL (WFNN,NORTH,1,NX,NY,NY,1,NZ,1,1)
  **    S2-wall
WALL (WFNS,SOUTH,1,NX,1,1,1,NZ,1,1)
    GROUP 15. Termination of sweeps
LSWEEP=20
REAL(MASIN,DTF);MASIN=WIDTH*WIN*RHO1
RESREF(P1)=1.E-12*MASIN
RESREF(W1)=RESREF(P1)*WIN; RESREF(V1)=RESREF(W1)
RESREF(KE)=RESREF(P1)*TKEIN; RESREF(:TLSC:)=RESREF(P1)*EPSIN
    GROUP 16. Termination of iterations
LITER(P1)=10
    GROUP 17. Under-relaxation devices
RELAX(P1,LINRLX,0.5);DTF=ZWLAST/WIN/NZ
RELAX(W1,FALSDT,DTF); RELAX(V1,FALSDT,DTF)
RELAX(KE,FALSDT,DTF); RELAX(:TLSC:,FALSDT,DTF)
    GROUP 22. Spot-value print-out
IYMON=2;IZMON=56;NPRMON=LSWEEP
    GROUP 23. Field print-out and plot control
NPRINT=LSWEEP;ITABL=3;NPLT=2
NYPRIN=1;NZPRIN=1;IZPRF=18;IZPRL=24;TSTSWP=-1
  ** activate printout of near-wall y+ values
WALPRN=T