PHOTON USE
  p
  phi
 
 
 
  msg grid
  gr x 1
  msg Press  to continue
  pause
  cl
  msg 1st-phase (light fluid) velocity vectors
  set vec comp
  - vcrt wcrt
  vec x 1 sh
  gr ou x 1
  msg Press  to continue
  pause
  cl
  msg 2nd-phase (dense fluid) velocity vectors
  set vec comp
  - v2cr w2cr
  vec x 1 sh
  gr ou x 1
  msg Press  to continue
  pause
  cl
  msg contour of pressure
  con p1 x 1 fi;0.002
  gr ou x 1
  msg Press  to continue
  pause
  cl
  msg contour of 1st-phase (light fluid) volume fraction
  con r1 x 1 fi;0.002
  gr ou x 1
  msg Press  to continue
  pause
  cl
  msg contour of 2nd-phase (dense fluid) volume fraction
  con r2 x 1 fi;0.002
  gr ou x 1
  msg Press e to END
  enduse
TEXT(PLANE 2PHS FLOW IN TURNAROUND DUCT: W568
TITLE
  DISPLAY
    This case concerns plane, two-dimensional, incompressible
    two phase flow through a 180 degree turnaround duct. It
    is based on Library case b527; but there is friction at the
    walls.
  ENDDIS
    GROUP 1. Run title
REAL(REYNO,WIN,DIAM);REYNO=3.E6;DIAM=30.;WIN=1.0
    GROUP 6. Body-fitted coordinates or grid distortion
BFC=T;NONORT=T
GSET(D,1,10,20,1.0,DIAM,100.0)
GSET(C,K21,F,K21,+,0.0,110.0,0.0)
GSET(C,K17,F,K21,+,0.0,0.0,-100.0,INC,1.0)
GSET(C,K5,F,K17,RX,-3.14159,95.0,0.0,INC,1.0)
GSET(C,K1,F,K5,+,0.0,0.0,100.0,INC,1.0)
    Set wup=t to account better for the high curvature of
    the w resolute...
WUP=T
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1);SOLUTN(P1,Y,Y,Y,N,N,N)
ONEPHS=F;SOLVE(V2,W2,R1,R2)
    Activate the following line if the properties are required.
    STORE(REYN,VREL,CD,APRJ,CFIPS)
    GROUP 9. Properties of the medium (or media)
ENUL=WIN*DIAM/REYNO;ENUT=0.0;RHO2=1000.0
    GROUP 11. Initialization of variable or porosity fields
FIINIT(P1)=1.E-10;FIINIT(W1)=WIN
FIINIT(W2)=WIN;FIINIT(R1)=0.5;FIINIT(R2)=0.5
    Activate interphase drag law for spherical particles
CFIPS=GRND7
    Set minimum slip velocity, and particle diameter
CFIPA=0.001;CFIPB=0.2E-2
    GROUP 13. Boundary conditions and special sources
    Inlet velocities and volume fractions are the same for
    both phases
INLET(INLET,LOW,1,1,1,NY,1,1,1,1)
VALUE(INLET,P1,0.5*RHO1*WIN);VALUE(INLET,W1,WIN)
VALUE(INLET,P2,0.5*RHO2*WIN);VALUE(INLET,W2,WIN)
PATCH(OUTLET,HIGH,1,1,1,NY,NZ,NZ,1,1)
COVAL(OUTLET,P1,1.E5,0.0);COVAL(OUTLET,P2,1.E5*RHO2,0.0)
COVAL(OUTLET,V1,ONLYMS,0.0);COVAL(OUTLET,W1,ONLYMS,0.0)
COVAL(OUTLET,V2,ONLYMS,0.0);COVAL(OUTLET,W2,ONLYMS,0.0)
WALL(TOP,NORTH,1,1,NY,NY,1,NZ,1,1)
WALL(BOT,SOUTH,1,1,1,1,1,NZ,1,1)
    GROUP 15. Termination of sweeps
LSWEEP=100
    GROUP 17. Under-relaxation devices
RELAX(P1,LINRLX,0.5)
RELAX(V1,FALSDT,10.0);RELAX(W1,FALSDT,10.0)
RELAX(V2,FALSDT,10.0);RELAX(W2,FALSDT,10.0)
    GROUP 22. Spot-value print-out
IYMON=5;IZMON=15
    GROUP 23. Field print-out and plot control
TSTSWP=-1