GROUP 1. Run title and other preliminaries
 
TEXT(LAM-BRE_2D Y-Z NOPOR CHANNEL TEST  :T215
TITLE
  DISPLAY
  This case provides a test of the Lam-Bremhorst low-Reynolds
  number k-e model for 2d steady developing flow in a channel.
  As a test of symmetry both halves of the channel are
  considered in the y-z plane. In addition the temperature
  equation is solved via the TEM1 variable with a uniformly-
  distributed heat flux applied to the fluid at each wall. The
  case acts as a benchmark calculation against which may be
  compared calculations of the same case involving blockages
  represented via "conjugate heat transfer" or "porosities".
  A relatively coarse grid is used so as to permit convergence
  in about 400 sweeps. The problem has been set up to perform
  30 sweeps only, so as to reduce execution times in performing
  routine testing procedures.
  ENDDIS
REAL(REY,RHOIN,WIN,HGHT,DHYDR,REYH,FRIC,US,TKEIN,EPIN,TIN)
HGHT=0.1; REY=1.E5;WIN=10.0;DHYDR=2.*HGHT; REYH=2.*REY;TIN=300.
FRIC=1./(1.82*LOG10(REYH)-1.64)**2;US=WIN*(FRIC/8.)**0.5
ENUL=WIN*HGHT/REY
    GROUP 3. X-DIRECTION GRID SPECIFICATION
    GROUP 4. Y-DIRECTION GRID SPECIFICATION
REAL(LENGTH,DELT1,DELY,KFAC,AA)
  ** define first dely from wall and the grid-expansion
     factor Kfac which defines a constant ratio of lengths of
     two adjacent cells.
DELT1=0.5*ENUL/US;KFAC=1.8;DELY=DELT1/(0.5*HGHT)
  ** calculate NY from dely & Kfac
INTEGER(NY2,JJM,JJJ)
AA=(0.5/DELY)*(KFAC-1.0)+1.0
AA=LOG(AA)/LOG(KFAC)+1.0001
NY2=AA;NY=2*NY2
  ** define uniform grid initially
IREGY=1;GRDPWR(Y,NY,YVLAST,1.0)
  ** compute expanding grid from south boundary over one
     half of the channel width
YFRAC(1)=DELY
DO JJ=2,NY2
+ JJM=JJ-1
+ DELY=KFAC*DELY
+ YFRAC(JJ)=YFRAC(JJM)+DELY
ENDDO
YFRAC(NY2)=0.5
  ** create symmetrical grid in the second half of the channel
JJJ=0
DO JJ=NY-1,NY2+1,-1
+ JJJ=JJJ+1
+ YFRAC(JJ)=1.-YFRAC(JJJ)
ENDDO
YFRAC(NY)=1.0;YVLAST=HGHT
    GROUP 5. Z-direction grid specification
LENGTH=5.*HGHT;NZ=10;GRDPWR(Z,NZ,LENGTH,1.0)
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1,TEM1);SOLUTN(P1,Y,Y,Y,P,P,P)
SOLUTN(TEM1,Y,Y,Y,P,P,P);STORE(PRPS)
TURMOD(KEMODL-LOWRE);STORE(ENUT);KELIN=1
  ** use harmonic-averaging to permit comparison
     with a "conjugate-heat-transfer" calculation
SOLUTN(V1,Y,Y,P,P,P,Y);SOLUTN(W1,Y,Y,P,P,P,Y)
SOLUTN(KE,Y,Y,P,P,P,Y);SOLUTN(EP,Y,Y,P,P,P,Y)
SOLUTN(TEM1,P,P,P,P,P,Y)
    GROUP 8. TERMS (IN DIFFERENTIAL EQUATIONS) & DEVICES
    GROUP 9. PROPERTIES OF THE MEDIUM (OR MEDIA)
PRNDTL(TEM1)=CONDFILE;
    GROUP 11. INITIALIZATION OF VARIABLE OR POROSITY FIELDS
FIINIT(P1)=1.E-3;FIINIT(W1)=WIN;TKEIN=2.*US**2
EPIN=0.1643*TKEIN**1.5/(0.1*0.5*HGHT)
FIINIT(KE)=TKEIN;FIINIT(EP)=EPIN;FIINIT(W1)=WIN;FIINIT(TEM1)=TIN
    GROUP 13. BOUNDARY CONDITIONS AND SPECIAL SOURCES
  ** air inflow boundary
PATCH(INLET,LOW,1,NX,1,NY,1,1,1,1)
COVAL(INLET,P1,FIXFLU,RHO1*WIN);COVAL(INLET,W1,ONLYMS,WIN)
COVAL(INLET,KE,ONLYMS,TKEIN);COVAL(INLET,EP,ONLYMS,EPIN)
COVAL(INLET,TEM1,ONLYMS,TIN)
  ** outflow boundary
PATCH(OUTL,HIGH,1,1,1,NY,NZ,NZ,1,1)
COVAL(OUTL,P1,1.E3,0.0);COVAL(OUTL,W1,ONLYMS,0.0)
COVAL(OUTL,KE,ONLYMS,0.0);COVAL(OUTL,EP,ONLYMS,0.0)
COVAL(OUTL,TEM1,ONLYMS,SAME);COVAL(OUTL,V1,ONLYMS,0.0)
  ** wall boundaries; prescribed heat flux at both walls
PATCH(WALLN,NWALL,1,1,NY,NY,1,NZ,1,1)
COVAL(WALLN,KE,1.0,0.0);COVAL(WALLN,W1,LOGLAW,0.0)
COVAL(WALLN,TEM1,FIXFLU,0.5E3/LENGTH);COVAL(WALLN,LTLS,1.0,0.)
PATCH(WALLS,SWALL,1,1,1,1,1,NZ,1,1)
COVAL(WALLS,KE,1.0,0.0);COVAL(WALLS,W1,LOGLAW,0.0)
COVAL(WALLS,TEM1,FIXFLU,0.5E3/LENGTH);COVAL(WALLS,LTLS,1.0,0.)
    GROUP 15. TERMINATION OF SWEEPS
RESREF(P1)=1.E-12*WIN*HGHT
RESREF(W1)=RESREF(P1)*WIN*RHO1; RESREF(V1)=RESREF(W1)
RESREF(KE)=RESREF(P1)*RHO1*TKEIN; RESREF(EP)=RESREF(P1)*RHO1*EPIN
RESREF(TEM1)=RESREF(P1)*RHO1*TIN*1.E3
    GROUP 17. Under-relaxation devices
RELAX(P1,LINRLX,1.0); REAL(DTF);DTF=5.*ZWLAST/WIN/NZ
RELAX(V1,FALSDT,DTF); RELAX(W1,FALSDT,DTF)
RELAX(KE,FALSDT,DTF); RELAX(EP,FALSDT,DTF)
    GROUP 22. Monitor print-out
IZMON=NZ/2;IYMON=NY;ITABL=3;NPLT=5
    GROUP 24. DUMPS FOR RESTARTS
  ** activate printout of near-wall y+ values
YPLS=T;LSWEEP=30;NPRINT=LSWEEP;NYPRIN=1;NZPRIN=1;TSTSWP=-1
  ** Define fluid properties via Q1
FIINIT(PRPS)=34
  ** mat no. rho enul cp kond expan
  **   1        air
CSG10=Q1
  MATFLG=T;NMAT=1
  34 1. 1.E-5 1.E3 0.01 0