TEXT(Realisable KE_2D Elliptic Round Free Jet: T309
TITLE
  DISPLAY
  The problem considered is the submerged free turbulent round
  jet in stagnant surroundings. The jet issues from a pipe of
  diameter D at a Reynolds number of 38,500. The calculation is 
  carried out with the elliptic solver for a domain which is 30D
  long by 7.5D wide.
 
  Calculations are performed with the standard k-e & k-w models,
  and the following k-e variants: Chen-Kim, RNG and Realisable
  k-e models. The experimental data indicate a velocity half-
  width spreading rate of 0.086 in the self-similar region of
  the jet. The present calculations predict the following
  spreading rates:
 
               data    k-e    chen-kim   RNG   Realisable  k-w
     dyh/dz    .086    .11     .11      .168    .10         ?
 
  All results are in poor agreement with the experimental data,
  especially the RNG model. The realisable k-e model performs
  best by almost having the discrepancy found with the standard
  k-e model. The half-width spreading rate is calculated
  approximately using In-Form commands and then written to the 
  text output file named inforout.
  
  As noted by Menter [1992] the current form of Wilcox k-w model
  dates from 1988, and it predicts much higher eddy viscosities than
  the k-e model, which leads to a much larger jet spreading rate.
  Therefore, this form of the model isn't suited for the prediction
  of free jets, but it is coded here in preparation for a future
  extension to the Wilcox 1998 model which performs much better
  for free jets. - F.R.Menter, "Improved 2-equation k-w turbulence
  models for aerodynamic flows", NASA TN 103975, (1992).
  ENDDIS
    GROUP 1. Run title and other preliminaries
REAL(WINJ,WIN_FS,KE_FS,EP_FS,KEINJ,EPINJ,DIAM,PRADO,PRADI,CD)
REAL(OM_FS,OMINJ,LAMVIS,ENUT_FS,TINJ,TIN_FS,REYNO)
REYNO=3.85E4
DIAM=0.058;PRADI=0.5*DIAM;PRADO=15.*PRADI
CD=0.1643

  ** jet-inflow conditions
WINJ=20.;TINJ=0.05
KEINJ=(TINJ*WINJ)**2; EPINJ=CD*KEINJ**1.5/(0.1*PRADI)
   ** laminar kinematic viscosity
LAMVIS=WINJ*DIAM/REYNO
   ** free-stream conditions
WIN_FS=WINJ/100.;TIN_FS=0.05
ENUT_FS=5.*LAMVIS
KE_FS=(TIN_FS*WIN_FS)**2;EP_FS=0.09*KE_FS**2/ENUT_FS
    GROUP 3. X-direction grid specification
CARTES=F;XULAST=0.1
    GROUP 4. Y-direction grid specification
INTEGER(NYF,NYO,NYG)
NYF=10;NYO=50;NYG=NYF+NYO
NREGY=2;NY=46
IREGY=1;GRDPWR(Y,NYF,PRADI,1.0)
IREGY=2;GRDPWR(Y,NYO,-(PRADO-PRADI),1.04)
 
    GROUP 5. Z-direction grid specification
NZ=120;GRDPWR(Z,NZ,-(30.*DIAM),1.01)
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1);STORE(ENUT)
SOLUTN(P1,P,P,Y,P,P,P);SOLUTN(V1,P,P,P,P,P,N)
SOLUTN(W1,P,P,P,P,P,N)
INTEGER(JKO);JKO=0
CHAR(CTURB)
MESG( Enter the required turbulence model:
MESG(  KEM  -  Standard k-e model
MESG(  CKM  -  Chen Kim k-e model
MESG(  RNG  -  RNG  k-e model
MESG(  KOM  -  Wilcox k-omega model
MESG(  RKE  -  Realisable k-e model (default)
MESG(
READVDU(CTURB,CHAR,RKE)
CASE :CTURB: OF
WHEN KEM,3
+ TEXT(standard KE_2D Elliptic Round Free Jet
+ MESG(Standard k-e model
+ TURMOD(KEMODL)
WHEN CKM,3
+ TEXT(Chen-Kim KE_2D Elliptic Round Free Jet
+ MESG(Chen Kim k-e model
+ TURMOD(KECHEN)
WHEN RNG,3
+ TEXT(RNG KE_2D Elliptic Round Free Jet
+ MESG(RNG k-e model
+ TURMOD(KERNG)
WHEN KOM,3
+ TEXT(KO_2D Elliptic Round Free Jet
+ MESG(k-omega model
+ TURMOD(KOMODL)
+ STORE(EP);OMINJ=EPINJ/(0.09*KEINJ)
+ OM_FS=EP_FS/(0.09*KE_FS)
+ JKO=1
WHEN RKE,3
+ TEXT(Realisable KE_2D Elliptic Round Free Jet
+ MESG(RK k-e model
+ TURMOD(KEREAL)
+ STORE(CMU,C1E)
+ OUTPUT(CMU,P,P,P,P,Y,Y);OUTPUT(C1E,P,P,P,P,Y,Y)
ENDCASE

    GROUP 8. Terms (in differential equations) & devices
    GROUP 9. Properties of the medium (or media)
ENUL=LAMVIS
    GROUP 11. Initialization of variable or porosity fields
FIINIT(W1)=WIN_FS
PATCH(INIT,INIVAL,1,NX,1,NYF,1,NZ,1,LSTEP)
INIT(INIT,W1,0.0,WINJ); FIINIT(KE)=KEINJ;FIINIT(EP)=EPINJ
    GROUP 13. Boundary conditions and special sources
  ** Jet Inlet Conditions
INLET(IN1,LOW,1,NX,1,NYF,1,1,1,LSTEP)
VALUE(IN1,P1,RHO1*WINJ); VALUE(IN1,W1,WINJ)
VALUE(IN1,KE,KEINJ);VALUE(IN1,EP,EPINJ)
IF(JKO.GT.0) THEN
+VALUE(IN1,OMEG,OMINJ);FIINIT(OMEG)=OMINJ
ENDIF
  ** Free Boundary Conditions
INLET(IN2,LOW,1,NX,#2,#2,1,1,1,LSTEP)
VALUE(IN2,P1,RHO1*WIN_FS);VALUE(IN2,W1,WIN_FS)
VALUE(IN2,KE,KE_FS);VALUE(IN2,EP,EP_FS)
IF(JKO.GT.0) THEN
+VALUE(IN2,OMEG,OM_FS)
ENDIF  
  
PATCH(FREEB,NORTH,1,NX,NYG,NYG,1,NZ,1,LSTEP)
COVAL(FREEB,W1,ONLYMS,WIN_FS)
COVAL(FREEB,KE,ONLYMS,KE_FS);COVAL(FREEB,EP,ONLYMS,EP_FS)
COVAL(FREEB,P1,1.E3,0.0)
IF(JKO.GT.0) THEN  		  
+VALUE(FREEB,OMEG,OM_FS)
ENDIF

OUTLET(OUT,HIGH,1,NX,1,NYG,NZ,NZ,1,LSTEP)
COVAL(OUT,P1,1.E3,0.0)
VALUE(OUT,V1,0.0); VALUE(OUT,W1,0.0)
VALUE(OUT,KE,0.0);VALUE(OUT,EP,0.0)
IF(JKO.GT.0) THEN
+VALUE(OUT,OMEG,0.0)
ENDIF
 
    GROUP 15. Termination of sweeps
LSWEEP=1000
    GROUP 16. Termination of iterations
    GROUP 17. Under-relaxation devices
KELIN=3
REAL(RLXFAC); RLXFAC=8.*ZWLAST/WINJ/NZ
RELAX(V1,FALSDT,RLXFAC); RELAX(W1,FALSDT,RLXFAC)
RELAX(KE,LINRLX,0.4); RELAX(EP,LINRLX,0.4)
CASE :CTURB: OF
WHEN RKE,3
+ RELAX(KE,FALSDT,RLXFAC); RELAX(EP,FALSDT,RLXFAC)
+ RELAX(ENUT,LINRLX,0.2)
+ VARMAX(ENUT)=0.1
WHEN KOM,3
+RLXFAC=ZWLAST/WINJ/NZ
+RELAX(V1,FALSDT,4.*RLXFAC);RELAX(W1,FALSDT,4.*RLXFAC)
+RELAX(EP,LINRLX,1.0);RELAX(ENUT,LINRLX,0.25)
+RELAX(KE,FALSDT,4.*RLXFAC);RELAX(OMEG,FALSDT,4.*RLXFAC)
   ** ENUT is limited to 0.06 m^2/s to prevent
      an unrealistic final solution
+VARMAX(ENUT)=0.06
+LSWEEP=1800
+OUTPUT(EP,P,P,P,P,Y,Y)
ENDCASE
    GROUP 18. Limits on variables or increments to them
    GROUP 20. Preliminary print-out
ECHO=T
    GROUP 21. Print-out of variables
NYPRIN=1
    GROUP 22. Spot-value print-out
TSTSWP=-1
IYMON=NYF+2;IZMON=NZ-1;NPLT=10;ITABL=3;NZPRIN=1

    GROUP 23. Field print-out and plot control
    GROUP 24. Dumps for restarts
   ** compute half-width spreading rate for inforout file
(stored of wh is 0.5*W1[&1&] )
(stored of YGP is YG)
PATCH(HWIDTH,CELL,1,NX,2,NY-1,1,NZ-1,1,LSTEP)
(stored of YH is 0.0)
(stored of YH at HWIDTH is YGP with IF(W1.GT.WH.AND.W1[,+1,].LT.WH))
INTEGER(IZ1);IZ1=3*NZ/4
PATCH(HWIDTH1,CELL,1,NX,2,NY-1,IZ1,IZ1,1,LSTEP)
PATCH(HWIDTH2,CELL,1,NX,2,NY-1,NZ-1,NZ-1,1,LSTEP)
(make1 dyhdz)
(MAKE1 YH1)
(store1 of YH1 at HWIDTH1 is MAX(YH,1.1E-10))
(PRINT YH1 IS YH1)
(MAKE1 YH2)
(store1 of YH2 at HWIDTH2 is MAX(YH,1.1E-10))
(PRINT YH2 IS YH2)
(stored of ZGM is ZG)
(store1 of dyhdz is (YH2-YH1)/(ZGM[,1,NZ-1]-ZGM[,1,:IZ1:]))
(PRINT DYHDZ IS DYHDZ)

RESFAC=1.E-4

DISTIL=T
CASE :CTURB: OF
WHEN KEM,3
+EX(P1  )=9.599E-02;EX(V1  )=1.382E-01 
+EX(W1  )=3.588E+00;EX(KE  )=2.341E+00 
+EX(EP  )=1.389E+02;EX(ZGM )=7.009E-01 
+EX(YH  )=1.195E-03;EX(YGP )=1.437E-01 
+EX(WH  )=6.250E+00;EX(EPKE)=1.994E+01 
+EX(ENUT)=9.597E-03 
WHEN CKM,3
+EX(P1  )=7.320E-02;EX(V1  )=1.227E-01
+EX(W1  )=3.723E+00;EX(KE  )=2.074E+00
+EX(EP  )=1.291E+02;EX(ZGM )=7.009E-01
+EX(YH  )=9.887E-04;EX(YGP )=1.437E-01
+EX(WH  )=6.880E+00;EX(EPKE)=2.261E+01
+EX(ENUT)=8.212E-03
WHEN RNG,3
+EX(P1  )=1.099E-01;EX(V1  )=1.431E-01
+EX(W1  )=3.536E+00;EX(KE  )=2.441E+00
+EX(EP  )=1.281E+02;EX(ZGM )=7.009E-01
+EX(YH  )=1.303E-03;EX(YGP )=1.437E-01
+EX(WH  )=6.298E+00;EX(EPKE)=2.038E+01
+EX(ENUT)=1.253E-02
WHEN KOM,3
+EX(P1  )=5.301E-01;EX(V1  )=1.742E-01
+EX(W1  )=1.897E+00;EX(KE  )=1.116E+01
+EX(EP  )=3.611E+02;EX(ZGM )=7.009E-01
+EX(YH  )=1.504E-03;EX(YGP )=1.437E-01
+EX(WH  )=2.209E+00;EX(EPKE)=1.000E-10
+EX(OMEG)=1.044E+02;EX(ENUT)=5.971E-02
WHEN RKE,3
+EX(P1  )=1.305E-01;EX(V1  )=1.469E-01
+EX(W1  )=3.445E+00;EX(KE  )=2.526E+00
+EX(EP  )=1.544E+02;EX(ZGM )=7.009E-01
+EX(YH  )=1.415E-03;EX(YGP )=1.437E-01
+EX(WH  )=5.621E+00;EX(C1E )=5.655E-01
+EX(DWDZ)=4.708E+00;EX(DWDY)=5.334E+01
+EX(DVDZ)=7.864E-01;EX(DVDY)=4.056E+00
+EX(DUDX)=2.478E+00;EX(EPKE)=1.887E+01
+EX(CMU )=9.016E-02;EX(ENUT)=1.300E-02
ENDCASE