TEXT(YAP_KE 2D IMPINGING ROUND JET: T303
TITLE
 
  DISPLAY
   The case considered is the normal impingement of a turbulent
   round jet of air on a heated flat plate. The jet issues into
   atmospheric ambient fluid at a Reynolds number of 70,000 from a
   pipe located 6 pipe diameters above the electrically heated
   plate. The jet injection temperature is ambient so that the
   purpose of the flow process is to effect cooling. For the case
   of orthogonal impaction, the flow is axisymmetric and is directed
   outward along the surface giving rise to a radial wall jet.
   The calculation may be performed with one of five turbulence
   models: the k-e model with the Yap correction; the k-omega model;
   the two-layer low-Re k-e model; the Lam-Bremhorst low-Re k-e
   model + Yap correction; and the k-omega low-Re model. The high-Re
   models use a mesh of 70 radial and 61 axial cells, and the low-Re
   models use a mesh of 70 radial by 112 axial cells.
  ENDDIS
   This case is the validation case investigated at CFD95, Canada
   (see Pollard et al (1996), CFDSC/V/95-3) and in the 2nd ERCOFTAC
   -IAHR Workshop on Refined-Flow Modelling. The flow geometry and
   conditions approximate to those reported experimentally by
   D.Cooper et al ( Int.J.Heat Mass Transfer, Vol.36, No.10, p2675,
   [1993] ).
   The calculation is set to run for 200 sweeps with the high-Re
   k-e model + yap correction, although about more sweeps are
   required for convergence. Typically, the low-Re calculations
   require several thousand sweeps for convergence, and the high-Re
   calculations about 1000 sweeps.
 
   PHOTON USE
   p
 
 
    0.20443E+04 0.15633E+04 CR
   vec x 1 sh
   rot
   90
   pause
   cl;con p1 x 1 fi;1;gr x 1
   pause
   cl;con ke x 1 fi;1
   pause
   cl;con tmp1 x 1 fi;1
   pause
   ENDUSE
 
CHAR(CTUR,TLSC);INTEGER(TMODEL);BOOLEAN(LOWRE,KO);LOWRE=F;KO=F
BOOLEAN(FIXQ);FIXQ=T
MESG( Enter required turbulence model:
MESG( The options are:
MESG(  KYAP  - k-e model + Yap corr. (default)
MESG(  KOM   - k-omega model
MESG(  TWOL  - 2-Layer low-Re k-e model
MESG(  LAMB  - Lam-Brem low-Re k-e model + Yap corr.
MESG(  KOLO  - k-omega low-Re model
READVDU(CTUR,CHAR,KYAP)
CASE :CTUR: OF
WHEN KYAP,4
+ TMODEL=1;TLSC=EP;KELIN=1
+ MESG(Yap  k-e model
WHEN TWOL,4
+ TEXT(2-LAYER_2D IMPINGING ROUND JET
+ TMODEL=2;LOWRE=T;TLSC=EP;KELIN=3
+ MESG(2-LAYER k-e model
+ SELREF=F
WHEN LAMB,4
+ TEXT(LAMB_2D IMPINGING ROUND JET
+ TMODEL=3;LOWRE=T;TLSC=EP;KELIN=3
+ MESG(LAMB low-Re k-e model
WHEN KOM,3
+ TEXT(KO_2D IMPINGING ROUND JET
+ TMODEL=4;TLSC=OMEG;KO=T
+ MESG(k-omega model
WHEN KOLO,3
+ TEXT(KO LOW-RE_2D IMPINGING ROUND JET
+ TMODEL=5;TLSC=OMEG;LOWRE=T;KO=T
+ MESG(k-omega low-Re model
ENDCASE
INTEGER(NYJ,NYFS)
REAL(REY,DIAM,HEIGHT,WJET,RADJ,TKEIN,EPSIN,DTF,AIN,FLOW)
REAL(YPLS1,DELZ1,DELZ,AA,KFAC,US,SFAC,VREL,ENUFRE,KEFRE,EPFRE)
REAL(CP,TJET,TAMB,QPLATE,QIN,COND,PRLAM,NUSLT,DELTEM,EPSINI)
REAL(TWAL)
CP=1005.0;TJET=300.0;TAMB=TJET; REY=7.E4;TWAL=310.0
PRLAM=0.71; RHO1=1.178;ENUL=1.567E-5
DIAM=1.0; RADJ=0.5*DIAM;HEIGHT=6.*DIAM
WJET=REY*ENUL/DIAM;TKEIN=0.01*WJET*WJET
COND=CP*RHO1*ENUL/PRLAM;EPSIN=.1643*TKEIN**1.5/(0.09*DIAM)
NUSLT=0.045*(REY**0.7)*PRLAM**0.4
DELTEM=10.0;QPLATE=NUSLT*COND*DELTEM/DIAM
ENUFRE=ENUL;KEFRE=1.E-5;EPFRE=0.09*KEFRE**2/ENUFRE
    GROUP 3. X-direction grid specification
CARTES=F;NX=1;XULAST=0.1;AIN=0.5*RADJ*RADJ*XULAST
    GROUP 4. Y-direction grid specification
NYJ=20;NYFS=50
NREGY=2; REGEXT(Y,7.*DIAM);IREGY=1;GRDPWR(Y,NYJ,RADJ,1.0)
IREGY=2;GRDPWR(Y,NYFS,7.*DIAM-RADJ,1.1)
    GROUP 5. Z-direction grid specification
  ** define first dely from wall
  ** The grid-expansion factor Kfac defines a constant ratio
     of lengths of two adjacent cells.
IF(LOWRE) THEN
+ KFAC=1.055;YPLS1=1.5
ELSE
+ KFAC=1.05;YPLS1=30.
ENDIF
 
ZWLAST=1.0
SFAC=5.E-3;VREL=0.4;US=(SFAC)**0.5*VREL
DELZ1=YPLS1*ENUL/US;DELZ=DELZ1/HEIGHT
  ** calculate NZ from delZ & Kfac
AA=(ZWLAST/DELZ)*(KFAC-1.0)+1.0
AA=LOG(AA)/LOG(KFAC)+1.0001
NZ=AA
  ** define uniform grid initially
IREGZ=1;GRDPWR(Z,NZ,ZWLAST,1.0)
  ** compute expanding grid from north boundary
ZFRAC(NZ)=1.0;INTEGER(JJM,JJM1)
DO JJ=NZ,2,-1
+ JJM=JJ-1
+ ZFRAC(JJM)=ZFRAC(JJ)-DELZ
+ DELZ=KFAC*DELZ
ENDDO
ZWLAST=HEIGHT
 
DTF=5.*HEIGHT/WJET/NZ
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1,H1);SOLUTN(P1,Y,Y,Y,N,N,N)
SOLUTN(H1,Y,Y,Y,P,P,P)
 
CASE (TMODEL) OF
WHEN 1
+ TURMOD(KEMODL-YAP);WALLCO=GRND2
WHEN 2
+ TURMOD(KEMODL-2L);WALLCO=GRND2
WHEN 3
+ TURMOD(KEMODL-LOWRE-YAP);WALLCO=GRND2
WHEN 4
+ TURMOD(KOMODL);STORE(EP);WALLCO=GRND2;EPSIN=EPSIN/(0.09*TKEIN)
+ EPFRE=EPFRE/(0.09*KEFRE)
WHEN 5
+ TURMOD(KOMODL-LOWRE);WALLCO=GRND2;EPSIN=EPSIN/(0.09*TKEIN)
+ EPFRE=EPFRE/(0.09*KEFRE)
ENDCASE
SOLUTN(V1,P,P,P,P,P,N);SOLUTN(W1,P,P,P,P,P,N)
SOLUTN(H1,P,P,P,P,P,N)
STORE(LEN1,ENUT,TMP1,YPLS,SKIN)
    GROUP 9. Properties of the medium (or media)
FLOW=RHO1*WJET*AIN
QIN=FLOW*TJET*CP
PRT(H1)=0.86;PRNDTL(H1)=PRLAM;TMP1=LINH;TMP1A=0.0;TMP1B=1./CP
    GROUP 11. Initialization of variable or porosity fields
FIINIT(W1)=1.E-10;FIINIT(V1)=0.0;FIINIT(H1)=CP*TAMB
FIINIT(KE)=TKEIN
IF(KO) THEN
+ FIINIT(OMEG)=TKEIN/(10.*ENUL)
ELSE
+ FIINIT(EP)=0.09*TKEIN**2/(10.*ENUL)
ENDIF
PATCH(INWJET,INIVAL,1,1,1,NYJ,1,NZ,1,1)
COVAL(INWJET,W1,ZERO,WJET)
    GROUP 12. Convection and diffusion adjustments
      GROUP 13. Boundary conditions and special sources
   ** plate heating
WALL(PLATE,HIGH,1,NX,1,NY,NZ,NZ,1,1)
IF(FIXQ) THEN
+ PATCH(QPLATE,HIGH,1,NX,1,NY,NZ,NZ,1,1)
+ COVAL(QPLATE,H1,FIXFLU,QPLATE)
ELSE
  ** wall boundary conditions
+ COVAL(PLATE,H1,GRND2,CP*TWAL)
ENDIF
  ** Uniform inlet conditions
INLET(JET1,LOW,1,1,1,NYJ,1,1,1,1)
VALUE(JET1,P1,RHO1*WJET);VALUE(JET1,W1,WJET)
VALUE(JET1,:TLSC:,EPSIN);VALUE(JET1,H1,CP*TJET)
VALUE(JET1,KE,TKEIN)
 
  ** low entrainment boundary
PATCH(TOP,LOW,1,1,NYJ+1,NY,1,1,1,1)
COVAL(TOP,P1,1.E3,0.0);COVAL(TOP,W1,ONLYMS,0.0)
COVAL(TOP,U1,ONLYMS,0.0);COVAL(TOP,V1,ONLYMS,0.0)
COVAL(TOP,:TLSC:,ONLYMS,EPFRE)
COVAL(TOP,KE,ONLYMS,KEFRE);COVAL(TOP,H1,ONLYMS,CP*TAMB)
  ** top entrainment boundary
PATCH(SIDE,NORTH,1,1,NY,NY,1,NZ,1,1)
COVAL(SIDE,P1,1.E8,0.0);COVAL(SIDE,W1,ONLYMS,0.0)
COVAL(SIDE,V1,ONLYMS,0.0);COVAL(SIDE,:TLSC:,ONLYMS,EPFRE)
COVAL(SIDE,KE,ONLYMS,KEFRE);COVAL(SIDE,H1,ONLYMS,CP*TAMB)
    GROUP 15. Termination of sweeps
LSWEEP=300
    GROUP 16. Termination of iterations
    GROUP 17. Under-relaxation devices
DTF=0.5*HEIGHT/WJET/NZ;DTF=1.5*DTF
RELAX(W1,FALSDT,DTF); RELAX(V1,FALSDT,DTF)
RELAX(KE,FALSDT,DTF); RELAX(:TLSC:,FALSDT,DTF)
RELAX(H1,linrlx,0.5)
IF(KO) THEN
+ RELAX(KE,FALSDT,DTF); RELAX(OMEG,FALSDT,DTF)
ELSE
+ KELIN=3; RELAX(KE,LINRLX,0.4); RELAX(EP,LINRLX,0.7)
ENDIF
    GROUP 22. Spot-value print-out
IF(LOWRE) THEN
+ IYMON=42;IZMON=30
ELSE
+ IYMON=50;IZMON=NZ-10
ENDIF
    GROUP 23. Field print-out and plot control
NPLT=25;TSTSWP=-1;WALPRN=T;ITABL=3
OUTPUT(ENUT,Y,N,N,Y,Y,Y)
OUTPUT(YPLS,N,N,N,N,N,N);OUTPUT(SKIN,N,N,N,N,N,N)
OUTPUT(TMP1,p,p,p,p,y,y)
IF(LOWRE) THEN
+ STORE(REYN,FMU,FTWO);STORE(FONE)
ENDIF
STORE(STAN,STRS,SKIN,STNO)
CP1     = 1.005000E+03