TALK=T;RUN( 1, 1)
** LOAD(x207) from the x Input Library
** PHOENICS VALIDATION CASE
GROUP 1. Run title and other preliminaries
TEXT(K-W_1D DEVELOPED PIPE FLOW :T207
TITLE
DISPLAY
The case considered is fully-developed turbulent flow and heat
transfer in a circular pipe at Re=1.E5 and Pr=3.0. The tube wall
is held at a constant temperature, and the calculation integrates
down to the wall through the viscous sublayer. A non-uniform grid
is employed so as to concentrate cells very close to the wall.
For this purpose a grid is generated which is a geometric
progression with the property that the ratio of any two adjacent
cell lengths is a constant. The turbulence is simulated by one of
7 low-Re turbulence models, namely: the Lam-Bremhorst, Chen-Kim or
2-layer k-e models; or the Wilcox 1988 or 2008 k-w model; or the
Menter k-w model or k-w SST models.
ENDDIS
The PHOENICS predictions reveal the following major results:
LB CK 2L KW KWR KWM SST Data
f 0.020 0.018 0.019 0.018 0.017 0.018 0.017 0.018
vdp 3.36 3.36 3.42 3.55 3.53 3.47 3.53 3.75
Nu 390 363 407 367 354 375 354 392
where the friction factor f =8.*(wstar/wbulk)**2, the velocity
defect parameter vdp=(wcl-wbulk)/wstar, and Nu=h*d/k is the
Nusselt number. Here, wstar is the friction velocity, h is the
heat transfer coefficient based on bulk conditions. It should
be noted that grid effects have not been investigated.
In-Form is used to print the f, vdp and Nu to the PHIDA, RESULT
and inforout files.
ENDDIS
The following AUTOPLOT use file produces four plots;
the first is the axial velocity profile; the second
is the temperature profile; the third is the turbulence
energy profile; and the fourth is the dissipation rate
profile.
AUTOPLOT USE
file
phi 5
da 1 w1;col9 1
msg Velocity (W1) profile
msg Press RETURN to continue
pause
clear
da 1 tem1;col9 1
msg temperature profile
msg Press RETURN to continue
pause
clear
da 1 ke;col9 1
msg KE profile
msg Press RETURN to continue
pause
clear
da 1 ep;col9 1
msg EP profile
msg Press e to END
ENDUSE
INTEGER(TMODEL);CHAR(CTURB,TLSC)
BOOLEAN(KWMOD);KWMOD=F
REAL(DIAM,WIN,REY,MIXL,FRIC,DPDZ,MASIN,DTF,TKEIN,EPSIN)
REAL(DELT1,DELT2,DELT3,US,EPSPLS,KFAC,DELY,AA,GR,GYPLUS)
REAL(GWPLUS,GWR,QIN,DTDZ,COND,CP,TW,AIN,AWAL,NUSS,XR,RIN)
DIAM=0.1;WIN=1.0; REY=1.E5;FRIC=1./(1.82*LOG10(REY)-1.64)**2
FRIC
DPDZ=FRIC*RHO1*WIN*WIN/(2.*DIAM);US=WIN*(FRIC/8.)**0.5
** estimate initial values from K+=2 & EP+=1./(ak*Y+)
EPSPLS=1./(0.41*100.); RIN=0.5*DIAM
TKEIN=2.*US*US;ENULA=WIN*DIAM/REY;EPSIN=EPSPLS*US**4/ENULA
** the grid-expansion factor Kfac defines a constant ratio of
lengths of two adjacent cells.
MESG( Enter the required turbulence model:
MESG( LB - Low-Re Lam-Brem. k-e model
MESG( CK - Low-Re Chen-Kim k-e model
MESG( 2L - Low-Re 2-layer k-e model
MESG( KW - Wilcox 1988 low-Re k-w model (default)
MESG( KWR - Wilcox 2008 low-Re k-w model
MESG( KWM - Menter 1992 k-w model
MESG( KWS - k-w SST model
MESG(
READVDU(CTURB,CHAR,KW)
CASE :CTURB: OF
WHEN LB,2
+ TEXT(LAM-BRE KE_1D DEVELOPED PIPE FLOW :T207
+ MESG(Low-Re Lam-Bem. k-e turbulence model
+ TMODEL=1;KFAC=1.1;TLSC=EP
WHEN CK,2
+ TEXT(CHEN-KIM KE_1D DEVELOPED PIPE FLOW :T207
+ MESG(Low-Re Chen-Kim k-e turbulence model
+ TMODEL=2;KFAC=1.1;TLSC=EP
WHEN 2L,2
+ TEXT(2-LAYER KE_1D DEVELOPED PIPE FLOW :T207
+ MESG(Low-Re 2-layer k-e turbulence model
+ SELREF=F;TMODEL=3;KFAC=1.2;TLSC=EP
WHEN KW,2
+ TEXT(Wilcox 1988 K-W_1D DEVELOPED PIPE FLOW:T207
+ MESG(Wilcox 1988 Low-Re k-w model
+ TMODEL=4;KFAC=1.1;TLSC=OMEG;KWMOD=T
+ EPSIN=EPSIN/(0.09*TKEIN)
WHEN KWR,3
+ TEXT(Wilcox 2008 K-W_1D DEVELOPED PIPE FLOW:T207
+ MESG(Wilcox 2008 Low-Re k-w model
+ TMODEL=5;KFAC=1.1;TLSC=OMEG;KWMOD=T
+ EPSIN=EPSIN/(0.09*TKEIN)
WHEN KWM,3
+ TEXT(MENTER K-W_1D DEVELOPED PIPE FLOW:T207
+ MESG(Menter Low-Re k-w model
+ TMODEL=6;KFAC=1.1;TLSC=OMEG;KWMOD=T
+ EPSIN=EPSIN/(0.09*TKEIN)
WHEN KWS,3
+ TEXT(K-W SST_1D DEVELOPED PIPE FLOW:T207
+ MESG(Low-Re k-w SST model
+ TMODEL=7;KFAC=1.1;TLSC=OMEG;KWMOD=T
+ EPSIN=EPSIN/(0.09*TKEIN)
ENDCASE
GROUP 3. X-direction grid specification
CARTES=F;XULAST=0.1;AIN=0.5*RIN*RIN*XULAST
GROUP 4. Y-direction grid specification
ENULA=WIN*DIAM/REY
** define first dely from wall
DELT1=1.*ENULA/US;DELY=DELT1/(0.5*DIAM)
** calculate NY from dely & Kfac
AA=(YVLAST/DELY)*(KFAC-1.0)+1.0;AA=LOG(AA)/LOG(KFAC)+1.0001
NY=AA
** define uniform grid initially
IREGY=1;GRDPWR(Y,NY,YVLAST,1.0)
** compute expanding grid from north boundary
YFRAC(NY)=1.0;INTEGER(JJM,JJM1)
DO JJ=NY,2,-1
+ JJM=JJ-1
+ YFRAC(JJM)=YFRAC(JJ)-DELY
+ DELY=KFAC*DELY
ENDDO
YVLAST=0.5*DIAM
GROUP 5. Z-direction grid specification
ZWLAST=0.1*DIAM
GROUP 7. Variables stored, solved & named
SOLVE(W1,TEM1);STORE(ENUT,LEN1)
SOLUTN(W1,P,P,P,P,P,N)
CASE (TMODEL) OF
WHEN 1
+ TURMOD(KEMODL-LOWRE);KELIN=3
+ STORE(FMU,REYT,REYN,FONE,FTWO)
WHEN 2
+ TURMOD(KECHEN-LOWRE);KELIN=3
+ STORE(FMU,REYT,REYN,FONE,FTWO)
WHEN 3
+ TURMOD(KEMODL-2L);KELIN=1
+ STORE(FMU,REYT,FTWO)
WHEN 4
+ TURMOD(KWMODL-LOWRE)
+ STORE(FMU,FTWO,REYT)
WHEN 5
+ TURMOD(KWMODLR-LOWRE)
WHEN 6
+ TURMOD(KWMENTER-LOWRE)
+ STORE(DKDY,DFDY,CDWS,SIGK,SIGW)
WHEN 7
+ TURMOD(KWSST-LOWRE)
+ STORE(DKDY,DFDY,CDWS,SIGK,SIGW)
ENDCASE
GROUP 8. Terms (in differential equations) & devices
TERMS(W1,N,N,P,P,P,P);TERMS(KE,Y,N,P,P,P,P)
TERMS(:TLSC:,Y,N,P,P,P,P);TERMS(TEM1,N,N,P,P,P,P)
GROUP 9. Properties of the medium (or media)
ENUL=ENULA;PRNDTL(H1)=3.0;MASIN=RHO1*WIN*AIN
** prescribe energy flow from slab and fluid specific heat
estimated from Dittus-Boelter Nu=0.023*Re**0.8*Pr**0.4
with (Tw-Tb)=5.0
NUSS=0.023*REY**0.8*PRNDTL(H1)**0.4;CP=1.0;AWAL=RIN*XULAST
COND=RHO1*CP*ENUL/PRNDTL(H1);QIN=NUSS*5.0*COND/DIAM
NUSS
** compute d(tbulk)/dz for input to single-slab
thermal solver and prescribe wall temperature
DTDZ=QIN*AWAL/MASIN;TW=10.
STORE(KOND,AREH)
GROUP 11. Initialization of variable or porosity fields
FIINIT(:TLSC:)=EPSIN;FIINIT(KE)=TKEIN;FIINIT(TEM1)=0.5*TW
** use log-law for initial W profile
DO JJ=1,NY
+PATCH(IN:JJ:,INIVAL,1,NX,JJ,JJ,1,NZ,1,1)
+GR=0.5*YFRAC(JJ)
IF(JJ.NE.1) THEN
+ JJM1=JJ-1
+ GR=YFRAC(JJM1)+0.5*(YFRAC(JJ)-YFRAC(JJM1))
ENDIF
+GYPLUS=YVLAST*(1.-GR)*US/ENULA
+GWPLUS=LOG(GYPLUS)/0.41+5.25
IF(GYPLUS.LE.11.5) THEN
+ GWPLUS=GYPLUS
ENDIF
+INIT(IN:JJ:,W1,ZERO,GWPLUS*US)
ENDDO
GROUP 13. Boundary conditions and special sources
WALL(WALLN,NORTH,1,1,NY,NY,1,NZ,1,1);COVAL(WALLN,W1,LOGLAW,0.0)
COVAL(WALLN,TEM1,LOGLAW,TW)
** activate pressure-drop calculation in single-slab solver
FDFSOL=T;USOURC=T
PATCH(FDFW1DP,VOLUME,1,NX,1,NY,1,NZ,1,1)
COVAL(FDFW1DP,W1,MASIN,GRND1)
** temperature source/sink term for fully-developed flow
PATCH(FDFCWT,PHASEM,1,NX,1,NY,1,NZ,1,1)
COVAL(FDFCWT,TEM1,DTDZ,TW)
GROUP 15. Termination of sweeps
TSTSWP=-1;LITHYD=6
GROUP 16. Termination of iterations
GROUP 17. Under-relaxation devices
DTF=5.0*ZWLAST/WIN; RELAX(W1,FALSDT,DTF)
CASE (TMODEL) OF
WHEN 1
+ LSWEEP=70; RELAX(KE,LINRLX,0.3); RELAX(EP,LINRLX,0.5)
WHEN 2
+ LSWEEP=70; RELAX(KE,LINRLX,0.3); RELAX(EP,LINRLX,0.5)
WHEN 3
+ LSWEEP=40; RELAX(KE,FALSDT,DTF); RELAX(EP,FALSDT,DTF)
ENDCASE
IF(KWMOD) THEN
+ LSWEEP=40;RELAX(KE,FALSDT,DTF);RELAX(OMEG,FALSDT,DTF)
ENDIF
GROUP 18. Limits on variables or increments to them
VARMIN(W1)=1.E-10
GROUP 22. Spot-value print-out
IYMON=NY-2;NZPRIN=1;NYPRIN=2;IYPRF=1;NUMCLS=5
GROUP 24. Dumps for restarts
** store(stan) returns incorrect stanton number in RESULT file
WALPRN=T;STORE(YPLS,SKIN,STAN,STRS,HTCO)
** compute expected Nusselt number from Petukhov
XR=1.07+12.7*(PRNDTL(H1)**.666-1.)*(FRIC/8.)**0.5
NUSS=REY*PRNDTL(H1)*FRIC/(8.*XR)
NUSS
STORE(PRPS);EX(PRPS)=33;FIINIT(PRPS)=33;PRNDTL(TEM1)=CONDFILE
** mat no. rho enul cp kond expan
** 1 air
CSG10='q1'
MATFLG=T;NMAT=1
33 1. 1.E-6 1.0 3.333E-7 0
(stored of FRIC is 8.*STRS/(:WIN:*:WIN:))
(stored of UTAU is STRS^0.5)
(stored of VDP is (W1[&1&]-WIN)/UTAU[&NY&])
** compute Tbulk & Nusselt
(stored AREH is AHIGH)
(stored TSUM is 0.0)
(stored TSUM at FDFCWT is SUM(W1*AREH*TEM1))
(stored ASUM is 0.0)
(stored ASUM at FDFCWT is SUM(W1*AREH))
(stored TB at FDFCWT is TSUM/ASUM)
(stored of NUSS is HTCO*:DIAM:*(:TW:-TEM1[&NY&1])/(:COND:*(:TW:-TB)))
(make ffac is 0.0)
(make ustar is 0.0)
(make vdus is 0.0)
(make nus is 0.0)
(store1 of ffac at walln is fric)
(store1 of ustar at walln is utau)
(store1 of vdus at walln is vdp)
(store1 of nus at walln is nuss)
** print to inforout file
(print of f is ffac)
(print of u* is ustar)
(print of (ucl-ub)/u* is vdus)
(print of Nu is nus)
DISTIL=T
CASE :CTURB: OF
WHEN LB,2
+EX(W1 )=7.985E-01;EX(KE )=6.795E-03
+EX(EP )=2.373E-01;EX(VDP )=3.363E+00
+EX(UTAU)=8.655E-04;EX(FRIC)=3.397E-04
+EX(STRS)=4.246E-05;EX(STAN)=2.096E-02
+EX(SKIN)=6.290E-02;EX(YPLS)=9.027E-03
+EX(FONE)=2.328E+00;EX(REYN)=5.309E+02
+EX(EPKE)=1.036E+08;EX(LTLS)=1.714E-04
+EX(WDIS)=7.667E-03;EX(FTWO)=9.570E-01
+EX(REYT)=1.109E+03;EX(FMU )=7.379E-01
+EX(LEN1)=2.556E-03;EX(ENUT)=9.649E-05
+EX(TEM1)=6.128E+00;EX(NUSS)=6.723E+00
+EX(TB )=5.423E+00;EX(ASUM)=1.250E-04
+EX(TSUM)=6.779E-04;EX(HTCO)=5.447E-04
+EX(AREH)=2.155E-06;EX(KOND)=3.333E-07
WHEN CK,2
+EX(W1 )=7.949E-01;EX(KE )=6.238E-03
+EX(EP )=2.143E-01;EX(VDP )=3.359E+00
+EX(UTAU)=8.317E-04;EX(FRIC)=3.134E-04
+EX(STRS)=3.918E-05;EX(STAN)=2.272E-02
+EX(SKIN)=6.817E-02;EX(YPLS)=8.671E-03
+EX(FONE)=2.778E+00;EX(REYN)=5.196E+02
+EX(EPKE)=8.522E+07;EX(LTLS)=1.714E-04
+EX(WDIS)=7.667E-03;EX(FTWO)=9.566E-01
+EX(REYT)=1.076E+03;EX(FMU )=7.325E-01
+EX(LEN1)=2.558E-03;EX(ENUT)=9.382E-05
+EX(TEM1)=5.858E+00;EX(NUSS)=6.252E+00
+EX(TB )=5.078E+00;EX(ASUM)=1.250E-04
+EX(TSUM)=6.348E-04;EX(HTCO)=5.447E-04
+EX(AREH)=2.155E-06;EX(KOND)=3.333E-07
WHEN 2L,2
+EX(W1 )=7.403E-01;EX(KE )=5.621E-03
+EX(EP )=3.027E-01;EX(VDP )=3.420E+00
+EX(UTAU)=1.443E-03;EX(FRIC)=5.585E-04
+EX(STRS)=6.981E-05;EX(STAN)=3.711E-02
+EX(SKIN)=1.113E-01;EX(YPLS)=1.512E-02
+EX(LTLS)=1.532E-04;EX(WDIS)=6.725E-03
+EX(FTWO)=5.152E+00;EX(REYT)=1.000E-10
+EX(FMU )=7.393E-01;EX(LEN1)=2.216E-03
+EX(ENUT)=8.272E-05;EX(TEM1)=6.526E+00
+EX(NUSS)=1.196E+01;EX(TB )=5.610E+00
+EX(ASUM)=1.250E-04;EX(TSUM)=7.013E-04
+EX(HTCO)=9.292E-04;EX(AREH)=3.676E-06
+EX(KOND)=3.333E-07
WHEN KW,2
+EX(W1 )=7.818E-01;EX(KE )=5.965E-03
+EX(EP )=4.789E-01;EX(STRS)=3.808E-05
+EX(STAN)=2.338E-02;EX(SKIN)=7.014E-02
+EX(YPLS)=8.548E-03;EX(OMEG)=1.592E+04
+EX(FTWO)=8.509E-01;EX(REYT)=8.923E+01
+EX(FMU )=7.597E-01;EX(LEN1)=2.508E-03
+EX(ENUT)=8.482E-05;EX(TEM1)=5.963E+00
+EX(VDP )=3.554E+00;EX(UTAU)=8.201E-04
+EX(FRIC)=3.046E-04;EX(NUSS)=6.327E+00
+EX(TB )=5.137E+00;EX(ASUM)=1.250E-04
+EX(TSUM)=6.421E-04;EX(HTCO)=5.447E-04
+EX(AREH)=2.155E-06;EX(KOND)=3.333E-07
WHEN KWR,3
+EX(W1 )=7.814E-01;EX(KE )=4.674E-03
+EX(EP )=2.151E-01;EX(NUSS)=6.207E+00
+EX(TB )=5.043E+00;EX(ASUM)=1.250E-04
+EX(TSUM)=6.303E-04;EX(VDP )=3.604E+00
+EX(UTAU)=8.029E-04;EX(FRIC)=2.918E-04
+EX(HTCO)=5.447E-04;EX(STRS)=3.648E-05
+EX(STAN)=2.440E-02;EX(SKIN)=7.321E-02
+EX(YPLS)=8.367E-03;EX(AREH)=2.155E-06
+EX(KOND)=3.333E-07;EX(DWDY)=3.433E+02
+EX(GEN1)=5.116E+05;EX(FBP )=1.000E+00
+EX(OMEG)=1.697E+04;EX(LEN1)=2.392E-03
+EX(ENUT)=8.221E-05;EX(TEM1)=5.904E+00
WHEN KWM,3
+EX(W1 )=7.842E-01;EX(KE )=4.890E-03
+EX(EP )=2.290E-01;EX(VDP )=3.475E+00
+EX(UTAU)=8.190E-04;EX(FRIC)=3.038E-04
+EX(STRS)=3.797E-05;EX(STAN)=2.344E-02
+EX(SKIN)=7.033E-02;EX(YPLS)=8.537E-03
+EX(SIGW)=2.000E+00;EX(SIGK)=2.000E+00
+EX(CDWS)=1.203E-04;EX(DFDY)=7.802E+08
+EX(DKDY)=2.873E+00;EX(LTLS)=1.714E-04
+EX(WDIS)=7.667E-03;EX(BF1 )=1.000E+00
+EX(OMEG)=1.605E+04
+EX(LEN1)=2.484E-03;EX(ENUT)=8.678E-05
+EX(TEM1)=6.056E+00;EX(ASUM)=1.250E-04
+EX(HTCO)=5.447E-04;EX(AREH)=2.155E-06
+EX(KOND)=3.333E-07;EX(NUSS)=6.473E+00
+EX(TB )=5.246E+00;EX(TSUM)=6.558E-04
WHEN KWS,3
+EX(W1 )=7.822E-01;EX(KE )=4.617E-03
+EX(EP )=2.111E-01;EX(NUSS)=6.107E+00
+EX(TB )=4.962E+00;EX(ASUM)=1.250E-04
+EX(TSUM)=6.202E-04;EX(VDP )=3.533E+00
+EX(UTAU)=7.953E-04;EX(FRIC)=2.863E-04
+EX(HTCO)=5.447E-04;EX(STRS)=3.579E-05
+EX(STAN)=2.487E-02;EX(SKIN)=7.463E-02
+EX(YPLS)=8.287E-03;EX(AREH)=2.155E-06
+EX(KOND)=3.333E-07;EX(SIGW)=2.000E+00
+EX(SIGK)=2.000E+00;EX(CDWS)=1.153E-03
+EX(DFDY)=7.802E+08;EX(DKDY)=2.674E+00
+EX(LTLS)=1.714E-04;EX(WDIS)=7.667E-03
+EX(GEN1)=5.000E+05;EX(BF2 )=1.000E+00
+EX(BF1 )=1.000E+00;EX(OMEG)=1.605E+04
+EX(LEN1)=2.465E-03;EX(ENUT)=8.303E-05
+EX(TEM1)=5.837E+00
ENDCASE
STOP