photon use
  ext
  parphi;;;;
 
  view y
  gr ou y 1
  msg pressure contours
  con p1 y 1 fi;0.001
  pause;con off;red
  msg heavier-phase volume-fraction contours
  con r2 y 1 fi;0.01
  pause
  msg the grid had 5 times as many z-direction
  msg intervals as are shown here
  gr y 1
  enduse
TEXT(2-PHASE STEADY SEDIMENTATION; PARAB:W581
TITLE
  DISPLAY
  A 2-phase mixture flows along a horizontal duct.
  Gravity causes the heavier material to fall to the bottom.
  The parabolic mode of calculation is employed.
  The flow is laminar.
  ENDDIS
REAL(HEIGHT,LENGTH,WIN,R1IN,R2IN)
HEIGHT=1.0;length=5.0*HEIGHT
win=1.0
    GROUP 3. X-direction grid specification
GRDPWR(X,10,height,1.0)
    GROUP 5. Z-direction grid specification
grdpwr(z,50,length,1.0);parab=t
SOLVE(P1,U1,w1)
ONEPHS=F;SOLVE(U2,w2,r1,R2)
    GROUP 9. Properties of the medium (or media)
RHO1=1.0;RHO2=1000.0;enul=1.e-4
    GROUP 10. Inter-phase-transfer processes and properties
CFIPS=1.e5
    GROUP 11. Initialization of variable or porosity fields
R1IN=0.9;R2IN=1-R1IN
    Initial values
FIINIT(W1)=WIN;FIINIT(W2)=WIN
    GROUP 13. Boundary conditions and special sources
    Inlet
INLET(INLET,LOW,1,NX,1,1,1,1,1,1)
VALUE(INLET,P1,RHO1*R1IN*WIN);VALUE(INLET,W1,WIN)
VALUE(INLET,P2,RHO2*R2IN*WIN);VALUE(INLET,W2,WIN)
 
PATCH(GRAVITY,PHASEM,1,NX,1,1,1,NZ,1,1)
COVAL(GRAVITY,U2,FIXFLU,-9.81*(1.0-RHO1/RHO2))
PATCH(BOTTOM,WWALL,1,1,1,1,1,NZ,1,1)
COVAL(BOTTOM,W1,1.0,0.0);COVAL(BOTTOM,W2,1.0,0.0)
    GROUP 16. Termination of iterations
LITHYD=25;SELREF=T;RESFAC=1.E-2
    GROUP 17. Under-relaxation devices
REAL(DTF);DTF=0.1*(height/9.81)**0.5
RELAX(U1,FALSDT,2.0*DTF);RELAX(U2,FALSDT,DTF)
RELAX(W1,FALSDT,2.0*DTF);RELAX(W2,FALSDT,2.0*DTF)
RELAX(R1,LINRLX,0.5);RELAX(R2,LINRLX,0.5)
    GROUP 22. Monitor print-out
IXMON=1;TSTSWP=-1;IDISPA=NZ/10