DISPLAY
  The case considered is 2d developing flow and heat transfer
  in plane two-dimensional channel. The Reynolds number is 1.E4
  based on channel height and the laminar Prandtl number is unity.
  The solution domain encompasses both sides of the channel so as
  to provide a test of symmetry. The calculation may be carried
  out with the elliptic or parabolic solution algorithm. The
  results are essentially symmetric about the channel centre line
  though not perfect, and the reasons for the slight asymmetry need
  to be investigated.
  ENDDIS
 
CHAR(RUNTYP); RUNTYP=ELLIPTIC
BOOLEAN(HEAT);HEAT=T;IRSMSM=2; RUNTYP=PARABOLIC
REAL(GMIXL,TKEIN,EPSIN,DTFS,FLOW,REY,WIN,RHOIN); REY=1.E4
REAL(XLEN,YLEN,ZLEN);XLEN=1.0;YLEN=1.0;ZLEN=50.0
WIN=1.0; RHOIN=1.0
TEXT(RSTM_2DY-Z :RUNTYP: CHANNEL        :T607
TITLE
RSET(D,CHANL,XLEN,YLEN,ZLEN,1,0)
IF(:RUNTYP:.EQ.PARABOLIC) THEN
+ PARAB=T;WALPRN=T;NZ=100
ELSE
+ NZ=30
ENDIF
NX=1;NY=20; RSET(M,NX,NY,NZ)
SOLVE(P1);SOLUTN(P1,Y,Y,Y,P,P,P);SOLVE(V1,W1)
IF(HEAT) THEN
+ SOLVE(H1);TERMS(H1,N,P,P,P,P,P)
ENDIF
    ** inflow boundary
PATCH(INL/1,LOW,#1,#1,#1,#1,#1,#1,1,1)
COVAL(INL,P1,FIXFLU,RHOIN*WIN)
COVAL(INL,W1,ONLYMS,WIN);COVAL(INL,V1,ONLYMS,0)
    ** outflow boundary
IF(.NOT.PARAB) THEN
+ PATCH(OUT/2,HIGH,#1,#1,#1,#1,#1,#1,1,1);COVAL(OUT,P1,1.E4,0.0)
ENDIF
    ** upper channel wall
PATCH(WAL/3,NWALL,#1,#1,#1,#1,#1,#1,1,1);COVAL(WAL,W1,1.0,0)
    ** lower channel wall
PATCH(WL2/3,SWALL,#1,#1,#1,#1,#1,#1,1,1);COVAL(WL2,W1,1.0,0)
DIFCUT=0.;DTFS=ZWLAST/WIN/NZ;TURMOD(REYSTRS,DTFS,WAL,WL2)
STORE(FWAL);ENUL=YLEN*WIN/REY;GMIXL=0.035*YVLAST
TKEIN=0.5*(0.1*WIN)**2;EPSIN=TKEIN**1.5/GMIXL*.1643
VALUE(INL,KE,TKEIN);VALUE(INL,EP,EPSIN)
VALUE(INL,U2RS,2.*TKEIN/3.);VALUE(INL,V2RS,2.*TKEIN/3.)
VALUE(INL,W2RS,2.*TKEIN/3.)
FIINIT(W1)=WIN;FIINIT(KE)=TKEIN;FIINIT(EP)=EPSIN
FIINIT(W2RS)=2.*TKEIN/3.;FIINIT(V2RS)=2.*TKEIN/3.
FIINIT(U2RS)=2.*TKEIN/3.;FIINIT(VWRS)=0.3*TKEIN
IF(PARAB) THEN
+ LITHYD=10
ELSE
+ LSWEEP=200
ENDIF
TSTSWP=-1;IYMON=NY-2;IZMON=NZ/2
FLOW=RHOIN*WIN*YLEN*XLEN
RESREF(P1)=1.E-12*FLOW/RHOIN; RESREF(W1)=1.E-12*FLOW*WIN
RESREF(V1)=RESREF(W1); RESREF(EP)=1.E-12*FLOW*EPSIN
RESREF(U2RS)=1.E-12*FLOW*FIINIT(U2RS); RESREF(V2RS)=RESREF(U2RS)
RESREF(W2RS)=RESREF(U2RS); RESREF(VWRS)=1.E-12*FLOW*FIINIT(VWRS)
RELAX(P1,LINRLX,1.0); RELAX(V1,FALSDT,DTFS); RELAX(W1,FALSDT,DTFS)
RELAX(EP,FALSDT,DTFS/5.); RELAX(U2RS,FALSDT,DTFS/5.)
RELAX(V2RS,FALSDT,DTFS/5.); RELAX(W2RS,FALSDT,DTFS/5.)
RELAX(VWRS,FALSDT,DTFS/5.)
IF(HEAT) THEN
+ REAL(CPGAS,TIN,TWALL,HIN);TIN=50.+273.;TWALL=20.+273.
+ CPGAS=1.E3;HIN=CPGAS*TIN;FIINIT(H1)=HIN;VALUE(INL,H1,HIN)
+ COVAL(WAL,H1,LOGLAW,CPGAS*TWALL);COVAL(WL2,H1,LOGLAW,CPGAS*TWALL)
+ RELAX(H1,FALSDT,DTFS); RHO1=RECSCAL; RHO1A=0.0;
+ RHO1B=1./(CPGAS*TIN)
IF(.NOT.PARAB) THEN
+ RELAX(VTRS,FALSDT,DTFS/5.); RELAX(WTRS,FALSDT,DTFS/5.)
ENDIF
ENDIF