TALK=F;RUN(1,1)
TEXT(LoRe K-W SST_2D IMPINGING ROUND JET : T218
TITLE
 
  DISPLAY
   The case considered is the normal impingement of a turbulent
   round jet of air on a heated flat plate. The jet issues into
   atmospheric ambient fluid at a Reynolds number of 70,000 from a
   pipe located 6 pipe diameters above the electrically heated
   plate. The jet injection temperature is ambient so that the
   purpose of the flow process is to effect cooling. For the case
   of orthogonal impaction, the flow is axisymmetric and is directed
   outward along the surface giving rise to a radial wall jet.
   The calculation may be performed with one of 5 low-Reynolds-number 
   turbulence models: ; the Lam-Bremhorst k-e model with or without 
   the Yap correction; the 2-layer k-e model; the Wilcox 2008 k-w
   model; and the k-w SST model. The models use a mesh of 70 radial 
   by 110 axial cells.
  ENDDIS
   This case is the validation case investigated at CFD95, Canada
   (see Pollard et al (1996), CFDSC/V/95-3) and in the 2nd ERCOFTAC
   -IAHR Workshop on Refined-Flow Modelling. The flow geometry and
   conditions approximate to those reported experimentally by
   D.Cooper et al (1993) and Craft et al (1993) for Re=7E4 and H/D=6.
   
   Cooper, D., Jackson, D.C., Launder, B.E. & Liao, G.X.,"Impinging 
   jet studies for turbulence model assessment-l. Flow-field 
   experiments",Int.J.Heat & Mass Transfer, Vol.36. No.1O. p2675-2684,
   (1993)

   Craft,T.J., Graham,L.J.W & Launder, B.E., "Impinging jet studies 
   for turbulence model assessment-II. An examination of the
   performance of four turbulence models", Int.J.Heat & Mass Transfer, 
   Vol.36. No.1O. p2685-2697,(1993)

    This AUTOPLOT sequence provides a plot of the radial distribution
	of the Nusselt number along the plate.
 
   AUTOPLOT USE
   file
   phida 3
 
   da 1 nuss z m
   divide x 1 1
   col9 1
   level y 0;level x 0
   scale x 0 7
   msg plate Nusselt number
   pause
   cl
   da 1 nus z m
   divide x 1 1
   col9 1
   level y 0;level x 0
   scale x 0 7
   msg plate scaled Nusselt number
   pause 
   
   msg Press e to END

   ENDUSE
CHAR(CTUR,TLSC);BOOLEAN(KWMOD,FIXQ)
KWMOD=F;FIXQ=T
INTEGER(NYJ,NYFS)
REAL(REY,DIAM,HEIGHT,WJET,RADJ,TKEIN,EPSIN,DTF,AIN,FLOW)
REAL(YPLS1,DELZ1,DELZ,AA,KFAC,US,SFAC,VREL,ENUFRE,KEFRE,EPFRE)
REAL(CP,TJET,TAMB,QPLATE,QIN,COND,PRLAM,NUSLT,DELTEM,EPSINI)
REAL(TWAL,RPLATE,APLATE,NUFAC)
  ** nozzle discharge conditions
REY=7.E4
DIAM=1.0; RADJ=0.5*DIAM;HEIGHT=6.*DIAM
WJET=REY*ENUL/DIAM;TKEIN=0.01*WJET*WJET
EPSIN=.1643*TKEIN**1.5/(0.09*DIAM)
  ** temperature conditions
TJET=300.0;TAMB=TJET;TWAL=310.0
  ** physical properties
CP=1005.0;PRLAM=0.71; RHO1=1.178;ENUL=1.567E-5
COND=CP*RHO1*ENUL/PRLAM
NUSLT=0.045*(REY**0.7)*PRLAM**0.4

  ** wall heat flux in W/m^2
DELTEM=10.0  ! estimate temperature rise
QPLATE=NUSLT*COND*DELTEM/DIAM
QPLATE
  ** free stream turbulence
ENUFRE=ENUL;KEFRE=1.E-5;EPFRE=0.09*KEFRE**2/ENUFRE
  ** plate area - not needed
APLATE=XULAST*RPLATE*RPLATE/8.

    GROUP 3. X-direction grid specification
CARTES=F;NX=1;XULAST=0.1;AIN=0.5*RADJ*RADJ*XULAST
    GROUP 4. Y-direction grid specification
RPLATE=7.*DIAM
NYJ=20;NYFS=50
NREGY=2; REGEXT(Y,RPLATE);IREGY=1;GRDPWR(Y,NYJ,RADJ,1.0)
IREGY=2;GRDPWR(Y,NYFS*2,RPLATE-RADJ,1.1)

    GROUP 5. Z-direction grid specification
NZ=110
  ** define uniform grid initially
IREGZ=1;GRDPWR(Z,NZ,ZWLAST,-2.1)
ZWLAST=HEIGHT 

    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1,TEM1);SOLUTN(P1,Y,Y,Y,N,N,N)
SOLUTN(TEM1,Y,Y,Y,P,P,P)
MESG( Enter required turbulence model:
MESG( The options are:
MESG(  LB   - Lam-Brem low-Re k-e model 
MESG(  LBY  - Lam-Brem low-Re k-e model + Yap corr.
MESG(  2L   - 2-Layer low-Re k-e model
MESG(  KWR  - k-w low-Re Wilcox 2008 model
MESG(  KWS  - k-w low-Re SST model (default)

READVDU(CTUR,CHAR,LBY)
CASE :CTUR: OF
WHEN LB,2
+ TEXT(LoRe LB K E_2D IMPINGING ROUND JET
+ TLSC=EP;KELIN=3
+ MESG(Lam-Bremhorst low-Re k-e model
+ TURMOD(KEMODL-LOWRE)
WHEN LBY,3
+ TEXT(LoRe LB K E YAP_2D IMPINGING ROUND JET
+ TLSC=EP;KELIN=3
+ MESG(LamB low-Re k-e +Yap correction
+ TURMOD(KEMODL-LOWRE-YAP)
WHEN 2L,2
+ TEXT(2-LAYER_K E 2D IMPINGING ROUND JET
+ TLSC=EP;KELIN=3
+ MESG(2-LAYER k-e model
+ TURMOD(KEMODL-2L)
+ SELREF=F
WHEN KWR,3
+ TEXT(LoRe Wilcox 2008 K W_2D IMPINGING ROUND JET
+ TLSC=OMEG;KWMOD=T
+ MESG(Wilcox 2008 low-Re k-w model
+ TURMOD(KWMODLR-LOWRE);EPSIN=EPSIN/(0.09*TKEIN)
+ EPFRE=EPFRE/(0.09*KEFRE)
WHEN KWS,3
+ TEXT(LoRe K-W SST_2D IMPINGING ROUND JET
+ TLSC=OMEG;KWMOD=T
+ MESG(Low-Re k-w SST model
+ TURMOD(KWSST-LOWRE);EPSIN=EPSIN/(0.09*TKEIN)
+ EPFRE=EPFRE/(0.09*KEFRE)
ENDCASE 

SOLUTN(V1,P,P,P,P,P,N);SOLUTN(W1,P,P,P,P,P,N)
SOLUTN(TEM1,P,P,P,P,P,N)

STORE(LEN1,ENUT,YPLS,SKIN,STRS)

    __________________________________________________________________
   SAVE7BEGIN

(STORED of DWAL is 0.5*DZW)
(stored of TDIF is TEM1-:TAMB:)
   ** Local Heat transfer coefficient in (kW/m^2.degC)
(STORED TWAL at PLATE is TEM1)
   ** Plate temperature
(STORED TWAL at PLATE is TEM1+:QPLATE:*DWAL/COND)
   ** Local heat transfer coefficient
(STORED HTCL at PLATE is :QPLATE:/(TWAL-:TAMB:+TINY))
   ** Nusselt number
(STORED of NUSS is HTCL*:DIAM:/:COND:)
    ** Scaled Nusselt number
NUFAC=REY**(0.7)*PRLAM**(0.4)
(STORED of NUS is NUSS/:NUFAC:)
  SAVE7END
    _____________________________________________________________________

    GROUP 9. Properties of the medium (or media)
FLOW=RHO1*WJET*AIN
QIN=FLOW*TJET*CP
PRT(TEM1)=0.86;PRNDTL(TEM1)=PRLAM
CP1=CP
    GROUP 11. Initialization of variable or porosity fields
FIINIT(W1)=1.E-10;FIINIT(V1)=0.0;FIINIT(TEM1)=TAMB
FIINIT(KE)=TKEIN
IF(KWMOD) THEN
+ FIINIT(OMEG)=TKEIN/(10.*ENUL)
ELSE
+ FIINIT(EP)=0.09*TKEIN**2/(10.*ENUL)
ENDIF
PATCH(INWJET,INIVAL,1,1,1,NYJ,1,NZ,1,1)
COVAL(INWJET,W1,ZERO,WJET)
    GROUP 12. Convection and diffusion adjustments
      GROUP 13. Boundary conditions and special sources
   ** plate heating
WALL(PLATE,HIGH,1,NX,1,NY,NZ,NZ,1,1)
IF(FIXQ) THEN
+ PATCH(QPLATE,HIGH,1,NX,1,NY,NZ,NZ,1,1)
+ COVAL(QPLATE,TEM1,FIXFLU,QPLATE)
ELSE
  ** wall boundary conditions
+ COVAL(PLATE,TEM1,GRND2,TWAL)
ENDIF

  ** Uniform inlet conditions
INLET(JET1,LOW,1,1,1,NYJ,1,1,1,1)
VALUE(JET1,P1,RHO1*WJET);VALUE(JET1,W1,WJET)
VALUE(JET1,:TLSC:,EPSIN);VALUE(JET1,TEM1,TJET)
VALUE(JET1,KE,TKEIN)
 
  ** low entrainment boundary
PATCH(TOP,LOW,1,1,NYJ+1,NY,1,1,1,1)
COVAL(TOP,P1,1.E3,0.0);COVAL(TOP,W1,ONLYMS,0.0)
COVAL(TOP,U1,ONLYMS,0.0);COVAL(TOP,V1,ONLYMS,0.0)
COVAL(TOP,:TLSC:,ONLYMS,EPFRE)
COVAL(TOP,KE,ONLYMS,KEFRE);COVAL(TOP,TEM1,ONLYMS,TAMB)

  ** top entrainment boundary
PATCH(SIDE,NORTH,1,1,NY,NY,1,NZ,1,1)
COVAL(SIDE,P1,1.E8,0.0);COVAL(SIDE,W1,ONLYMS,0.0)
COVAL(SIDE,V1,ONLYMS,0.0);COVAL(SIDE,:TLSC:,ONLYMS,EPFRE)
COVAL(SIDE,KE,ONLYMS,KEFRE);COVAL(SIDE,TEM1,ONLYMS,TAMB)

    GROUP 15. Termination of sweeps
LSWEEP=6000
    GROUP 16. Termination of iterations
    GROUP 17. Under-relaxation devices
DTF=1.5*HEIGHT/WJET/NZ
   DTF=1.5*DTF
RELAX(W1,FALSDT,DTF); RELAX(V1,FALSDT,DTF)
RELAX(KE,FALSDT,DTF); RELAX(:TLSC:,FALSDT,DTF)
RELAX(TEM1,LINRLX,0.3)
IF(KWMOD) THEN
+ RELAX(KE,FALSDT,DTF); RELAX(OMEG,FALSDT,DTF)
ELSE
+ KELIN=3; RELAX(KE,LINRLX,0.4); RELAX(EP,LINRLX,0.7)
ENDIF
VARMAX(TEM1)=5.*TAMB;VARMIN(TEM1)=0.9*TAMB
    GROUP 22. Spot-value print-out
IYMON=42;IZMON=30
    GROUP 23. Field print-out and plot control
NPLT=25;TSTSWP=-1;WALPRN=T;ITABL=3
OUTPUT(ENUT,Y,N,N,Y,Y,Y)
OUTPUT(YPLS,N,N,N,N,N,N);OUTPUT(SKIN,N,N,N,N,N,N)
OUTPUT(TEM1,P,P,P,P,Y,Y)
SPEDAT(SET,OUTPUT,NOFIELD,L,T)
    GROUP 22. Monitor print-out
SPEDAT(SET,GXMONI,PLOTALL,L,T)

DISTIL=T
CASE :CTUR: OF
WHEN LB,2
+EX(TWAL)=2.769E+00;EX(DWAL)=2.727E-02
+EX(LEN1)=6.811E-02;EX(TEM1)=3.002E+02
+EX(P1  )=1.212E-02;EX(V1  )=6.081E-02 
+EX(W1  )=1.025E-01;EX(KE  )=4.649E-03 
+EX(EP  )=2.924E-03;EX(NUS )=9.850E-04 
+EX(NUSS)=2.116E+00;EX(HTCL)=5.529E-02 
+EX(TDIF)=3.664E-01;EX(STRS)=1.013E-05 
+EX(SKIN)=2.043E-01;EX(YPLS)=2.714E-03 
+EX(ENUT)=2.315E-03;EX(EPKE)=6.916E+00 
+EX(LTLS)=8.152E+00;EX(WDIS)=1.936E+00
WHEN LBY,3
+EX(TWAL)=2.797E+00;EX(DWAL)=2.727E-02
+EX(LEN1)=5.919E-02;EX(LTLS)=8.152E+00
+EX(WDIS)=1.936E+00;EX(TEM1)=3.003E+02
+EX(P1  )=1.216E-02;EX(V1  )=6.194E-02
+EX(W1  )=1.024E-01;EX(KE  )=3.960E-03
+EX(EP  )=1.672E-03;EX(NUS )=5.082E-04
+EX(NUSS)=1.092E+00;EX(HTCL)=2.853E-02
+EX(TDIF)=5.382E-01;EX(STRS)=6.534E-06
+EX(SKIN)=2.803E-01;EX(YPLS)=2.208E-03
+EX(ENUT)=1.955E-03;EX(EPKE)=3.957E+05
WHEN 2L,2
+EX(TWAL)=2.797E+00;EX(DWAL)=2.727E-02
+EX(ENUT)=3.406E-03;EX(LEN1)=1.742E-01 
+EX(LTLS)=8.152E+00;EX(WDIS)=1.936E+00 
+EX(TEM1)=3.004E+02;EX(EPKE)=1.362E+01 
+EX(P1  )=1.214E-02;EX(V1  )=6.179E-02
+EX(W1  )=1.024E-01;EX(KE  )=3.959E-03
+EX(EP  )=1.745E-03;EX(NUS )=4.968E-04
+EX(NUSS)=1.067E+00;EX(HTCL)=2.789E-02
+EX(TDIF)=5.497E-01;EX(STRS)=6.748E-06
+EX(SKIN)=2.649E-01;EX(YPLS)=2.252E-03
+EX(ENUT)=2.205E-03;EX(LEN1)=2.264E-01
WHEN KWS,3
+EX(P1  )=1.023E-02;EX(V1  )=5.771E-02
+EX(W1  )=9.500E-02;EX(KE  )=4.629E-03
+EX(EP  )=1.219E-03;EX(NUS )=5.310E-04
+EX(NUSS)=1.141E+00;EX(HTCL)=2.980E-02
+EX(TDIF)=5.037E-01;EX(STRS)=5.361E-06
+EX(SKIN)=3.080E-01;EX(YPLS)=2.040E-03
+EX(ENUT)=2.347E-03;EX(LEN1)=6.708E-02
+EX(GEN1)=5.271E+01;EX(BF2 )=4.951E-01
+EX(TWAL)=2.819E+00;EX(DWAL)=2.727E-02 
+EX(LTLS)=8.152E+00;EX(WDIS)=1.936E+00 
+EX(BF1 )=3.605E-01;EX(OMEG)=5.162E+02 
+EX(TEM1)=3.005E+02 
WHEN KWR,3
+EX(TWAL)=2.800E+00;EX(DWAL)=2.727E-02
+EX(FBP )=8.954E-01;EX(OMEG)=5.475E+02
+EX(TEM1)=3.004E+02;EX(P1  )=8.929E-03 
+EX(V1  )=5.584E-02;EX(W1  )=9.211E-02 
+EX(KE  )=6.071E-03;EX(EP  )=1.393E-03 
+EX(NUS )=5.024E-04;EX(NUSS)=1.079E+00 
+EX(HTCL)=2.820E-02;EX(TDIF)=5.670E-01 
+EX(STRS)=4.085E-06;EX(SKIN)=4.030E-01 
+EX(YPLS)=1.783E-03;EX(ENUT)=4.138E-03 
+EX(LEN1)=9.813E-02;EX(DWDZ)=6.837E-02 
+EX(DWDY)=9.827E-02;EX(DVDZ)=1.067E+00 
+EX(DVDY)=3.511E-02;EX(DUDX)=4.751E-02 
+EX(GEN1)=3.182E+01;EX(XWP )=1.419E+00 
ENDCASE
STOP