TALK=F;RUN( 1, 1)

TEXT( Library case Y616: Conjugate heat transfer of rotating objects

  >>>>>>>>>>>>>>>>>>>>>> Comment begins >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
  PLANT information :
     * Data input groups used: 8, 9 , 13
     * Ground groups planted : 8-1, 9-6, 9-7, 13
     * Headings used  : SCUF??, PRPT??, SORC??
     * Functions used : None
     * Commands used  : REGION
  <<<<<<<<<<<<<<<<<<<<<<<<<  Comment ends <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    GROUP 2. Transience; time-step specification
    GROUP 3. X-direction grid specification
CARTES=F;GRDPWR(X,21,2.*3.14,1.0);RINNER=0.05
    GROUP 4. Y-direction grid specification
GRDPWR(Y,20,0.25,1.0)
    GROUP 5. Z-direction grid specification
    GROUP 7. Variables stored, solved & named
SOLVE(P1,U1,V1,TEMP)
SOLUTN(U1,Y,Y,N,P,P,Y)
SOLUTN(V1,Y,Y,N,P,P,Y)
SOLUTN(TEMP,Y,Y,N,P,P,Y)
STORE(MARK)
    GROUP 8. Terms (in differential equations) & devices
TERMS(TEMP,N,Y,Y,P,P,P)
U1AD=GRND
     VELAD=-3.*RG2D
    REGION() 1
  >>>>>>>>>>>>>>>>>>>>>>>> Comment begins >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    The above statement removes the rotation velocity from the solid.
  <<<<<<<<<<<<<<<<<<<<<<<<<  Comment ends <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    GROUP 9. Properties of the medium (or media)
ENUL=GRND
     VISL=0.001
PRNDTL(TEMP)=-GRND
     LAMPR(U1)=1.e5
    REGION() 1
     LAMPR(V1)=1.e5
    REGION() 1
     LAMPR(TEMP)=.003
    REGION() 1
  >>>>>>>>>>>>>>>>>>>>>>>> Comment begins >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    The above settings introduce the artificial high viscosities and
    actual conductivity for solid pipe material marked by MARK=1.
  <<<<<<<<<<<<<<<<<<<<<<<<<  Comment ends <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    GROUP 11. Initialization of variable or porosity fields
INIADD=F;FIINIT(MARK)=0.0
PATCH(INI1,INIVAL,1,NX,9,12,1,NZ,1,1)
INIT (INI1,MARK,ZERO,1.0)
  >>>>>>>>>>>>>>>>>>>>>>>> Comment begins >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    INIT command initializes unity marker for solid pipe.
  <<<<<<<<<<<<<<<<<<<<<<<<<  Comment ends <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
CONPOR(0.0,EAST,-2,-2,1,8,1,NZ)
CONPOR(0.0,EAST,-9,-9,1,8,1,NZ)
CONPOR(0.0,EAST,-16,-16,1,8,1,NZ)

CONPOR(0.0,EAST,-5,-5,13,NY,1,NZ)
CONPOR(0.0,EAST,-12,-12,13,NY,1,NZ)
CONPOR(0.0,EAST,-19,-19,13,NY,1,NZ)
    GROUP 13. Boundary conditions and special sources
XCYCLE=T
  ** South wall
PATCH(WALLS,SWALL,1,NX,1,1,1,NZ,1,LSTEP)
COVAL(WALLS,U1,1.0,0.0)
COVAL(WALLS,TEMP,1.0,0.0)
  ** North wall
PATCH(WALLN,NWALL,1,NX,NY,NY,1,NZ,1,LSTEP)
COVAL(WALLN,U1,1.0,0.0)
COVAL(WALLN,TEMP,1.0,0.0)
  ** Pressure relief
PATCH(FIXPR1,CELL,1,1,1,1,1,1,1,1)
COVAL(FIXPR1,P1,FIXP,0.0)
COVAL(FIXPR1,TEMP,ONLYMS,SAME)
PATCH(FIXPR2,CELL,1,1,NY,NY,1,1,1,1)
COVAL(FIXPR2,P1,FIXP,0.0)
COVAL(FIXPR2,TEMP,ONLYMS,SAME)
  ** Rotated pipe  velocity
PATCH(SS001,VOLUME,1,NX,1,NY,1,NZ,1,lstep)
   CO=1.e10
   VAL=3.0*RG2D
COVAL(SS001,U1,GRND,GRND)
   CO=1.e10
   VAL=0.0
COVAL(SS001,V1,GRND,GRND)
   CO=FIXFLU
   VAL=3.0/FIXFLU
COVAL(SS001,TEMP,GRND,GRND)
  >>>>>>>>>>>>>>>>>>>>>>>> Comment begins >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
    PATCH name SS001 indicates that it is the solid pipe, MARK=1, for
    which the velocities are set to solid body rotation. It is heated up
    by volumetric heat source.
  <<<<<<<<<<<<<<<<<<<<<<<<<  Comment ends <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    GROUP 15. Termination of sweeps
LSWEEP=200
    GROUP 16. Termination of iterations
    GROUP 17. Under-relaxation devices
RELAX(P1,LINRLX,0.5)
RELAX(U1,FALSDT,100.0);RELAX(V1,FALSDT,100.)
    GROUP 18. Limits on variables or increments to them
    GROUP 19. Data communicated by satellite to GROUND
NAMSAT=MOSG
    GROUP 20. Preliminary print-out
    GROUP 21. Print-out of variables
    GROUP 22. Spot-value print-out
    GROUP 23. Field print-out and plot control
TSTSWP=-1
idispa=1; csg1=p; selref=t; resfac=1.e-2
  PHOTON USE
  extrapolate



  vi z
  GR Y 1;GR Y M;GR Y 10 10 Z 1 1;GR Y 14 14 Z 1 1
  GR X 4 4 Y 1 9 Z 1 1
  GR X 11 11 Y 1 9 Z 1 1
  GR X 18 18 Y 1 9 Z 1 1
  GR X 7 7 Y 14 21 Z 1 1
  GR X 14 14 Y 14 21 Z 1 1
  GR X 21 21 Y 14 21 Z 1 1
  msg  Vectors
  vec z 1 sh
  msg  Hit Enter to continue
  pause;cl
  msg  Temperature contours
  con temp z 1 fil;.001
  GR Y 1;GR Y M;GR Y 10 10 Z 1 1;GR Y 14 14 Z 1 1
  GR X 4 4 Y 1 9 Z 1 1
  GR X 11 11 Y 1 9 Z 1 1;GR X 18 18 Y 1 9 Z 1 1
  GR X 7 7 Y 14 21 Z 1 1;GR X 14 14 Y 14 21 Z 1 1
  GR X 21 21 Y 14 21 Z 1 1
  msg  Hit Enter to continue
  ENDUSE
STOP