```

PHOTON USE
p
phi
1 20 1

msg grid (scale enlarged 20 times in y direction)
gr z 1
msg Press  to continue
pause;  cl
msg 1st-phase (vapour) velocity vectors
vec z 1 sh;  gr ou z 1
msg Press  to continue
pause ;  cl
msg 2nd-phase (water) velocity vectors
set vec comp;  au2 bv2 -;  vec z 1 sh;  gr ou z 1
msg Press  to continue
pause;  cl
msg contours of pressure
con p1 z 1 fi;0.1;  gr ou z 1
msg Press  to continue
pause;  cl
msg contours of 1st-phase (vapour) volume fraction
con gas z 1 fi;0.1;  gr ou z 1
msg Press  to continue
pause ;  cl
msg contours of 2nd-phase (water) enthalpy
con iliq z 1 fi;0.1;  gr ou z 1
msg Press e to END
enduse

GROUP 1. Run title
TEXT(BOILING , NO GRAVITY :              W897
TITLE
DISPLAY
NUMERICAL BENCHMARK PROBLEM 3.2: BOILING IN A CHANNEL
Saturated water enters a duct of uniform rectangular
cross-section. The first quarter of its length is
unheated; but heat is supplied to the remainder of the
pipe at a fixed rate, causing boiling, and a consequent
acceleration of both liquid and vapour.

Three cases are considered. In the first, the influence
of gravity is totally neglected. In the second, the duct
is vertical, with flow from bottom to top, and the effect
of gravity is accounted for. In the third, the pipe is
horizontal, and the effect of gravity is again taken into
account.

The task is to predict the distributions of steam and water
velocities and enthalpies, of pressure, and of volume
fraction, along the pipe. Special interest attaches to
comparisons between the three cases.
ENDDIS
REAL(CHATIM,REFMAS,VELCTY,HEAT,XLEN,SIDE,AREA)
VELCTY=0.01;HEAT=1.E5;XLEN=1.0;SIDE=0.01;AREA=SIDE*SIDE
GROUP 3. X-direction grid specification
GRDPWR(X,20,XLEN,1.0)
GROUP 4. Y-direction grid specification
GRDPWR(Y,10,SIDE,1.0);ZWLAST=SIDE
GROUP 7. Variables stored, solved & named
ONEPHS=F;SOLVE(P1,U1,U2,V1,V2,H1,H2,R1,R2)
NAME(R1)=GAS;NAME(R2)=LIQ;NAME(U2)=AU2;NAME(H2)=ILIQ;NAME(V2)=BV2
** Provide storage for inter-phase mass transfer
STORE(MDOT)
GROUP 8. Terms (in differential equations) & devices
** Cut off built-in sources
TERMS(H1,N,Y,Y,Y,Y,Y);TERMS(ILIQ,N,P,P,P,P,P)
GROUP 9. Properties of the medium (or media)
RHO2=1.E3;ENUL=1.E-3
GROUP 10. Inter-phase-transfer processes and properties
** Set constant inter-phase friction factor and activate
the calculation of the inter-phase mass transfer by
means of a heat balance between the two phases.
Note that the minus sign is merely a signal to use the
second-phase density.
CFIPS=-5.E1;CMDOT=HEATBL
** Set the inter-phase heat transfer coefficients
CINT(H1)=1.E-2;CINT(ILIQ)=1.E0
** Set the values of the enthalpies at the interface
PHINT(H1)=2.5E6;PHINT(ILIQ)=4.0E5
GROUP 11. Initialization of variable or porosity fields
FIINIT(GAS)=1.E-2;FIINIT(LIQ)=0.99
FIINIT(H1)=2.5E6;FIINIT(ILIQ)=4.0E5
FIINIT(U1)=VELCTY;FIINIT(AU2)=VELCTY;FIINIT(MDOT)=0.0
GROUP 13. Boundary conditions and special sources
** Inlet at low-x (west) end
INLET(INLET,WEST,1,1,1,NY,1,1,1,1)
VALUE(INLET,P2,VELCTY*RHO2);VALUE(INLET,AU2,VELCTY)
VALUE(INLET,ILIQ,4.0E5)
** Outlet at high-x (east)
PATCH(OUTLET,CELL,NX,NX,1,NY,1,1,1,1)
COVAL(OUTLET,P1,1.0,0.0);COVAL(OUTLET,P2,1.0*RHO2,0.0)
COVAL(OUTLET,U1,ONLYMS,0.0);COVAL(OUTLET,AU2,ONLYMS,0.0)
COVAL(OUTLET,V1,ONLYMS,0.0);COVAL(OUTLET,BV2,ONLYMS,0.0)
COVAL(OUTLET,H1,ONLYMS,SAME);COVAL(OUTLET,ILIQ,ONLYMS,SAME)
** Heated walls
PATCH(NORTH1,PHASEM,NX/4+1,NX,NY,NY,1,1,1,1)
COVAL(NORTH1,ILIQ,FIXFLU,HEAT)
PATCH(SOUTH1,PHASEM,NX/4+1,NX,1,1,1,1,1,1)
COVAL(SOUTH1,ILIQ,FIXFLU,HEAT)
** Friction at walls
PATCH(NORTH2,NORTH,1,NX,NY,NY,1,1,1,1)
COVAL(NORTH2,U1,-0.002,0.0);COVAL(NORTH2,AU2,-0.002,0.0)
PATCH(SOUTH2,SOUTH,1,NX,1,1,1,1,1,1)
COVAL(SOUTH2,U1,-0.002,0.0);COVAL(SOUTH2,AU2,-0.002,0.0)
GROUP 15. Termination of sweeps
LSWEEP=500
GROUP 16. Termination of iterations
REFMAS=RHO2*VELCTY*AREA;RESREF(P1)=1.E-7*VELCTY*AREA
RESREF(GAS)=1.E-7*REFMAS;RESREF(LIQ)=1.E-7*REFMAS
RESREF(U1)=RESREF(GAS)*VELCTY
RESREF(AU2)=RESREF(LIQ)*VELCTY
RESREF(V1)=RESREF(GAS)*VELCTY
RESREF(BV2)=RESREF(LIQ)*VELCTY
RESREF(H1)=RESREF(GAS)*PHINT(H1)
RESREF(ILIQ)=RESREF(LIQ)*PHINT(ILIQ)
LITER(U1)=20;LITER(V1)=1;LITER(AU2)=20;LITER(BV2)=1
LITER(LIQ)=1;LITER(GAS)=1
GROUP 17. Under-relaxation devices
CHATIM=0.01*XLEN/VELCTY
RELAX(U1,FALSDT,CHATIM);RELAX(AU2,FALSDT,0.1*CHATIM)
RELAX(V1,FALSDT,0.001*CHATIM);RELAX(BV2,FALSDT,0.001*CHATIM)
RELAX(H1,FALSDT,CHATIM);RELAX(ILIQ,FALSDT,0.1*CHATIM)
RELAX(GAS,LINRLX,0.35);RELAX(LIQ,LINRLX,0.35)
GROUP 19. Data communicated by satellite to GROUND
GROUP 20. Preliminary print-out
GROUP 22. Spot-value print-out
TSTSWP=-1;IXMON=NX/2;IYMON=NY/2
GROUP 23. Field print-out and plot control
IPLTF=3;IPLTL=LSWEEP;NPLT=1;NXPRIN=NX/5;NYPRIN=NY/5;ORSIZ=0.4
PATCH(LONGPLOT,PROFIL,1,NX,1,1,1,1,1,1)
PLOT(LONGPLOT,P1,0.0,0.0)
PLOT(LONGPLOT,LIQ,0.0,0.0);PLOT(LONGPLOT,U1,-1.0,-1.0)
PLOT(LONGPLOT,AU2,-1.0,-1.0);PLOT(LONGPLOT,MDOT,0.0,0.0)
PATCH(MAP,CONTUR,1,NX,1,NY,1,1,1,1)
PLOT(MAP,P1,0.0,10.0);PLOT(MAP,U1,0.0,10.0)
PLOT(MAP,AU2,0.0,10.0);PLOT(MAP,GAS,0.0,10.0)
PLOT(MAP,LIQ,0.0,10.0);PLOT(MAP,ILIQ,0.0,10.0)
GROUP 24. Dumps for restarts
```