PHOTON USE
  p
  phi
 
 
 
  msg grid
  gr x 1
  msg Press  to continue
  pause
  cl
  msg 1st-phase (light phase) velocity vectors
  vec x 1 sh
  gr ou x 1
  msg Press  to continue
  pause
  cl
  msg 2nd-phase (dense phase) velocity vectors
  set vec comp
  - v2 w2
  vec x 1 sh
  gr ou x 1
  msg Press  to continue
  pause
  cl
  msg contour of pressure
  con p1 x 1 fi;0.002
  gr ou x 1
  msg Press  to continue
  pause
  cl
  msg contour of 1st-phase (light phase) volume fraction
  con r1 x 1 fi;0.002
  gr ou x 1
  msg Press  to continue
  pause
  cl
  msg contour of 1st-phase temperature
  con tmp1 x 1 fi;0.002
  gr ou x 1
  msg Press  to continue
  pause
  cl
  msg contour of 2nd-phase temperature
  con tmp2 x 1 fi;0.002
  gr ou x 1
  msg Press e to END
  enduse
 
TEXT(2PHS FLOW IN TURNAROUND DUCT :      W578
TITLE
  DISPLAY
   This case concerns plane, two-dimensional, incompressible
   two phase flow through a 180 degree turnaround duct. It
   is based on Library case b527.
 
   The gas enters at 300K, the particles at 600K. The wall
   surface temperature is 400k.
 
   The particle diameter is 1mm.
  ENDDIS
    GROUP 1. Run title
REAL(REYNO,WIN,DIAM);REYNO=3.E6;DIAM=30.;WIN=1.0
    GROUP 6. Body-fitted coordinates or grid distortion
BFC=T;NONORT=T
GSET(D,1,10,20,1.0,DIAM,100.0)
GSET(C,K21,F,K21,+,0.0,110.0,0.0)
GSET(C,K17,F,K21,+,0.0,0.0,-100.0,INC,1.0)
GSET(C,K5,F,K17,RX,-3.14159,95.0,0.0,INC,1.0)
GSET(C,K1,F,K5,+,0.0,0.0,100.0,INC,1.0)
   ** Set wup=t to account better for the high curvature of
      the w resolute...
WUP=T
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1);SOLUTN(P1,Y,Y,Y,N,N,N)
ONEPHS=F;SOLVE(V2,W2,R1,R2,H1,H2)
STORE(TMP1,TMP2)
    Activate the following line if required.
    STORE(REYN,VREL,CD,APRJ,CFIPS)
    GROUP 9. Properties of the medium (or media)
ENUL=WIN*DIAM/REYNO;ENUT=500*ENUL;RHO2=2000.0
TMP1=LINH; TMP1A=273; TMP1B=1/1000
TMP2=LINH; TMP2A=273; TMP2B=1/2000
CP1=1000.0; CP2=2000.0
    GROUP 10. Inter-phase-transfer processes and properties
   Activate interphase drag law for spherical particles
CFIPS=GRND7;STORE(SIZE)
   Set minimum slip velocity, and particle diameter
CFIPA=1E-6;CFIPB=1E-3
   Get interphase heat transfer coefficients from local Nusselt
   number
CINT(H1)=GRND7; CINT(H2)=GRND7
   Interphase heat transfer driven by temperature difference
PHINT(H1)=TMP2B/TMP1B
    GROUP 11. Initialization of variable or porosity fields
FIINIT(W1)=WIN;FIINIT(W2)=WIN
FIINIT(R1)=0.5;FIINIT(R2)=0.5
    GROUP 13. Boundary conditions and special sources
INLET(INLET,LOW,1,1,1,NY,1,1,1,1)
VALUE(INLET,P1,0.9*RHO1*WIN);VALUE(INLET,W1,WIN)
VALUE(INLET,H1,(300-TMP1A)/TMP1B)
VALUE(INLET,P2,0.1*RHO2*WIN);VALUE(INLET,W2,WIN)
VALUE(INLET,H2,(600-TMP2A)/TMP2B)
 
PATCH(OUTLET,HIGH,1,1,1,NY,NZ,NZ,1,1)
COVAL(OUTLET,P1,1.E1*RHO1,0.0);COVAL(OUTLET,P2,1.E1*RHO2,0.0)
COVAL(OUTLET,V1,ONLYMS,0.0);COVAL(OUTLET,W1,ONLYMS,0.0)
COVAL(OUTLET,V2,ONLYMS,0.0);COVAL(OUTLET,W2,ONLYMS,0.0)
COVAL(OUTLET,H1,ONLYMS,(300-TMP1A)/TMP1B)
COVAL(OUTLET,H2,ONLYMS,(300-TMP2A)/TMP2B)
 
WALL(TOP,NORTH,1,1,NY,NY,1,NZ,1,1)
COVAL(TOP,H1,LOGLAW,(400-TMP1A)/TMP1B)
WALL(BOT,SOUTH,1,1,1,1,1,NZ,1,1)
COVAL(BOT,H1,LOGLAW,(400-TMP1A)/TMP1B)
    GROUP 15. Termination of sweeps
LSWEEP=250
    GROUP 17. Under-relaxation devices
RELAX(P1,LINRLX,0.75)
RELAX(V1,FALSDT,10.0);RELAX(W1,FALSDT,10.0)
RELAX(V2,FALSDT,10.0);RELAX(W2,FALSDT,10.0)
RELAX(R1,LINRLX,0.8);RELAX(R2,LINRLX,0.8)
RELAX(H1,LINRLX,0.5);RELAX(H2,LINRLX,0.5)
    GROUP 22. Spot-value print-out
IYMON=5;IZMON=15;TSTSWP=-1
    GROUP 23. Field print-out and plot control